lib/Gruntmaster/App/Command/Add.pm

   1 package Gruntmaster::App::Command::Add;
   2
   3 use 5.014000;
   4 use warnings;
   5
   6 our $VERSION = '5999.000_004';
   7
   8 use Gruntmaster::App '-command';
   9 use Gruntmaster::Data;
  10
  11 use Date::Parse qw/str2time/;
  12 use File::Slurp qw/read_file write_file/;
  13 use IO::Prompter [ -style => 'bold', '-stdio', '-verbatim' ];
  14 use JSON::MaybeXS qw/encode_json/;
  15 use Term::ANSIColor qw/RED RESET/;
  16
  17 use constant LEVEL_VALUES => {
  18         beginner => 100,
  19         easy => 250,
  20         medium => 500,
  21         hard => 1000,
  22 };
  23
  24 sub usage_desc { '%c [-cp] add id' }
  25
  26 my %TABLE = (
  27         contests => \&add_contest,
  28         problems => \&add_problem,
  29 );
  30
  31 sub validate_args {
  32         my ($self, $opt, $args) = @_;
  33         my @args = @$args;
  34         $self->usage_error('No table selected') unless $self->app->table;
  35         $self->usage_error('Don\'t know how to add to this table') unless $TABLE{$self->app->table};
  36         $self->usage_error('Wrong number of arguments') if @args != 1;
  37 }
  38
  39 sub execute {
  40         my ($self, $opt, $args) = @_;
  41         my ($id) = @$args;
  42         $TABLE{$self->app->table}->($self, $id);
  43 }
  44
  45 sub add_contest {
  46         my ($self, $id) = @_;
  47
  48         my $name = prompt 'Contest name';
  49         my $owner = prompt 'Owner';
  50         my $start = str2time prompt 'Start time' or die 'Cannot parse time';
  51         my $stop = str2time prompt 'Stop time' or die 'Cannot parse time';
  52
  53         db->insert(contests => {id => $id, name => $name, owner => $owner, start => $start, stop => $stop});
  54 }
  55
  56 sub add_problem {
  57         my ($self, $id) = @_;
  58         my $db = $self->app->db;
  59
  60         my $name = prompt 'Problem name';
  61         my $private = prompt('Private?', '-yn') eq 'y';
  62         my $contest = prompt 'Contest';
  63         my $author = prompt 'Problem author (full name)';
  64         my $writer = prompt 'Problem statement writer (full name)';
  65         my $owner = prompt 'Problem owner (username)';
  66         my $level = prompt 'Problem level', -menu => "beginner\neasy\nmedium\nhard";
  67         my $value = LEVEL_VALUES->{$level};
  68         my $statement = read_file prompt 'File with problem statement', -complete => 'filenames';
  69         my $generator = prompt 'Generator', -menu => "File\nRun\nUndef";
  70         my $runner = prompt 'Runner', -menu => "File\nVerifier\nInteractive";
  71         my $judge = prompt 'Judge', -menu => "Absolute\nPoints";
  72         my $testcnt = prompt 'Test count', '-i';
  73
  74         my $timeout = prompt 'Time limit (seconds)', '-n';
  75         my $olimit = prompt 'Output limit (bytes)', '-i';
  76         say 'Memory limits are broken, so I won\'t ask you for one';
  77
  78         my (@tests, $gensource, $genformat, $versource, $verformat);
  79
  80         if ($generator eq 'Run') {
  81                 $gensource = read_file prompt '[Generator::Run] Generator file name', -complete => 'filenames';
  82                 $genformat = prompt '[Generator::Run] Generator format', -menu => [qw/C CPP MONO JAVA PASCAL PERL PYTHON/];
  83         }
  84
  85         if ($runner eq 'File') {
  86                 my $default = $judge eq 'Points' ? 10 : 'Ok';
  87                 $tests[$_ - 1] = prompt "[Runner::File] Score for test ${_} [$default]", -default => $default for 1 .. $testcnt;
  88         }
  89
  90         if ($runner eq 'Verifier' || $runner eq 'Interactive') {
  91                 say RED, 'WARNING: Runner::Interactive is experimental', RESET if $runner eq 'Interactive';
  92                 $versource = read_file prompt "[Runner::$runner] Verifier file name", -complete => 'filenames';
  93                 $verformat = prompt "[Runner::$runner] Verifier format", -menu => [qw/C CPP MONO JAVA PASCAL PERL PYTHON/];
  94         }
  95
  96         my %options = (
  97                 id => $id,
  98                 name => $name,
  99                 level => $level,
 100                 value => $value,
 101                 statement => $statement,
 102                 author => $author,
 103                 writer => $writer,
 104                 owner => $owner,
 105                 generator => $generator,
 106                 runner => $runner,
 107                 judge => $judge,
 108                 testcnt => $testcnt,
 109         );
 110         $options{private} = $private if $private;
 111         $options{timeout} = $timeout if $timeout;
 112         $options{olimit} = $olimit if $olimit;
 113         $options{tests} = encode_json \@tests if @tests;
 114         $options{gensource} = $gensource if $gensource;
 115         $options{genformat} = $genformat if $genformat;
 116         $options{versource} = $versource if $versource;
 117         $options{verformat} = $verformat if $verformat;
 118         db->insert(problems => \%options);
 119         db->insert(contest_problems => {problem => $id, contest => $contest}) if $contest;
 120 }
 121
 122 1;
 123 __END__