lib/Gruntmaster/Data.pm

   1 use utf8;
   2 package Gruntmaster::Data;
   3
   4 # Created by DBIx::Class::Schema::Loader
   5 # DO NOT MODIFY THE FIRST PART OF THIS FILE
   6
   7 use strict;
   8 use warnings;
   9
  10 use base 'DBIx::Class::Schema';
  11
  12 __PACKAGE__->load_namespaces;
  13
  14
  15 # Created by DBIx::Class::Schema::Loader v0.07039 @ 2014-03-05 13:11:39
  16 # DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:dAEmtAexvUaNXLgYz2rNEg
  17
  18 our $VERSION = '5999.000_010';
  19
  20 use Lingua::EN::Inflect qw/PL_N/;
  21 use JSON::MaybeXS qw/decode_json/;
  22 use List::Util qw/sum/;
  23 use PerlX::Maybe qw/maybe/;
  24 use Sub::Name qw/subname/;
  25
  26 use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private statement timeout olimit value/];
  27 use constant USER_PUBLIC_COLUMNS => [qw/id admin name town university level/];
  28 use constant JOBS_PER_PAGE => 10;
  29
  30 sub dynsub{
  31         our ($name, $sub) = @_;
  32         no strict 'refs';
  33         *$name = subname $name => $sub
  34 }
  35
  36 BEGIN {
  37         for my $rs (qw/contest contest_problem job open problem user/) {
  38                 my $rsname = ucfirst $rs;
  39                 $rsname =~ s/_([a-z])/\u$1/g;
  40                 dynsub PL_N($rs) => sub { $_[0]->resultset($rsname)              };
  41                 dynsub      $rs  => sub { $_[0]->resultset($rsname)->find($_[1]) };
  42         }
  43 }
  44
  45 use constant LEVEL_VALUES => {
  46         beginner => 100,
  47         easy => 250,
  48         medium => 500,
  49         hard => 1000,
  50 };
  51
  52 sub calc_score{
  53         my ($mxscore, $time, $tries, $totaltime) = @_;
  54         my $score = $mxscore;
  55         $time = 0 if $time < 0;
  56         $time = 300 if $time > $totaltime;
  57         $score = ($totaltime - $time) / $totaltime * $score;
  58         $score -= $tries / 10 * $mxscore;
  59         $score = $mxscore * 3 / 10 if $score < $mxscore * 3 / 10;
  60         int $score + 0.5
  61 }
  62
  63 sub standings {
  64         my ($self, $ct) = @_;
  65         $ct &&= $self->contest($ct);
  66
  67         my @problems = map { $_->problem } $self->contest_problems->search({contest => $ct && $ct->id}, {qw/join problem order_by problem.level/});
  68         my (%scores, %tries);
  69         for my $job ($self->jobs->search({contest => $ct && $ct->id}, {order_by => 'id'})) {
  70                 if ($ct) {
  71                         my $open = $self->opens->find($ct->id, $job->problem->id, $job->owner->id);
  72                         my $time = $job->date - ($open ? $open->time : $ct->start);
  73                         next if $time < 0;
  74                         my $value = $job->problem->value // LEVEL_VALUES->{$job->problem->level};
  75                         my $factor = $job->result ? 0 : 1;
  76                         $factor = $1 / 100 if $job->result_text =~ /^(\d+ )/;
  77                         $scores{$job->owner->id}{$job->problem->id} = int ($factor * calc_score ($value, $time, $tries{$job->owner->id}{$job->problem->id}++, $ct->stop - $ct->start));
  78                 } else {
  79                         no warnings 'numeric';
  80                         $scores{$job->owner->id}{$job->problem->id} = 0 + $job->result_text || ($job->result ? 0 : 100)
  81                 }
  82         }
  83
  84         my @st = sort { $b->{score} <=> $a->{score} or $a->{user}->id cmp $b->{user}->id} map {
  85                 my $user = $_;
  86                 +{
  87                         user => $self->user($user),
  88                         score => sum (values %{$scores{$user}}),
  89                         scores => [map { $scores{$user}{$_->id} // '-'} @problems],
  90                         problems => $ct,
  91                 }
  92         } keys %scores;
  93
  94         $st[0]->{rank} = 1;
  95         $st[$_]->{rank} = $st[$_ - 1]->{rank} + ($st[$_]->{score} < $st[$_ - 1]->{score}) for 1 .. $#st;
  96         @st
  97 }
  98
  99 sub user_list {
 100         my $rs = $_[0]->users->search(undef, {order_by => 'name', columns => USER_PUBLIC_COLUMNS});
 101         [ map +{ $_->get_columns }, $rs->all ]
 102 }
 103
 104 sub user_entry {
 105         my ($self, $id) = @_;
 106         +{ $self->users->find($id, {columns => USER_PUBLIC_COLUMNS})->get_columns }
 107 }
 108
 109 sub problem_list {
 110         my ($self, %args) = @_;
 111         my $rs = $self->problems->search(undef, {order_by => 'me.name', columns => PROBLEM_PUBLIC_COLUMNS, prefetch => 'owner'});
 112         $rs = $rs->search({-or => ['contest_problems.contest' => undef, 'contest.stop' => {'<=', time}], 'me.private' => 0}, {join => {'contest_problems' => 'contest'}, distinct => 1}) unless $args{contest};
 113         $rs = $rs->search({'contest_problems.contest' => $args{contest}}, {join => 'contest_problems'}) if $args{contest};
 114         $rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
 115         my %params;
 116         $params{contest} = $args{contest} if $args{contest};
 117         for ($rs->all) {
 118                 $params{$_->level} //= [];
 119                 push @{$params{$_->level}}, {$_->get_columns, owner_name => $_->owner->name} ;
 120         }
 121         \%params
 122 }
 123
 124 sub problem_entry {
 125         my ($self, $id, $contest, $user) = @_;
 126         my $pb = $self->problems->find($id, {columns => PROBLEM_PUBLIC_COLUMNS, prefetch => 'owner'});
 127         my $running = $contest && $self->contest($contest)->is_running;
 128         eval {
 129                 $self->opens->create({
 130                         contest => $contest,
 131                         problem => $id,
 132                         owner => $user,
 133                         time => time,
 134                 })
 135         } if $running;
 136         +{ $pb->get_columns, owner_name => $pb->owner->name, cansubmit => $contest ? $running : 1 }
 137 }
 138
 139 sub contest_list {
 140         my ($self, %args) = @_;
 141         my $rs = $self->contests->search(undef, {order_by => {-desc => 'start'}, prefetch => 'owner'});
 142         $rs = $rs->search({owner => $args{owner}}) if $args{owner};
 143         my %params;
 144         for ($rs->all) {
 145                 my $state = $_->is_pending ? 'pending' : $_->is_running ? 'running' : 'finished';
 146                 $params{$state} //= [];
 147                 push @{$params{$state}}, { $_->get_columns, started => !$_->is_pending, owner_name => $_->owner->name };
 148         }
 149         \%params
 150 }
 151
 152 sub contest_entry {
 153         my ($self, $id) = @_;
 154         my $ct = $self->contest($id);
 155         +{ $ct->get_columns, started => !$ct->is_pending, owner_name => $ct->owner->name }
 156 }
 157
 158 sub job_list {
 159         my ($self, %args) = @_;
 160         $args{page} //= 1;
 161         my $rs = $self->jobs->search(undef, {order_by => {-desc => 'me.id'}, prefetch => ['problem', 'owner'], rows => JOBS_PER_PAGE, page => $args{page}});
 162         $rs = $rs->search({'me.owner' => $args{owner}})   if $args{owner};
 163         $rs = $rs->search({contest    => $args{contest}}) if $args{contest};
 164         $rs = $rs->search({problem    => $args{problem}}) if $args{problem};
 165         return {
 166                 log => [map {
 167                         my %params = $_->get_columns;
 168                         $params{owner_name}   = $_->owner->name;
 169                         $params{problem_name} = $_->problem->name;
 170                         $params{results} &&= decode_json $params{results};
 171                         $params{size}      = length $params{source};
 172                         delete $params{source};
 173                         \%params
 174                 } $rs->all],
 175                 current_page => $rs->pager->current_page,
 176                 maybe previous_page => $rs->pager->previous_page,
 177                 maybe next_page => $rs->pager->next_page,
 178                 maybe last_page => $rs->pager->last_page,
 179         }
 180 }
 181
 182 sub job_entry {
 183         my ($self, $id) = @_;
 184         my $job = $self->jobs->find($id, {prefetch => ['problem', 'owner']});
 185         my %params = $job->get_columns;
 186         $params{owner_name}   = $job->owner->name;
 187         $params{problem_name} = $job->problem->name;
 188         $params{results} &&= decode_json $params{results};
 189         $params{size}      = length $params{source};
 190         delete $params{source};
 191         \%params
 192 }
 193
 194 1;
 195
 196 __END__
 197
 198 =encoding utf-8
 199
 200 =head1 NAME
 201
 202 Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools
 203
 204 =head1 SYNOPSIS
 205
 206   my $db = Gruntmaster::Data->connect('dbi:Pg:');
 207
 208   my $problem = $db->problem('my_problem');
 209   $problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
 210   $problem->rerun; # And rerun all jobs for this problem
 211
 212   # ...
 213
 214   my $contest = $db->contests->create({ # Create a new contest
 215     id => 'my_contest',
 216     name => 'My Awesome Contest',
 217     start => time + 100,
 218     end => time + 1900,
 219   });
 220   $db->contest_problems->create({ # Add a problem to the contest
 221     contest => 'my_contest',
 222     problem => 'my_problem',
 223   });
 224
 225   say 'The contest has not started yet' if $contest->is_pending;
 226
 227   # ...
 228
 229   my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
 230   $_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest
 231
 232 =head1 DESCRIPTION
 233
 234 Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.
 235
 236 In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:
 237
 238 =over
 239
 240 =item contests
 241
 242 Equivalent to C<< $schema->resultset('Contest') >>
 243
 244 =item contest_problems
 245
 246 Equivalent to C<< $schema->resultset('ContestProblem') >>
 247
 248 =item jobs
 249
 250 Equivalent to C<< $schema->resultset('Job') >>
 251
 252 =item problems
 253
 254 Equivalent to C<< $schema->resultset('Problem') >>
 255
 256 =item users
 257
 258 Equivalent to C<< $schema->resultset('User') >>
 259
 260 =item contest($id)
 261
 262 Equivalent to C<< $schema->resultset('Contest')->find($id) >>
 263
 264 =item job($id)
 265
 266 Equivalent to C<< $schema->resultset('Job')->find($id) >>
 267
 268 =item problem($id)
 269
 270 Equivalent to C<< $schema->resultset('Problem')->find($id) >>
 271
 272 =item user($id)
 273
 274 Equivalent to C<< $schema->resultset('User')->find($id) >>
 275
 276 =item user_list
 277
 278 Returns a list of users as an arrayref containing hashrefs.
 279
 280 =item user_entry($id)
 281
 282 Returns a hashref with information about the user $id.
 283
 284 =item problem_list([%args])
 285
 286 Returns a list of problems grouped by level. A hashref with levels as keys.
 287
 288 Takes the following arguments:
 289
 290 =over
 291
 292 =item owner
 293
 294 Only show problems owned by this user
 295
 296 =item contest
 297
 298 Only show problems in this contest
 299
 300 =back
 301
 302 =item problem_entry($id, [$contest, $user])
 303
 304 Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.
 305
 306 =item contest_list([%args])
 307
 308 Returns a list of contests grouped by state. A hashref with the following keys:
 309
 310 =over
 311
 312 =item pending
 313
 314 An arrayref of hashrefs representing pending contests
 315
 316 =item running
 317
 318 An arrayref of hashrefs representing running contests
 319
 320 =item finished
 321
 322 An arrayref of hashrefs representing finished contests
 323
 324 =back
 325
 326 Takes the following arguments:
 327
 328 =over
 329
 330 =item owner
 331
 332 Only show contests owned by this user.
 333
 334 =back
 335
 336 =item contest_entry($id)
 337
 338 Returns a hashref with information about the contest $id.
 339
 340 =item job_list([%args])
 341
 342 Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:
 343
 344 =over
 345
 346 =item owner
 347
 348 Only show jobs submitted by this user.
 349
 350 =item contest
 351
 352 Only show jobs submitted in this contest.
 353
 354 =item problem
 355
 356 Only show jobs submitted for this problem.
 357
 358 =item page
 359
 360 Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.
 361
 362 =back
 363
 364 =item job_entry($id)
 365
 366 Returns a hashref with information about the job $id.
 367
 368 =back
 369
 370 =head1 AUTHOR
 371
 372 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
 373
 374 =head1 COPYRIGHT AND LICENSE
 375
 376 Copyright (C) 2014 by Marius Gavrilescu
 377
 378 This library is free software; you can redistribute it and/or modify
 379 it under the same terms as Perl itself, either Perl version 5.18.1 or,
 380 at your option, any later version of Perl 5 you may have available.
 381
 382
 383 =cut