lib/Gruntmaster/Data.pm

   1 use utf8;
   2 package Gruntmaster::Data;
   3
   4 # Created by DBIx::Class::Schema::Loader
   5 # DO NOT MODIFY THE FIRST PART OF THIS FILE
   6
   7 use strict;
   8 use warnings;
   9
  10 use base 'DBIx::Class::Schema';
  11
  12 __PACKAGE__->load_namespaces;
  13
  14
  15 # Created by DBIx::Class::Schema::Loader v0.07039 @ 2014-03-05 13:11:39
  16 # DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:dAEmtAexvUaNXLgYz2rNEg
  17
  18 our $VERSION = '5999.000_012';
  19
  20 use Lingua::EN::Inflect qw/PL_N/;
  21 use JSON::MaybeXS qw/decode_json/;
  22 use PerlX::Maybe qw/maybe/;
  23 use Sub::Name qw/subname/;
  24
  25 use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private statement timeout olimit value/];
  26 use constant USER_PUBLIC_COLUMNS => [qw/id admin name town university level/];
  27 use constant JOBS_PER_PAGE => 10;
  28
  29 sub dynsub{
  30         our ($name, $sub) = @_;
  31         no strict 'refs'; ## no critic (Strict)
  32         *$name = subname $name => $sub
  33 }
  34
  35 BEGIN {
  36         for my $rs (qw/contest contest_problem job open problem user problem_status contest_status/) {
  37                 my $rsname = ucfirst $rs;
  38                 $rsname =~ s/_([a-z])/\u$1/gs;
  39                 dynsub PL_N($rs) => sub { $_[0]->resultset($rsname)              };
  40                 dynsub      $rs  => sub { $_[0]->resultset($rsname)->find($_[1]) };
  41         }
  42 }
  43
  44 sub user_list {
  45         my $rs = $_[0]->users->search(undef, {columns => USER_PUBLIC_COLUMNS, prefetch => [qw/problem_statuses contest_statuses/]} );
  46         [ sort { $b->{solved} <=> $a->{solved} or $b->{attempted} <=> $a->{attempted} } map { ## no critic (ProhibitReverseSort)
  47                 my $solved    = $_->problem_statuses->count(solved => 1);
  48                 my $attempted = $_->problem_statuses->count(solved => 0);
  49                 my $contests  = $_->contest_statuses->count;
  50                 +{ $_->get_columns, solved => $solved, attempted => $attempted, contests => $contests }
  51         } $rs->all ]
  52 }
  53
  54 sub user_entry {
  55         my ($self, $id) = @_;
  56         my $user = $self->users->find($id, {columns => USER_PUBLIC_COLUMNS, prefetch => [qw/problem_statuses contest_statuses/]});
  57         my @problems = map { {problem => $_->get_column('problem'), solved => $_->solved} } $user->problem_statuses;
  58         my @contests = map { {contest => $_->contest->id, contest_name => $_->contest->name, rank => $_->rank, score => $_->score} } $user->contest_statuses->search(undef, {prefetch => 'contest'});
  59         +{ $user->get_columns, problems => \@problems, contests => \@contests }
  60 }
  61
  62 sub problem_list {
  63         my ($self, %args) = @_;
  64         my $rs = $self->problems->search(undef, {order_by => 'me.name', columns => PROBLEM_PUBLIC_COLUMNS, prefetch => 'owner'});
  65         $rs = $rs->search({-or => ['contest_problems.contest' => undef, 'contest.stop' => {'<=', time}], 'me.private' => 0}, {join => {'contest_problems' => 'contest'}, distinct => 1}) unless $args{contest};
  66         $rs = $rs->search({'contest_problems.contest' => $args{contest}}, {join => 'contest_problems'}) if $args{contest};
  67         $rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
  68         my %params;
  69         $params{contest} = $args{contest} if $args{contest};
  70         for ($rs->all) {
  71                 $params{$_->level} //= [];
  72                 push @{$params{$_->level}}, {$_->get_columns, owner_name => $_->owner->name} ;
  73         }
  74         \%params
  75 }
  76
  77 sub problem_entry {
  78         my ($self, $id, $contest, $user) = @_;
  79         my $running = $contest && $self->contest($contest)->is_running;
  80         my $columns = PROBLEM_PUBLIC_COLUMNS;
  81         push @$columns, 'solution' unless $running;
  82         my $pb = $self->problems->find($id, {columns => $columns, prefetch => 'owner'});
  83         eval { ## no critic (RequireCheckingReturnValueOfEval)
  84                 $self->opens->create({
  85                         contest => $contest,
  86                         problem => $id,
  87                         owner => $user,
  88                         time => time,
  89                 })
  90         } if $running;
  91         $contest &&= $self->contest($contest);
  92         +{ $pb->get_columns, owner_name => $pb->owner->name, cansubmit => $contest ? $running : 1, $running ? (contest_start => $contest->start, contest_stop => $contest->stop) : () }
  93 }
  94
  95 sub contest_list {
  96         my ($self, %args) = @_;
  97         my $rs = $self->contests->search(undef, {order_by => {-desc => 'start'}, prefetch => 'owner'});
  98         $rs = $rs->search({owner => $args{owner}}) if $args{owner};
  99         my %params;
 100         for ($rs->all) {
 101                 my $state = $_->is_pending ? 'pending' : $_->is_running ? 'running' : 'finished';
 102                 $params{$state} //= [];
 103                 push @{$params{$state}}, { $_->get_columns, started => !$_->is_pending, owner_name => $_->owner->name };
 104         }
 105         \%params
 106 }
 107
 108 sub contest_entry {
 109         my ($self, $id) = @_;
 110         my $ct = $self->contest($id);
 111         +{ $ct->get_columns, started => !$ct->is_pending, owner_name => $ct->owner->name }
 112 }
 113
 114 sub job_list {
 115         my ($self, %args) = @_;
 116         $args{page} //= 1;
 117         my $rs = $self->jobs->search(undef, {order_by => {-desc => 'me.id'}, prefetch => ['problem', 'owner'], rows => JOBS_PER_PAGE, page => $args{page}});
 118         $rs = $rs->search({'me.owner' => $args{owner}})   if $args{owner};
 119         $rs = $rs->search({contest    => $args{contest}}) if $args{contest};
 120         $rs = $rs->search({problem    => $args{problem}}) if $args{problem};
 121         return {
 122                 log => [map {
 123                         my %params = $_->get_columns;
 124                         $params{owner_name}   = $_->owner->name;
 125                         $params{problem_name} = $_->problem->name;
 126                         $params{results} &&= decode_json $params{results};
 127                         $params{size}      = length $params{source};
 128                         delete $params{source};
 129                         \%params
 130                 } $rs->all],
 131                 current_page => $rs->pager->current_page,
 132                 maybe previous_page => $rs->pager->previous_page,
 133                 maybe next_page => $rs->pager->next_page,
 134                 maybe last_page => $rs->pager->last_page,
 135         }
 136 }
 137
 138 sub job_entry {
 139         my ($self, $id) = @_;
 140         my $job = $self->jobs->find($id, {prefetch => ['problem', 'owner']});
 141         my %params = $job->get_columns;
 142         $params{owner_name}   = $job->owner->name;
 143         $params{problem_name} = $job->problem->name;
 144         $params{results} &&= decode_json $params{results};
 145         $params{size}      = length $params{source};
 146         delete $params{source};
 147         \%params
 148 }
 149
 150 sub update_status {
 151         my ($self) = @_;
 152         my @jobs = $self->jobs->search(undef, {cache => 1})->all;
 153
 154         my %hash;
 155         $hash{$_->get_column('problem'), $_->get_column('owner')} = [$_->id, $_->result ? 0 : 1] for @jobs;
 156         my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;
 157
 158         my @contest_statuses = map {
 159                 my $contest = $_->id;
 160                 map { [$contest, $_->{user}, $_->{score}, $_->{rank}] } $_->standings
 161         } $self->contests->all;
 162
 163         my $txn = sub {
 164                 $self->problem_statuses->delete;
 165                 $self->problem_statuses->populate([[qw/problem owner job solved/], @problem_statuses]);
 166                 $self->contest_statuses->delete;
 167                 $self->contest_statuses->populate([[qw/contest owner score rank/], @contest_statuses]);
 168         };
 169
 170         $self->txn_do($txn);
 171 }
 172
 173 1;
 174
 175 __END__
 176
 177 =encoding utf-8
 178
 179 =head1 NAME
 180
 181 Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools
 182
 183 =head1 SYNOPSIS
 184
 185   my $db = Gruntmaster::Data->connect('dbi:Pg:');
 186
 187   my $problem = $db->problem('my_problem');
 188   $problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
 189   $problem->rerun; # And rerun all jobs for this problem
 190
 191   # ...
 192
 193   my $contest = $db->contests->create({ # Create a new contest
 194     id => 'my_contest',
 195     name => 'My Awesome Contest',
 196     start => time + 100,
 197     end => time + 1900,
 198   });
 199   $db->contest_problems->create({ # Add a problem to the contest
 200     contest => 'my_contest',
 201     problem => 'my_problem',
 202   });
 203
 204   say 'The contest has not started yet' if $contest->is_pending;
 205
 206   # ...
 207
 208   my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
 209   $_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest
 210
 211 =head1 DESCRIPTION
 212
 213 Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.
 214
 215 In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:
 216
 217 =over
 218
 219 =item contests
 220
 221 Equivalent to C<< $schema->resultset('Contest') >>
 222
 223 =item contest_problems
 224
 225 Equivalent to C<< $schema->resultset('ContestProblem') >>
 226
 227 =item jobs
 228
 229 Equivalent to C<< $schema->resultset('Job') >>
 230
 231 =item problems
 232
 233 Equivalent to C<< $schema->resultset('Problem') >>
 234
 235 =item users
 236
 237 Equivalent to C<< $schema->resultset('User') >>
 238
 239 =item contest($id)
 240
 241 Equivalent to C<< $schema->resultset('Contest')->find($id) >>
 242
 243 =item job($id)
 244
 245 Equivalent to C<< $schema->resultset('Job')->find($id) >>
 246
 247 =item problem($id)
 248
 249 Equivalent to C<< $schema->resultset('Problem')->find($id) >>
 250
 251 =item user($id)
 252
 253 Equivalent to C<< $schema->resultset('User')->find($id) >>
 254
 255 =item user_list
 256
 257 Returns a list of users as an arrayref containing hashrefs.
 258
 259 =item user_entry($id)
 260
 261 Returns a hashref with information about the user $id.
 262
 263 =item problem_list([%args])
 264
 265 Returns a list of problems grouped by level. A hashref with levels as keys.
 266
 267 Takes the following arguments:
 268
 269 =over
 270
 271 =item owner
 272
 273 Only show problems owned by this user
 274
 275 =item contest
 276
 277 Only show problems in this contest
 278
 279 =back
 280
 281 =item problem_entry($id, [$contest, $user])
 282
 283 Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.
 284
 285 =item contest_list([%args])
 286
 287 Returns a list of contests grouped by state. A hashref with the following keys:
 288
 289 =over
 290
 291 =item pending
 292
 293 An arrayref of hashrefs representing pending contests
 294
 295 =item running
 296
 297 An arrayref of hashrefs representing running contests
 298
 299 =item finished
 300
 301 An arrayref of hashrefs representing finished contests
 302
 303 =back
 304
 305 Takes the following arguments:
 306
 307 =over
 308
 309 =item owner
 310
 311 Only show contests owned by this user.
 312
 313 =back
 314
 315 =item contest_entry($id)
 316
 317 Returns a hashref with information about the contest $id.
 318
 319 =item job_list([%args])
 320
 321 Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:
 322
 323 =over
 324
 325 =item owner
 326
 327 Only show jobs submitted by this user.
 328
 329 =item contest
 330
 331 Only show jobs submitted in this contest.
 332
 333 =item problem
 334
 335 Only show jobs submitted for this problem.
 336
 337 =item page
 338
 339 Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.
 340
 341 =back
 342
 343 =item job_entry($id)
 344
 345 Returns a hashref with information about the job $id.
 346
 347 =back
 348
 349 =head1 AUTHOR
 350
 351 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
 352
 353 =head1 COPYRIGHT AND LICENSE
 354
 355 Copyright (C) 2014 by Marius Gavrilescu
 356
 357 This library is free software; you can redistribute it and/or modify
 358 it under the same terms as Perl itself, either Perl version 5.18.1 or,
 359 at your option, any later version of Perl 5 you may have available.
 360
 361
 362 =cut