lib/Gruntmaster/Data.pm

   1 use utf8;
   2 package Gruntmaster::Data;
   3
   4 # Created by DBIx::Class::Schema::Loader
   5 # DO NOT MODIFY THE FIRST PART OF THIS FILE
   6
   7 use strict;
   8 use warnings;
   9
  10 use base 'DBIx::Class::Schema';
  11
  12 __PACKAGE__->load_namespaces;
  13
  14
  15 # Created by DBIx::Class::Schema::Loader v0.07039 @ 2014-03-05 13:11:39
  16 # DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:dAEmtAexvUaNXLgYz2rNEg
  17
  18 use parent qw/Exporter/;
  19 our $VERSION = '5999.000_013';
  20 our @EXPORT = qw/purge/; ## no critic (ProhibitAutomaticExportation)
  21
  22 use Lingua::EN::Inflect qw/PL_N/;
  23 use JSON::MaybeXS qw/decode_json/;
  24 use HTTP::Tiny;
  25 use PerlX::Maybe qw/maybe/;
  26 use Sub::Name qw/subname/;
  27
  28 use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private timeout olimit value/];
  29 use constant USER_PUBLIC_COLUMNS => [qw/id admin name town university country level/];
  30 use constant JOBS_PER_PAGE => 10;
  31
  32 sub dynsub{
  33         our ($name, $sub) = @_;
  34         no strict 'refs'; ## no critic (Strict)
  35         *$name = subname $name => $sub
  36 }
  37
  38 BEGIN {
  39         for my $rs (qw/contest contest_problem job open problem user problem_status contest_status/) {
  40                 my $rsname = ucfirst $rs;
  41                 $rsname =~ s/_([a-z])/\u$1/gs;
  42                 dynsub PL_N($rs) => sub { $_[0]->resultset($rsname)              };
  43                 dynsub      $rs  => sub { $_[0]->resultset($rsname)->find($_[1]) };
  44         }
  45 }
  46
  47 sub user_list {
  48         my ($self) = @_;
  49         my $rs = $self->users->search(undef, {columns => USER_PUBLIC_COLUMNS} );
  50         my (%solved, %attempted, %contests);
  51
  52         for my $row ($self->problem_statuses->all) {
  53                 $solved   {$row->rawowner}++ if     $row->solved;
  54                 $attempted{$row->rawowner}++ unless $row->solved;
  55         }
  56         $contests{$_->rawowner}++ for $self->contest_statuses->all;
  57
  58         [ sort { $b->{solved} <=> $a->{solved} or $b->{attempted} <=> $a->{attempted} } map { ## no critic (ProhibitReverseSort)
  59                 my $id = $_->id;
  60                 +{ $_->get_columns,
  61                    solved => ($solved{$id} // 0),
  62                    attempted => ($attempted{$id} // 0),
  63                    contests => ($contests{$id} // 0) }
  64         } $rs->all ]
  65 }
  66
  67 sub user_entry {
  68         my ($self, $id) = @_;
  69         my $user = $self->users->find($id, {columns => USER_PUBLIC_COLUMNS, prefetch => [qw/problem_statuses contest_statuses/]});
  70         my @problems = map { {problem => $_->get_column('problem'), solved => $_->solved} } $user->problem_statuses->search(undef, {order_by => 'problem'});
  71         my @contests = map { {contest => $_->contest->id, contest_name => $_->contest->name, rank => $_->rank, score => $_->score} } $user->contest_statuses->search(undef, {prefetch => 'contest', order_by => 'contest.start DESC'});
  72         +{ $user->get_columns, problems => \@problems, contests => \@contests }
  73 }
  74
  75 sub problem_list {
  76         my ($self, %args) = @_;
  77         my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
  78         push @columns, 'solution' if $args{solution} && $args{contest} && !$self->contest($args{contest})->is_running;
  79         my $rs = $self->problems->search(undef, {order_by => 'me.name', columns => \@columns, prefetch => 'owner'});
  80         $rs = $rs->search({-or => ['contest_problems.contest' => undef, 'contest.stop' => {'<=', time}], 'me.private' => 0}, {join => {'contest_problems' => 'contest'}, distinct => 1}) unless $args{contest} || $args{private};
  81         $rs = $rs->search({'contest_problems.contest' => $args{contest}}, {join => 'contest_problems'}) if $args{contest};
  82         $rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
  83         my %params;
  84         $params{contest} = $args{contest} if $args{contest};
  85         for ($rs->all) {
  86                 $params{$_->level} //= [];
  87                 push @{$params{$_->level}}, {$_->get_columns, owner_name => $_->owner->name} ;
  88         }
  89         \%params
  90 }
  91
  92 sub problem_entry {
  93         my ($self, $id, $contest, $user) = @_;
  94         my $running = $contest && $self->contest($contest)->is_running;
  95         my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
  96         push @columns, 'statement';
  97         push @columns, 'solution' unless $running;
  98         my $pb = $self->problems->find($id, {columns => \@columns, prefetch => 'owner'});
  99         my $open;
 100         $open = $self->opens->find_or_create({
 101                 contest => $contest,
 102                 problem => $id,
 103                 owner => $user,
 104                 time => time,
 105         }) if $running;
 106         $contest &&= $self->contest($contest);
 107         +{
 108                 $pb->get_columns,
 109                 owner_name => $pb->owner->name,
 110                 cansubmit => !$contest || !$contest->is_finished,
 111                 $running ? (
 112                         contest_start => $contest->start,
 113                         contest_stop => $contest->stop,
 114                         open_time => $open->time
 115                 ) : (),
 116         }
 117 }
 118
 119 sub contest_list {
 120         my ($self, %args) = @_;
 121         my $rs = $self->contests->search(undef, {order_by => {-desc => 'start'}, prefetch => 'owner'});
 122         $rs = $rs->search({owner => $args{owner}}) if $args{owner};
 123         my %params;
 124         for ($rs->all) {
 125                 my $state = $_->is_pending ? 'pending' : $_->is_running ? 'running' : 'finished';
 126                 $params{$state} //= [];
 127                 push @{$params{$state}}, { $_->get_columns, owner_name => $_->owner->name };
 128         }
 129         \%params
 130 }
 131
 132 sub contest_entry {
 133         my ($self, $id) = @_;
 134         my $ct = $self->contest($id);
 135         +{ $ct->get_columns, started => !$ct->is_pending, owner_name => $ct->owner->name }
 136 }
 137
 138 sub job_list {
 139         my ($self, %args) = @_;
 140         $args{page} //= 1;
 141         my $rs = $self->jobs->search({contest => $args{contest}}, {order_by => {-desc => 'me.id'}, prefetch => ['problem', 'owner'], rows => JOBS_PER_PAGE, page => $args{page}});
 142         $rs = $rs->search({'me.private'=> 0})          unless $args{private};
 143         $rs = $rs->search({'me.owner'  => $args{owner}})   if $args{owner};
 144         $rs = $rs->search({problem     => $args{problem}}) if $args{problem};
 145         return {
 146                 log => [map {
 147                         my %params = $_->get_columns;
 148                         $params{owner_name}   = $_->owner->name;
 149                         $params{problem_name} = $_->problem->name;
 150                         $params{results} &&= decode_json $params{results};
 151                         $params{size}      = length $params{source};
 152                         delete $params{source};
 153                         \%params
 154                 } $rs->all],
 155                 current_page => $rs->pager->current_page,
 156                 maybe previous_page => $rs->pager->previous_page,
 157                 maybe next_page => $rs->pager->next_page,
 158                 maybe last_page => $rs->pager->last_page,
 159         }
 160 }
 161
 162 sub job_entry {
 163         my ($self, $id) = @_;
 164         my $job = $self->jobs->find($id, {prefetch => ['problem', 'owner', 'contest']});
 165         my %params = $job->get_columns;
 166         $params{owner_name}   = $job->owner->name;
 167         $params{problem_name} = $job->problem->name;
 168         $params{contest_name} = $job->contest->name if $params{contest};
 169         $params{results} &&= decode_json $params{results};
 170         $params{size}      = length $params{source};
 171         delete $params{source};
 172         \%params
 173 }
 174
 175 sub update_status {
 176         my ($self) = @_;
 177         my @jobs = $self->jobs->search(undef, {cache => 1})->all;
 178
 179         my %hash;
 180         $hash{$_->get_column('problem'), $_->get_column('owner')} = [$_->id, $_->result ? 0 : 1] for @jobs;
 181         my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;
 182
 183         my @contest_statuses = map {
 184                 my $contest = $_->id;
 185                 map { [$contest, $_->{user}, $_->{score}, $_->{rank}] } $_->standings
 186         } $self->contests->all;
 187
 188         my $txn = sub {
 189                 $self->problem_statuses->delete;
 190                 $self->problem_statuses->populate([[qw/problem owner job solved/], @problem_statuses]);
 191                 $self->contest_statuses->delete;
 192                 $self->contest_statuses->populate([[qw/contest owner score rank/], @contest_statuses]);
 193         };
 194
 195         $self->txn_do($txn);
 196 }
 197
 198 my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
 199 my $ht = HTTP::Tiny->new;
 200
 201 sub purge {
 202         $ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
 203 }
 204
 205 1;
 206
 207 __END__
 208
 209 =encoding utf-8
 210
 211 =head1 NAME
 212
 213 Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools
 214
 215 =head1 SYNOPSIS
 216
 217   my $db = Gruntmaster::Data->connect('dbi:Pg:');
 218
 219   my $problem = $db->problem('my_problem');
 220   $problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
 221   $problem->rerun; # And rerun all jobs for this problem
 222
 223   # ...
 224
 225   my $contest = $db->contests->create({ # Create a new contest
 226     id => 'my_contest',
 227     name => 'My Awesome Contest',
 228     start => time + 100,
 229     end => time + 1900,
 230   });
 231   $db->contest_problems->create({ # Add a problem to the contest
 232     contest => 'my_contest',
 233     problem => 'my_problem',
 234   });
 235
 236   say 'The contest has not started yet' if $contest->is_pending;
 237
 238   # ...
 239
 240   my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
 241   $_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest
 242
 243 =head1 DESCRIPTION
 244
 245 Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.
 246
 247 In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:
 248
 249 =over
 250
 251 =item contests
 252
 253 Equivalent to C<< $schema->resultset('Contest') >>
 254
 255 =item contest_problems
 256
 257 Equivalent to C<< $schema->resultset('ContestProblem') >>
 258
 259 =item jobs
 260
 261 Equivalent to C<< $schema->resultset('Job') >>
 262
 263 =item problems
 264
 265 Equivalent to C<< $schema->resultset('Problem') >>
 266
 267 =item users
 268
 269 Equivalent to C<< $schema->resultset('User') >>
 270
 271 =item contest($id)
 272
 273 Equivalent to C<< $schema->resultset('Contest')->find($id) >>
 274
 275 =item job($id)
 276
 277 Equivalent to C<< $schema->resultset('Job')->find($id) >>
 278
 279 =item problem($id)
 280
 281 Equivalent to C<< $schema->resultset('Problem')->find($id) >>
 282
 283 =item user($id)
 284
 285 Equivalent to C<< $schema->resultset('User')->find($id) >>
 286
 287 =item user_list
 288
 289 Returns a list of users as an arrayref containing hashrefs.
 290
 291 =item user_entry($id)
 292
 293 Returns a hashref with information about the user $id.
 294
 295 =item problem_list([%args])
 296
 297 Returns a list of problems grouped by level. A hashref with levels as keys.
 298
 299 Takes the following arguments:
 300
 301 =over
 302
 303 =item owner
 304
 305 Only show problems owned by this user
 306
 307 =item contest
 308
 309 Only show problems in this contest
 310
 311 =back
 312
 313 =item problem_entry($id, [$contest, $user])
 314
 315 Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.
 316
 317 =item contest_list([%args])
 318
 319 Returns a list of contests grouped by state. A hashref with the following keys:
 320
 321 =over
 322
 323 =item pending
 324
 325 An arrayref of hashrefs representing pending contests
 326
 327 =item running
 328
 329 An arrayref of hashrefs representing running contests
 330
 331 =item finished
 332
 333 An arrayref of hashrefs representing finished contests
 334
 335 =back
 336
 337 Takes the following arguments:
 338
 339 =over
 340
 341 =item owner
 342
 343 Only show contests owned by this user.
 344
 345 =back
 346
 347 =item contest_entry($id)
 348
 349 Returns a hashref with information about the contest $id.
 350
 351 =item job_list([%args])
 352
 353 Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:
 354
 355 =over
 356
 357 =item owner
 358
 359 Only show jobs submitted by this user.
 360
 361 =item contest
 362
 363 Only show jobs submitted in this contest.
 364
 365 =item problem
 366
 367 Only show jobs submitted for this problem.
 368
 369 =item page
 370
 371 Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.
 372
 373 =back
 374
 375 =item job_entry($id)
 376
 377 Returns a hashref with information about the job $id.
 378
 379 =back
 380
 381 =head1 AUTHOR
 382
 383 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
 384
 385 =head1 COPYRIGHT AND LICENSE
 386
 387 Copyright (C) 2014 by Marius Gavrilescu
 388
 389 This library is free software; you can redistribute it and/or modify
 390 it under the same terms as Perl itself, either Perl version 5.18.1 or,
 391 at your option, any later version of Perl 5 you may have available.
 392
 393
 394 =cut