lib/Gruntmaster/Data.pm

   1 package Gruntmaster::Data;
   2 use v5.14;
   3 use warnings;
   4
   5 use parent qw/Exporter/;
   6 our $VERSION = '5999.000_013';
   7 our @EXPORT = qw/purge user_list user_entry problem_list problem_entry contest_list contest_entry contest_full contest_has_problem job_list job_entry job_full create_job standings update_status/; ## no critic (ProhibitAutomaticExportation)
   8
   9 use JSON::MaybeXS qw/decode_json/;
  10 use HTTP::Tiny;
  11 use PerlX::Maybe qw/maybe/;
  12
  13 use DBI;
  14 use DBIx::Simple;
  15 use List::Util qw/sum/;
  16 use SQL::Abstract;
  17
  18 use constant CONTEST_PUBLIC_COLUMNS => [qw/id name description start stop owner/];
  19 use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private timeout olimit value/];
  20 use constant USER_PUBLIC_COLUMNS => [qw/id admin name town university country level/];
  21 use constant JOBS_PER_PAGE => 50;
  22
  23 my %statements = (
  24         user_list_sth => 'SELECT * FROM user_list LIMIT 200',
  25         user_entry_sth => 'SELECT * FROM user_data WHERE id = ?',
  26
  27         problem_status_sth => 'SELECT problem,solved FROM problem_status WHERE owner = ?',
  28         contest_status_sth => 'SELECT contest,score,rank FROM contest_status WHERE owner = ?',
  29
  30         contest_list_sth => 'SELECT * FROM contest_entry',
  31         contest_entry_sth => 'SELECT * FROM contest_entry WHERE id = ?',
  32         contest_full_sth => 'SELECT * FROM contests WHERE id = ?',
  33         contest_problems_sth => 'SELECT problem FROM contest_problems JOIN problems pb ON problem=pb.id WHERE contest = ? ORDER BY pb.value',
  34         contest_has_problem_sth => 'SELECT EXISTS(SELECT 1 FROM contest_problems WHERE contest = ? AND problem = ?)',
  35         opens_sth => 'SELECT problem,owner,time FROM opens WHERE contest = ?',
  36
  37         problem_entry_sth => 'SELECT ' . (join ',', @{PROBLEM_PUBLIC_COLUMNS()}, 'statement', 'solution') . ' FROM problems WHERE id = ?',
  38         limits_sth => 'SELECT format,timeout FROM limits WHERE problem = ?',
  39         problem_values_sth => 'SELECT id,value FROM problems',
  40
  41         job_entry_sth => 'SELECT * FROM job_entry WHERE id = ?',
  42         job_full_sth => 'SELECT * FROM jobs WHERE id = ?',
  43 );
  44
  45 our $db;
  46
  47 sub init {
  48         $db = DBIx::Simple->new(@_);
  49         $db->keep_statements = 100;
  50 };
  51
  52 sub purge;
  53
  54 sub query {
  55         my ($stat, @extra) = @_;
  56         $db->query($statements{$stat} // $stat, @extra)
  57 }
  58
  59 my (%name_cache, %name_cache_time);
  60 use constant NAME_CACHE_MAX_AGE => 5;
  61
  62 sub object_name {
  63         my ($table, $id) = @_;
  64         $name_cache_time{$table} //= 0;
  65         if (time - $name_cache_time{$table} > NAME_CACHE_MAX_AGE) {
  66                 $name_cache_time{$table} = time;
  67                 $name_cache{$table} = {};
  68                 $name_cache{$table} = $db->select($table, 'id,name')->map;
  69         }
  70
  71         $name_cache{$table}{$id}
  72 }
  73
  74
  75 sub add_names ($) {
  76         my ($el) = @_;
  77         if (ref $el eq 'ARRAY') {
  78                 &add_names ($_) for @$el
  79         } else {
  80                 for my $object (qw/contest owner problem/) {
  81                         my $table = $object eq 'owner' ? 'users' : "${object}s";
  82                         $el->{"${object}_name"} = object_name $table, $el->{$object} if defined $el->{$object}
  83                 }
  84         }
  85
  86         $el
  87 }
  88
  89 sub user_list { scalar query('user_list_sth')->hashes }
  90
  91 sub user_entry {
  92         my ($id) = @_;
  93         my $ret = query('user_entry_sth', $id)->hash;
  94         $ret->{problems} = add_names query('problem_status_sth', $id)->hashes;
  95         $ret->{contests} = add_names query('contest_status_sth', $id)->hashes;
  96
  97         $ret;
  98 }
  99
 100 sub problem_list {
 101         my (%args) = @_;
 102         my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
 103         push @columns, 'solution' if $args{solution};
 104         my %where;
 105         $where{private} = 0 unless $args{contest} || $args{private};
 106         $where{'cp.contest'} = $args{contest} if $args{contest};
 107         $where{owner} = $args{owner} if $args{owner};
 108
 109         my $table = $args{contest} ? 'problems JOIN contest_problems cp ON cp.problem = id' : 'problems';
 110         my $ret = add_names $db->select(\$table, \@columns, \%where, 'name')->hashes;
 111
 112         my %params;
 113         for (@$ret) {
 114                 $params{$_->{level}} //= [];
 115                 push @{$params{$_->{level}}}, $_
 116         }
 117         \%params
 118 }
 119
 120 sub problem_entry {
 121         my ($id, $contest, $user) = @_;
 122         $contest &&= contest_entry $contest;
 123         my $ret = add_names query(problem_entry_sth => $id)->hash;
 124         my $limits = query(limits_sth => $id)->hashes;
 125         $ret->{limits} = $limits if @$limits;
 126
 127         if ($contest) {
 128                 $ret->{contest_start} = $contest->{start};
 129                 $ret->{contest_stop}  = $contest->{stop};
 130         }
 131
 132         $ret
 133 }
 134
 135 sub contest_list {
 136         my $ret = add_names query('contest_list_sth')->hashes;
 137
 138         my %ret;
 139         for (@$ret) {
 140                 my $state = $_->{finished} ? 'finished' : $_->{started} ? 'running' : 'pending';
 141                 $ret{$state} //= [];
 142                 push @{$ret{$state}}, $_;
 143         }
 144
 145         \%ret
 146 }
 147
 148 sub contest_entry {
 149         my ($id) = @_;
 150         add_names query(contest_entry_sth => $id)->hash;
 151 }
 152
 153 sub contest_full {
 154         my ($id) = @_;
 155         scalar query(contest_full_sth => $id)->hash;
 156 }
 157
 158 sub contest_has_problem {
 159         my ($contest, $problem) = @_;
 160         query('contest_has_problem_sth', $contest, $problem)->flat
 161 }
 162
 163 sub job_list {
 164         my (%args) = @_;
 165         $args{page} //= 1;
 166         my %where = (
 167                 maybe contest => $args{contest},
 168                 maybe owner => $args{owner},
 169                 maybe problem => $args{problem},
 170                 maybe result => $args{result},
 171         );
 172         $where{private} = 0 unless $args{private};
 173
 174         my $rows = $db->select('job_entry', 'COUNT(*)', \%where)->list;
 175         my $pages = int (($rows + JOBS_PER_PAGE - 1) / JOBS_PER_PAGE);
 176         my ($stmt, @bind) = $db->abstract->select('job_entry', '*', \%where, {-desc => 'id'});
 177         my $jobs = $db->query("$stmt LIMIT " . JOBS_PER_PAGE . ' OFFSET ' . ($args{page} - 1) * JOBS_PER_PAGE, @bind)->hashes;
 178         my %ret = (
 179                 log => add_names $jobs,
 180                 current_page => $args{page},
 181                 last_page    => $pages,
 182         );
 183         $ret{previous_page} = $args{page} - 1 if $args{page} - 1;
 184         $ret{next_page} = $args{page} + 1 if $args{page} < $pages;
 185
 186         \%ret;
 187 }
 188
 189 sub job_entry {
 190         my ($id) = @_;
 191         my $ret = add_names query(job_entry_sth => $id)->hash;
 192         $ret->{results} &&= decode_json $ret->{results};
 193         $ret
 194 }
 195
 196 sub job_full {
 197         my ($id) = @_;
 198         scalar query(job_full_sth => $id)->hash
 199 }
 200
 201 sub create_job {
 202         my (%args) = @_;
 203         $db->update('users', {lastjob => time});
 204         purge '/log/';
 205         scalar $db->insert('jobs', \%args, {returning => 'id'})->list
 206 }
 207
 208 sub calc_score {
 209         my ($mxscore, $time, $tries, $totaltime) = @_;
 210         my $score = $mxscore;
 211         $time = 0 if $time < 0;
 212         $time = 300 if $time > $totaltime;
 213         $score = ($totaltime - $time) / $totaltime * $score;
 214         $score -= $tries / 10 * $mxscore;
 215         $score = $mxscore * 3 / 10 if $score < $mxscore * 3 / 10;
 216         int $score + 0.5
 217 }
 218
 219 sub standings {
 220         my ($ct) = @_;
 221         $ct = contest_entry $ct;
 222
 223         my @problems = query(contest_problems_sth => $ct->{id})->flat;
 224         my $pblist = problem_list;
 225         my %values = query('problem_values_sth')->map;
 226 #       $values{$_} = $values{$_}->{value} for keys %values;
 227
 228         my (%scores, %tries, %opens);
 229         my $opens = query(opens_sth => $ct->{id});
 230         while ($opens->into(my ($problem, $owner, $time))) {
 231                 $opens{$problem, $owner} = $time;
 232         }
 233
 234         my $jobs = $db->select('job_entry', '*', {contest => $ct->{id}}, 'id');
 235
 236         while (my $job = $jobs->hash) {
 237                 my $open = $opens{$job->{problem}, $job->{owner}} // $ct->{start};
 238                 my $time = $job->{date} - $open;
 239                 next if $time < 0;
 240                 my $value = $values{$job->{problem}};
 241                 my $factor = $job->{result} ? 0 : 1;
 242                 $factor = $1 / 100 if $job->{result_text} =~ /^(\d+ )/s;
 243                 $scores{$job->{owner}}{$job->{problem}} = int ($factor * calc_score ($value, $time, $tries{$job->{owner}}{$job->{problem}}++, $ct->{stop} - $ct->{start}));
 244         }
 245
 246         my @st = sort { $b->{score} <=> $a->{score} or $a->{user} cmp $b->{user} } map { ## no critic (ProhibitReverseSortBlock)
 247                 my $user = $_;
 248                 +{
 249                         user => $user,
 250                         user_name => object_name(users => $user),
 251                         score => sum (values %{$scores{$user}}),
 252                         scores => [map { $scores{$user}{$_} // '-'} @problems],
 253                 }
 254         } keys %scores;
 255
 256         $st[0]->{rank} = 1 if @st;
 257         $st[$_]->{rank} = $st[$_ - 1]->{rank} + ($st[$_]->{score} < $st[$_ - 1]->{score}) for 1 .. $#st;
 258         +{
 259                 st => \@st,
 260                 problems => [map { [ $_, object_name(problems => $_)] } @problems],
 261         }
 262 }
 263
 264 sub update_status {
 265         my $jobs = $db->select('jobs', 'id,owner,problem,result', {}, 'id');
 266
 267         my %hash;
 268         while ($jobs->into(my ($id, $owner, $problem, $result))) {
 269                 $hash{$problem, $owner} = [$id, $result ? 0 : 1];
 270         }
 271
 272         my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;
 273
 274         my @contest_statuses = map {
 275                 my $ct = $_;
 276                 map { [$ct, $_->{user}, $_->{score}, $_->{rank}] } @{standings($ct)->{st}}
 277         } $db->select('contests', 'id')->flat;
 278
 279         $db->begin;
 280         $db->delete('problem_status');
 281         $db->query('INSERT INTO problem_status (problem,owner,job,solved) VALUES (??)', @$_) for @problem_statuses;
 282         $db->delete('contest_status');
 283         $db->query('INSERT INTO contest_status (contest,owner,score,rank) VALUES (??)', @$_) for @contest_statuses;
 284         $db->commit
 285 }
 286
 287 my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
 288 my $ht = HTTP::Tiny->new;
 289
 290 sub purge {
 291         $ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
 292 }
 293
 294 1;
 295
 296 __END__
 297
 298 =encoding utf-8
 299
 300 =head1 NAME
 301
 302 Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools
 303
 304 =head1 SYNOPSIS
 305
 306   my $db = Gruntmaster::Data->connect('dbi:Pg:');
 307
 308   my $problem = $db->problem('my_problem');
 309   $problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
 310   $problem->rerun; # And rerun all jobs for this problem
 311
 312   # ...
 313
 314   my $contest = $db->contests->create({ # Create a new contest
 315     id => 'my_contest',
 316     name => 'My Awesome Contest',
 317     start => time + 100,
 318     end => time + 1900,
 319   });
 320   $db->contest_problems->create({ # Add a problem to the contest
 321     contest => 'my_contest',
 322     problem => 'my_problem',
 323   });
 324
 325   say 'The contest has not started yet' if $contest->is_pending;
 326
 327   # ...
 328
 329   my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
 330   $_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest
 331
 332 =head1 DESCRIPTION
 333
 334 Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.
 335
 336 In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:
 337
 338 =over
 339
 340 =item contests
 341
 342 Equivalent to C<< $schema->resultset('Contest') >>
 343
 344 =item contest_problems
 345
 346 Equivalent to C<< $schema->resultset('ContestProblem') >>
 347
 348 =item jobs
 349
 350 Equivalent to C<< $schema->resultset('Job') >>
 351
 352 =item problems
 353
 354 Equivalent to C<< $schema->resultset('Problem') >>
 355
 356 =item users
 357
 358 Equivalent to C<< $schema->resultset('User') >>
 359
 360 =item contest($id)
 361
 362 Equivalent to C<< $schema->resultset('Contest')->find($id) >>
 363
 364 =item job($id)
 365
 366 Equivalent to C<< $schema->resultset('Job')->find($id) >>
 367
 368 =item problem($id)
 369
 370 Equivalent to C<< $schema->resultset('Problem')->find($id) >>
 371
 372 =item user($id)
 373
 374 Equivalent to C<< $schema->resultset('User')->find($id) >>
 375
 376 =item user_list
 377
 378 Returns a list of users as an arrayref containing hashrefs.
 379
 380 =item user_entry($id)
 381
 382 Returns a hashref with information about the user $id.
 383
 384 =item problem_list([%args])
 385
 386 Returns a list of problems grouped by level. A hashref with levels as keys.
 387
 388 Takes the following arguments:
 389
 390 =over
 391
 392 =item owner
 393
 394 Only show problems owned by this user
 395
 396 =item contest
 397
 398 Only show problems in this contest
 399
 400 =back
 401
 402 =item problem_entry($id, [$contest, $user])
 403
 404 Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.
 405
 406 =item contest_list([%args])
 407
 408 Returns a list of contests grouped by state. A hashref with the following keys:
 409
 410 =over
 411
 412 =item pending
 413
 414 An arrayref of hashrefs representing pending contests
 415
 416 =item running
 417
 418 An arrayref of hashrefs representing running contests
 419
 420 =item finished
 421
 422 An arrayref of hashrefs representing finished contests
 423
 424 =back
 425
 426 Takes the following arguments:
 427
 428 =over
 429
 430 =item owner
 431
 432 Only show contests owned by this user.
 433
 434 =back
 435
 436 =item contest_entry($id)
 437
 438 Returns a hashref with information about the contest $id.
 439
 440 =item job_list([%args])
 441
 442 Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:
 443
 444 =over
 445
 446 =item owner
 447
 448 Only show jobs submitted by this user.
 449
 450 =item contest
 451
 452 Only show jobs submitted in this contest.
 453
 454 =item problem
 455
 456 Only show jobs submitted for this problem.
 457
 458 =item page
 459
 460 Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.
 461
 462 =back
 463
 464 =item job_entry($id)
 465
 466 Returns a hashref with information about the job $id.
 467
 468 =back
 469
 470 =head1 AUTHOR
 471
 472 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
 473
 474 =head1 COPYRIGHT AND LICENSE
 475
 476 Copyright (C) 2014 by Marius Gavrilescu
 477
 478 This library is free software; you can redistribute it and/or modify
 479 it under the same terms as Perl itself, either Perl version 5.18.1 or,
 480 at your option, any later version of Perl 5 you may have available.
 481
 482
 483 =cut