lib/Gruntmaster/Data.pm

   1 use utf8;
   2 package Gruntmaster::Data;
   3
   4 # Created by DBIx::Class::Schema::Loader
   5 # DO NOT MODIFY THE FIRST PART OF THIS FILE
   6
   7 use strict;
   8 use warnings;
   9
  10 use base 'DBIx::Class::Schema';
  11
  12 __PACKAGE__->load_namespaces;
  13
  14
  15 # Created by DBIx::Class::Schema::Loader v0.07039 @ 2014-03-05 13:11:39
  16 # DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:dAEmtAexvUaNXLgYz2rNEg
  17
  18 our $VERSION = '5999.000_011';
  19
  20 use Lingua::EN::Inflect qw/PL_N/;
  21 use JSON::MaybeXS qw/decode_json/;
  22 use PerlX::Maybe qw/maybe/;
  23 use Sub::Name qw/subname/;
  24
  25 use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private statement timeout olimit value/];
  26 use constant USER_PUBLIC_COLUMNS => [qw/id admin name town university level/];
  27 use constant JOBS_PER_PAGE => 10;
  28
  29 sub dynsub{
  30         our ($name, $sub) = @_;
  31         no strict 'refs'; ## no critic (Strict)
  32         *$name = subname $name => $sub
  33 }
  34
  35 BEGIN {
  36         for my $rs (qw/contest contest_problem job open problem user problem_status contest_status/) {
  37                 my $rsname = ucfirst $rs;
  38                 $rsname =~ s/_([a-z])/\u$1/gs;
  39                 dynsub PL_N($rs) => sub { $_[0]->resultset($rsname)              };
  40                 dynsub      $rs  => sub { $_[0]->resultset($rsname)->find($_[1]) };
  41         }
  42 }
  43
  44 sub user_list {
  45         my $rs = $_[0]->users->search(undef, {order_by => 'name', columns => USER_PUBLIC_COLUMNS});
  46         [ map { { $_->get_columns } } $rs->all ]
  47 }
  48
  49 sub user_entry {
  50         my ($self, $id) = @_;
  51         my $user = $self->users->find($id, {columns => USER_PUBLIC_COLUMNS, prefetch => [qw/problem_statuses contest_statuses/]});
  52         my @problems = map { {problem => $_->get_column('problem'), solved => $_->solved} } $user->problem_statuses;
  53         my @contests = map { {contest => $_->contest->id, contest_name => $_->contest->name, rank => $_->rank, score => $_->score} } $user->contest_statuses->search(undef, {prefetch => 'contest'});
  54         +{ $user->get_columns, problems => \@problems, contests => \@contests }
  55 }
  56
  57 sub problem_list {
  58         my ($self, %args) = @_;
  59         my $rs = $self->problems->search(undef, {order_by => 'me.name', columns => PROBLEM_PUBLIC_COLUMNS, prefetch => 'owner'});
  60         $rs = $rs->search({-or => ['contest_problems.contest' => undef, 'contest.stop' => {'<=', time}], 'me.private' => 0}, {join => {'contest_problems' => 'contest'}, distinct => 1}) unless $args{contest};
  61         $rs = $rs->search({'contest_problems.contest' => $args{contest}}, {join => 'contest_problems'}) if $args{contest};
  62         $rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
  63         my %params;
  64         $params{contest} = $args{contest} if $args{contest};
  65         for ($rs->all) {
  66                 $params{$_->level} //= [];
  67                 push @{$params{$_->level}}, {$_->get_columns, owner_name => $_->owner->name} ;
  68         }
  69         \%params
  70 }
  71
  72 sub problem_entry {
  73         my ($self, $id, $contest, $user) = @_;
  74         my $running = $contest && $self->contest($contest)->is_running;
  75         my $columns = PROBLEM_PUBLIC_COLUMNS;
  76         push @$columns, 'solution' unless $running;
  77         my $pb = $self->problems->find($id, {columns => $columns, prefetch => 'owner'});
  78         eval { ## no critic (RequireCheckingReturnValueOfEval)
  79                 $self->opens->create({
  80                         contest => $contest,
  81                         problem => $id,
  82                         owner => $user,
  83                         time => time,
  84                 })
  85         } if $running;
  86         $contest &&= $self->contest($contest);
  87         +{ $pb->get_columns, owner_name => $pb->owner->name, cansubmit => $contest ? $running : 1, $running ? (contest_start => $contest->start, contest_stop => $contest->stop) : () }
  88 }
  89
  90 sub contest_list {
  91         my ($self, %args) = @_;
  92         my $rs = $self->contests->search(undef, {order_by => {-desc => 'start'}, prefetch => 'owner'});
  93         $rs = $rs->search({owner => $args{owner}}) if $args{owner};
  94         my %params;
  95         for ($rs->all) {
  96                 my $state = $_->is_pending ? 'pending' : $_->is_running ? 'running' : 'finished';
  97                 $params{$state} //= [];
  98                 push @{$params{$state}}, { $_->get_columns, started => !$_->is_pending, owner_name => $_->owner->name };
  99         }
 100         \%params
 101 }
 102
 103 sub contest_entry {
 104         my ($self, $id) = @_;
 105         my $ct = $self->contest($id);
 106         +{ $ct->get_columns, started => !$ct->is_pending, owner_name => $ct->owner->name }
 107 }
 108
 109 sub job_list {
 110         my ($self, %args) = @_;
 111         $args{page} //= 1;
 112         my $rs = $self->jobs->search(undef, {order_by => {-desc => 'me.id'}, prefetch => ['problem', 'owner'], rows => JOBS_PER_PAGE, page => $args{page}});
 113         $rs = $rs->search({'me.owner' => $args{owner}})   if $args{owner};
 114         $rs = $rs->search({contest    => $args{contest}}) if $args{contest};
 115         $rs = $rs->search({problem    => $args{problem}}) if $args{problem};
 116         return {
 117                 log => [map {
 118                         my %params = $_->get_columns;
 119                         $params{owner_name}   = $_->owner->name;
 120                         $params{problem_name} = $_->problem->name;
 121                         $params{results} &&= decode_json $params{results};
 122                         $params{size}      = length $params{source};
 123                         delete $params{source};
 124                         \%params
 125                 } $rs->all],
 126                 current_page => $rs->pager->current_page,
 127                 maybe previous_page => $rs->pager->previous_page,
 128                 maybe next_page => $rs->pager->next_page,
 129                 maybe last_page => $rs->pager->last_page,
 130         }
 131 }
 132
 133 sub job_entry {
 134         my ($self, $id) = @_;
 135         my $job = $self->jobs->find($id, {prefetch => ['problem', 'owner']});
 136         my %params = $job->get_columns;
 137         $params{owner_name}   = $job->owner->name;
 138         $params{problem_name} = $job->problem->name;
 139         $params{results} &&= decode_json $params{results};
 140         $params{size}      = length $params{source};
 141         delete $params{source};
 142         \%params
 143 }
 144
 145 sub update_status {
 146         my ($self) = @_;
 147         my @jobs = $self->jobs->search(undef, {cache => 1})->all;
 148
 149         my %hash;
 150         $hash{$_->get_column('problem'), $_->get_column('owner')} = [$_->id, $_->result ? 0 : 1] for @jobs;
 151         my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;
 152
 153         my @contest_statuses = map {
 154                 my $contest = $_->id;
 155                 map { [$contest, $_->{user}, $_->{score}, $_->{rank}] } $_->standings
 156         } $self->contests->all;
 157
 158         my $txn = sub {
 159                 $self->problem_statuses->delete;
 160                 $self->problem_statuses->populate([[qw/problem owner job solved/], @problem_statuses]);
 161                 $self->contest_statuses->delete;
 162                 $self->contest_statuses->populate([[qw/contest owner score rank/], @contest_statuses]);
 163         };
 164
 165         $self->txn_do($txn);
 166 }
 167
 168 1;
 169
 170 __END__
 171
 172 =encoding utf-8
 173
 174 =head1 NAME
 175
 176 Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools
 177
 178 =head1 SYNOPSIS
 179
 180   my $db = Gruntmaster::Data->connect('dbi:Pg:');
 181
 182   my $problem = $db->problem('my_problem');
 183   $problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
 184   $problem->rerun; # And rerun all jobs for this problem
 185
 186   # ...
 187
 188   my $contest = $db->contests->create({ # Create a new contest
 189     id => 'my_contest',
 190     name => 'My Awesome Contest',
 191     start => time + 100,
 192     end => time + 1900,
 193   });
 194   $db->contest_problems->create({ # Add a problem to the contest
 195     contest => 'my_contest',
 196     problem => 'my_problem',
 197   });
 198
 199   say 'The contest has not started yet' if $contest->is_pending;
 200
 201   # ...
 202
 203   my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
 204   $_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest
 205
 206 =head1 DESCRIPTION
 207
 208 Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.
 209
 210 In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:
 211
 212 =over
 213
 214 =item contests
 215
 216 Equivalent to C<< $schema->resultset('Contest') >>
 217
 218 =item contest_problems
 219
 220 Equivalent to C<< $schema->resultset('ContestProblem') >>
 221
 222 =item jobs
 223
 224 Equivalent to C<< $schema->resultset('Job') >>
 225
 226 =item problems
 227
 228 Equivalent to C<< $schema->resultset('Problem') >>
 229
 230 =item users
 231
 232 Equivalent to C<< $schema->resultset('User') >>
 233
 234 =item contest($id)
 235
 236 Equivalent to C<< $schema->resultset('Contest')->find($id) >>
 237
 238 =item job($id)
 239
 240 Equivalent to C<< $schema->resultset('Job')->find($id) >>
 241
 242 =item problem($id)
 243
 244 Equivalent to C<< $schema->resultset('Problem')->find($id) >>
 245
 246 =item user($id)
 247
 248 Equivalent to C<< $schema->resultset('User')->find($id) >>
 249
 250 =item user_list
 251
 252 Returns a list of users as an arrayref containing hashrefs.
 253
 254 =item user_entry($id)
 255
 256 Returns a hashref with information about the user $id.
 257
 258 =item problem_list([%args])
 259
 260 Returns a list of problems grouped by level. A hashref with levels as keys.
 261
 262 Takes the following arguments:
 263
 264 =over
 265
 266 =item owner
 267
 268 Only show problems owned by this user
 269
 270 =item contest
 271
 272 Only show problems in this contest
 273
 274 =back
 275
 276 =item problem_entry($id, [$contest, $user])
 277
 278 Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.
 279
 280 =item contest_list([%args])
 281
 282 Returns a list of contests grouped by state. A hashref with the following keys:
 283
 284 =over
 285
 286 =item pending
 287
 288 An arrayref of hashrefs representing pending contests
 289
 290 =item running
 291
 292 An arrayref of hashrefs representing running contests
 293
 294 =item finished
 295
 296 An arrayref of hashrefs representing finished contests
 297
 298 =back
 299
 300 Takes the following arguments:
 301
 302 =over
 303
 304 =item owner
 305
 306 Only show contests owned by this user.
 307
 308 =back
 309
 310 =item contest_entry($id)
 311
 312 Returns a hashref with information about the contest $id.
 313
 314 =item job_list([%args])
 315
 316 Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:
 317
 318 =over
 319
 320 =item owner
 321
 322 Only show jobs submitted by this user.
 323
 324 =item contest
 325
 326 Only show jobs submitted in this contest.
 327
 328 =item problem
 329
 330 Only show jobs submitted for this problem.
 331
 332 =item page
 333
 334 Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.
 335
 336 =back
 337
 338 =item job_entry($id)
 339
 340 Returns a hashref with information about the job $id.
 341
 342 =back
 343
 344 =head1 AUTHOR
 345
 346 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
 347
 348 =head1 COPYRIGHT AND LICENSE
 349
 350 Copyright (C) 2014 by Marius Gavrilescu
 351
 352 This library is free software; you can redistribute it and/or modify
 353 it under the same terms as Perl itself, either Perl version 5.18.1 or,
 354 at your option, any later version of Perl 5 you may have available.
 355
 356
 357 =cut