lib/Gruntmaster/Data.pm

   1 use utf8;
   2 package Gruntmaster::Data;
   3
   4 # Created by DBIx::Class::Schema::Loader
   5 # DO NOT MODIFY THE FIRST PART OF THIS FILE
   6
   7 use strict;
   8 use warnings;
   9
  10 use base 'DBIx::Class::Schema';
  11
  12 __PACKAGE__->load_namespaces;
  13
  14
  15 # Created by DBIx::Class::Schema::Loader v0.07039 @ 2014-03-05 13:11:39
  16 # DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:dAEmtAexvUaNXLgYz2rNEg
  17
  18 our $VERSION = '5999.000_011';
  19
  20 use Lingua::EN::Inflect qw/PL_N/;
  21 use JSON::MaybeXS qw/decode_json/;
  22 use List::Util qw/sum/;
  23 use PerlX::Maybe qw/maybe/;
  24 use Sub::Name qw/subname/;
  25
  26 use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private statement timeout olimit value/];
  27 use constant USER_PUBLIC_COLUMNS => [qw/id admin name town university level/];
  28 use constant JOBS_PER_PAGE => 10;
  29
  30 sub dynsub{
  31         our ($name, $sub) = @_;
  32         no strict 'refs'; ## no critic (Strict)
  33         *$name = subname $name => $sub
  34 }
  35
  36 BEGIN {
  37         for my $rs (qw/contest contest_problem job open problem user problem_status contest_status/) {
  38                 my $rsname = ucfirst $rs;
  39                 $rsname =~ s/_([a-z])/\u$1/gs;
  40                 dynsub PL_N($rs) => sub { $_[0]->resultset($rsname)              };
  41                 dynsub      $rs  => sub { $_[0]->resultset($rsname)->find($_[1]) };
  42         }
  43 }
  44
  45 sub calc_score{
  46         my ($mxscore, $time, $tries, $totaltime) = @_;
  47         my $score = $mxscore;
  48         $time = 0 if $time < 0;
  49         $time = 300 if $time > $totaltime;
  50         $score = ($totaltime - $time) / $totaltime * $score;
  51         $score -= $tries / 10 * $mxscore;
  52         $score = $mxscore * 3 / 10 if $score < $mxscore * 3 / 10;
  53         int $score + 0.5
  54 }
  55
  56 sub standings {
  57         my ($self, $ct) = @_;
  58         $ct &&= $self->contest($ct);
  59
  60         my @problems = map { $_->problem } $self->contest_problems->search({contest => $ct && $ct->id}, {qw/join problem order_by problem.level/});
  61         my (%scores, %tries);
  62         for my $job ($self->jobs->search({contest => $ct && $ct->id}, {order_by => 'id'})) {
  63                 if ($ct) {
  64                         my $open = $self->opens->find($ct->id, $job->problem->id, $job->owner->id);
  65                         my $time = $job->date - ($open ? $open->time : $ct->start);
  66                         next if $time < 0;
  67                         my $value = $job->problem->value;
  68                         my $factor = $job->result ? 0 : 1;
  69                         $factor = $1 / 100 if $job->result_text =~ /^(\d+ )/s;
  70                         $scores{$job->owner->id}{$job->problem->id} = int ($factor * calc_score ($value, $time, $tries{$job->owner->id}{$job->problem->id}++, $ct->stop - $ct->start));
  71                 } else {
  72                         no warnings 'numeric'; ## no critic (ProhibitNoWarnings)
  73                         $scores{$job->owner->id}{$job->problem->id} = 0 + $job->result_text || ($job->result ? 0 : 100)
  74                 }
  75         }
  76
  77         my @st = sort { $b->{score} <=> $a->{score} or $a->{user}->id cmp $b->{user}->id} map { ## no critic (ProhibitReverseSortBlock)
  78                 my $user = $_;
  79                 +{
  80                         user => $self->user($user),
  81                         score => sum (values %{$scores{$user}}),
  82                         scores => [map { $scores{$user}{$_->id} // '-'} @problems],
  83                         problems => $ct,
  84                 }
  85         } keys %scores;
  86
  87         $st[0]->{rank} = 1;
  88         $st[$_]->{rank} = $st[$_ - 1]->{rank} + ($st[$_]->{score} < $st[$_ - 1]->{score}) for 1 .. $#st;
  89         @st
  90 }
  91
  92 sub user_list {
  93         my $rs = $_[0]->users->search(undef, {order_by => 'name', columns => USER_PUBLIC_COLUMNS});
  94         [ map { { $_->get_columns } } $rs->all ]
  95 }
  96
  97 sub user_entry {
  98         my ($self, $id) = @_;
  99         my $user = $self->users->find($id, {columns => USER_PUBLIC_COLUMNS, prefetch => [qw/problem_statuses contest_statuses/]});
 100         my @problems = map { {problem => $_->get_column('problem'), solved => $_->solved} } $user->problem_statuses;
 101         my @contests = map { {contest => $_->get_column('contest'), rank => $_->rank, score => $_->score} } $user->contest_statuses;
 102         +{ $user->get_columns, problems => \@problems, contests => \@contests }
 103 }
 104
 105 sub problem_list {
 106         my ($self, %args) = @_;
 107         my $rs = $self->problems->search(undef, {order_by => 'me.name', columns => PROBLEM_PUBLIC_COLUMNS, prefetch => 'owner'});
 108         $rs = $rs->search({-or => ['contest_problems.contest' => undef, 'contest.stop' => {'<=', time}], 'me.private' => 0}, {join => {'contest_problems' => 'contest'}, distinct => 1}) unless $args{contest};
 109         $rs = $rs->search({'contest_problems.contest' => $args{contest}}, {join => 'contest_problems'}) if $args{contest};
 110         $rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
 111         my %params;
 112         $params{contest} = $args{contest} if $args{contest};
 113         for ($rs->all) {
 114                 $params{$_->level} //= [];
 115                 push @{$params{$_->level}}, {$_->get_columns, owner_name => $_->owner->name} ;
 116         }
 117         \%params
 118 }
 119
 120 sub problem_entry {
 121         my ($self, $id, $contest, $user) = @_;
 122         my $running = $contest && $self->contest($contest)->is_running;
 123         my $columns = PROBLEM_PUBLIC_COLUMNS;
 124         push @$columns, 'solution' unless $running;
 125         my $pb = $self->problems->find($id, {columns => $columns, prefetch => 'owner'});
 126         eval { ## no critic (RequireCheckingReturnValueOfEval)
 127                 $self->opens->create({
 128                         contest => $contest,
 129                         problem => $id,
 130                         owner => $user,
 131                         time => time,
 132                 })
 133         } if $running;
 134         $contest &&= $self->contest($contest);
 135         +{ $pb->get_columns, owner_name => $pb->owner->name, cansubmit => $contest ? $running : 1, $running ? (contest_start => $contest->start, contest_stop => $contest->stop) : () }
 136 }
 137
 138 sub contest_list {
 139         my ($self, %args) = @_;
 140         my $rs = $self->contests->search(undef, {order_by => {-desc => 'start'}, prefetch => 'owner'});
 141         $rs = $rs->search({owner => $args{owner}}) if $args{owner};
 142         my %params;
 143         for ($rs->all) {
 144                 my $state = $_->is_pending ? 'pending' : $_->is_running ? 'running' : 'finished';
 145                 $params{$state} //= [];
 146                 push @{$params{$state}}, { $_->get_columns, started => !$_->is_pending, owner_name => $_->owner->name };
 147         }
 148         \%params
 149 }
 150
 151 sub contest_entry {
 152         my ($self, $id) = @_;
 153         my $ct = $self->contest($id);
 154         +{ $ct->get_columns, started => !$ct->is_pending, owner_name => $ct->owner->name }
 155 }
 156
 157 sub job_list {
 158         my ($self, %args) = @_;
 159         $args{page} //= 1;
 160         my $rs = $self->jobs->search(undef, {order_by => {-desc => 'me.id'}, prefetch => ['problem', 'owner'], rows => JOBS_PER_PAGE, page => $args{page}});
 161         $rs = $rs->search({'me.owner' => $args{owner}})   if $args{owner};
 162         $rs = $rs->search({contest    => $args{contest}}) if $args{contest};
 163         $rs = $rs->search({problem    => $args{problem}}) if $args{problem};
 164         return {
 165                 log => [map {
 166                         my %params = $_->get_columns;
 167                         $params{owner_name}   = $_->owner->name;
 168                         $params{problem_name} = $_->problem->name;
 169                         $params{results} &&= decode_json $params{results};
 170                         $params{size}      = length $params{source};
 171                         delete $params{source};
 172                         \%params
 173                 } $rs->all],
 174                 current_page => $rs->pager->current_page,
 175                 maybe previous_page => $rs->pager->previous_page,
 176                 maybe next_page => $rs->pager->next_page,
 177                 maybe last_page => $rs->pager->last_page,
 178         }
 179 }
 180
 181 sub job_entry {
 182         my ($self, $id) = @_;
 183         my $job = $self->jobs->find($id, {prefetch => ['problem', 'owner']});
 184         my %params = $job->get_columns;
 185         $params{owner_name}   = $job->owner->name;
 186         $params{problem_name} = $job->problem->name;
 187         $params{results} &&= decode_json $params{results};
 188         $params{size}      = length $params{source};
 189         delete $params{source};
 190         \%params
 191 }
 192
 193 sub update_status {
 194         my ($self) = @_;
 195         my @jobs = $self->jobs->search(undef, {cache => 1})->all;
 196         my %hash;
 197         $hash{$_->get_column('problem'), $_->get_column('owner')} = [$_, $_->result ? 1 : 0] for @jobs;
 198         my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;
 199
 200         my @contest_statuses = map {
 201                 my $contest = $_->id;
 202                 my @standings = $self->standings($contest);
 203                 map { [$contest, $_->{user}, $_->{score}, $_->{rank}] } @standings;
 204         } $self->contests->all;
 205
 206         my $txn = sub {
 207                 $self->problem_statuses->delete;
 208                 $self->problem_statuses->populate([[qw/problem owner job solved/], @problem_statuses]);
 209                 $self->contest_statuses->delete;
 210                 $self->contest_statuses->populate([[qw/contest owner score rank/], @contest_statuses]);
 211         };
 212
 213         $self->txn_do($txn);
 214 }
 215
 216 1;
 217
 218 __END__
 219
 220 =encoding utf-8
 221
 222 =head1 NAME
 223
 224 Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools
 225
 226 =head1 SYNOPSIS
 227
 228   my $db = Gruntmaster::Data->connect('dbi:Pg:');
 229
 230   my $problem = $db->problem('my_problem');
 231   $problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
 232   $problem->rerun; # And rerun all jobs for this problem
 233
 234   # ...
 235
 236   my $contest = $db->contests->create({ # Create a new contest
 237     id => 'my_contest',
 238     name => 'My Awesome Contest',
 239     start => time + 100,
 240     end => time + 1900,
 241   });
 242   $db->contest_problems->create({ # Add a problem to the contest
 243     contest => 'my_contest',
 244     problem => 'my_problem',
 245   });
 246
 247   say 'The contest has not started yet' if $contest->is_pending;
 248
 249   # ...
 250
 251   my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
 252   $_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest
 253
 254 =head1 DESCRIPTION
 255
 256 Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.
 257
 258 In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:
 259
 260 =over
 261
 262 =item contests
 263
 264 Equivalent to C<< $schema->resultset('Contest') >>
 265
 266 =item contest_problems
 267
 268 Equivalent to C<< $schema->resultset('ContestProblem') >>
 269
 270 =item jobs
 271
 272 Equivalent to C<< $schema->resultset('Job') >>
 273
 274 =item problems
 275
 276 Equivalent to C<< $schema->resultset('Problem') >>
 277
 278 =item users
 279
 280 Equivalent to C<< $schema->resultset('User') >>
 281
 282 =item contest($id)
 283
 284 Equivalent to C<< $schema->resultset('Contest')->find($id) >>
 285
 286 =item job($id)
 287
 288 Equivalent to C<< $schema->resultset('Job')->find($id) >>
 289
 290 =item problem($id)
 291
 292 Equivalent to C<< $schema->resultset('Problem')->find($id) >>
 293
 294 =item user($id)
 295
 296 Equivalent to C<< $schema->resultset('User')->find($id) >>
 297
 298 =item user_list
 299
 300 Returns a list of users as an arrayref containing hashrefs.
 301
 302 =item user_entry($id)
 303
 304 Returns a hashref with information about the user $id.
 305
 306 =item problem_list([%args])
 307
 308 Returns a list of problems grouped by level. A hashref with levels as keys.
 309
 310 Takes the following arguments:
 311
 312 =over
 313
 314 =item owner
 315
 316 Only show problems owned by this user
 317
 318 =item contest
 319
 320 Only show problems in this contest
 321
 322 =back
 323
 324 =item problem_entry($id, [$contest, $user])
 325
 326 Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.
 327
 328 =item contest_list([%args])
 329
 330 Returns a list of contests grouped by state. A hashref with the following keys:
 331
 332 =over
 333
 334 =item pending
 335
 336 An arrayref of hashrefs representing pending contests
 337
 338 =item running
 339
 340 An arrayref of hashrefs representing running contests
 341
 342 =item finished
 343
 344 An arrayref of hashrefs representing finished contests
 345
 346 =back
 347
 348 Takes the following arguments:
 349
 350 =over
 351
 352 =item owner
 353
 354 Only show contests owned by this user.
 355
 356 =back
 357
 358 =item contest_entry($id)
 359
 360 Returns a hashref with information about the contest $id.
 361
 362 =item job_list([%args])
 363
 364 Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:
 365
 366 =over
 367
 368 =item owner
 369
 370 Only show jobs submitted by this user.
 371
 372 =item contest
 373
 374 Only show jobs submitted in this contest.
 375
 376 =item problem
 377
 378 Only show jobs submitted for this problem.
 379
 380 =item page
 381
 382 Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.
 383
 384 =back
 385
 386 =item job_entry($id)
 387
 388 Returns a hashref with information about the job $id.
 389
 390 =back
 391
 392 =head1 AUTHOR
 393
 394 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
 395
 396 =head1 COPYRIGHT AND LICENSE
 397
 398 Copyright (C) 2014 by Marius Gavrilescu
 399
 400 This library is free software; you can redistribute it and/or modify
 401 it under the same terms as Perl itself, either Perl version 5.18.1 or,
 402 at your option, any later version of Perl 5 you may have available.
 403
 404
 405 =cut