lib/Gruntmaster/Data.pm

   1 package Gruntmaster::Data;
   2 use 5.014;
   3 use warnings;
   4
   5 use parent qw/Exporter/;
   6 our $VERSION = '5999.000_013';
   7 our @EXPORT = qw/purge db user_list user_entry problem_list problem_entry contest_list contest_entry contest_has_problem job_list job_entry create_job standings update_status rerun_job take_job finish_job/; ## no critic (ProhibitAutomaticExportation)
   8
   9 use JSON::MaybeXS qw/decode_json/;
  10 use HTTP::Tiny;
  11 use PerlX::Maybe qw/maybe/;
  12
  13 use DBI;
  14 use DBIx::Simple;
  15 use List::Util qw/sum/;
  16 use SQL::Abstract;
  17
  18 use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private timeout olimit value/];
  19 use constant JOBS_PER_PAGE => 50;
  20
  21 my %statements = (
  22         user_list_sth => 'SELECT * FROM user_list LIMIT 200',
  23         user_entry_sth => 'SELECT * FROM user_data WHERE id = ?',
  24
  25         problem_status_sth => 'SELECT problem,solved FROM problem_status WHERE owner = ?',
  26         contest_status_sth => 'SELECT contest,score,rank FROM contest_status WHERE owner = ?',
  27
  28         contest_list_sth => 'SELECT * FROM contest_entry',
  29         contest_entry_sth => 'SELECT * FROM contest_entry WHERE id = ?',
  30         contest_problems_sth => 'SELECT problem FROM contest_problems JOIN problems pb ON problem=pb.id WHERE contest = ? ORDER BY pb.value',
  31         contest_has_problem_sth => 'SELECT EXISTS(SELECT 1 FROM contest_problems WHERE contest = ? AND problem = ?)',
  32         opens_sth => 'SELECT problem,owner,time FROM opens WHERE contest = ?',
  33
  34         problem_entry_sth => 'SELECT ' . (join ',', @{PROBLEM_PUBLIC_COLUMNS()}, 'statement', 'solution') . ' FROM problems WHERE id = ?',
  35         limits_sth => 'SELECT format,timeout FROM limits WHERE problem = ?',
  36         problem_values_sth => 'SELECT id,value FROM problems',
  37
  38         job_entry_sth => 'SELECT * FROM job_entry WHERE id = ?',
  39
  40         rerun_job_sth => 'UPDATE jobs SET daemon=NULL,result=-2,result_text=NULL,results=NULL,errors=NULL WHERE id = ?',
  41         take_job_sth => 'UPDATE jobs SET daemon=? WHERE id = (SELECT id FROM jobs WHERE daemon IS NULL LIMIT 1 FOR UPDATE) RETURNING id',
  42 );
  43
  44 our $db;
  45 sub db () { $db }
  46
  47 sub init {
  48         $db = DBIx::Simple->new(@_);
  49         $db->keep_statements = 100;
  50 };
  51
  52 sub purge;
  53
  54 sub query {
  55         my ($stat, @extra) = @_;
  56         $db->query($statements{$stat}, @extra)
  57 }
  58
  59 my (%name_cache, %name_cache_time);
  60 use constant NAME_CACHE_MAX_AGE => 5;
  61
  62 sub object_name {
  63         my ($table, $id) = @_;
  64         $name_cache_time{$table} //= 0;
  65         if (time - $name_cache_time{$table} > NAME_CACHE_MAX_AGE) {
  66                 $name_cache_time{$table} = time;
  67                 $name_cache{$table} = {};
  68                 $name_cache{$table} = $db->select($table, 'id,name')->map;
  69         }
  70
  71         $name_cache{$table}{$id}
  72 }
  73
  74
  75 sub add_names ($) { ## no critic (ProhibitSubroutinePrototypes)
  76         my ($el) = @_;
  77         return unless defined $el;
  78         if (ref $el eq 'ARRAY') {
  79                 &add_names ($_) for @$el ## no critic (ProhibitAmpersandSigils)
  80         } else {
  81                 for my $object (qw/contest owner problem/) {
  82                         my $table = $object eq 'owner' ? 'users' : "${object}s";
  83                         $el->{"${object}_name"} = object_name $table, $el->{$object} if defined $el->{$object}
  84                 }
  85         }
  86
  87         $el
  88 }
  89
  90 sub user_list { scalar query('user_list_sth')->hashes }
  91
  92 sub user_entry {
  93         my ($id) = @_;
  94         my $ret = query('user_entry_sth', $id)->hash;
  95         $ret->{problems} = add_names query('problem_status_sth', $id)->hashes;
  96         $ret->{contests} = add_names query('contest_status_sth', $id)->hashes;
  97
  98         $ret;
  99 }
 100
 101 sub problem_list {
 102         my (%args) = @_;
 103         my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
 104         push @columns, 'solution' if $args{solution};
 105         my %where;
 106         $where{private} = 0 unless $args{contest} || $args{private};
 107         $where{'cp.contest'} = $args{contest} if $args{contest};
 108         $where{owner} = $args{owner} if $args{owner};
 109
 110         my $table = $args{contest} ? 'problems JOIN contest_problems cp ON cp.problem = id' : 'problems';
 111         add_names $db->select(\$table, \@columns, \%where, 'name')->hashes
 112 }
 113
 114 sub problem_entry {
 115         my ($id, $contest) = @_;
 116         $contest = contest_entry ($contest) if $contest;
 117         my $ret = add_names query(problem_entry_sth => $id)->hash;
 118         my $limits = query(limits_sth => $id)->hashes;
 119         $ret->{limits} = $limits if @$limits;
 120
 121         if ($contest) {
 122                 $ret->{contest_start} = $contest->{start};
 123                 $ret->{contest_stop}  = $contest->{stop};
 124                 delete $ret->{solution}
 125         }
 126
 127         $ret
 128 }
 129
 130 sub contest_list { add_names query('contest_list_sth')->hashes }
 131
 132 sub contest_entry { add_names query(contest_entry_sth => $_[0])->hash }
 133
 134 sub contest_has_problem { query('contest_has_problem_sth', @_[0, 1])->flat }
 135
 136 sub job_list {
 137         my (%args) = @_;
 138         $args{page} = int ($args{page} // 1);
 139         my %where = (
 140                 maybe contest => $args{contest},
 141                 maybe owner => $args{owner},
 142                 maybe problem => $args{problem},
 143                 maybe result => $args{result},
 144         );
 145         $where{private} = 0 unless $args{private};
 146
 147         my $rows = $db->select('job_entry', 'COUNT(*)', \%where)->list;
 148         my $pages = int (($rows + JOBS_PER_PAGE - 1) / JOBS_PER_PAGE);
 149         my ($stmt, @bind) = $db->abstract->select('job_entry', '*', \%where, {-desc => 'id'});
 150         my $jobs = add_names $db->query("$stmt LIMIT " . JOBS_PER_PAGE . ' OFFSET ' . ($args{page} - 1) * JOBS_PER_PAGE, @bind)->hashes;
 151         my $pageinfo = {
 152                 current_page => $args{page},
 153                 last_page    => $pages,
 154                 ($args{page} - 1) ? (previous_page => $args{page} - 1) : (),
 155                 ($args{page} < $pages) ? (next_page => $args{page} + 1) : (),
 156         };
 157         wantarray ? ($jobs, $pageinfo) : $jobs;
 158 }
 159
 160 sub job_entry {
 161         my $ret = add_names query(job_entry_sth => $_[0])->hash;
 162         $ret->{results} = decode_json $ret->{results} if $ret->{results};
 163         $ret
 164 }
 165
 166 sub create_job {
 167         my (%args) = @_;
 168         $db->update('users', {lastjob => time}, {id => $args{owner}});
 169         purge '/log/';
 170         scalar $db->insert('jobs', \%args, {returning => 'id'})->list
 171 }
 172
 173 sub calc_score {
 174         my ($mxscore, $time, $tries, $totaltime) = @_;
 175         my $score = $mxscore;
 176         $time = 300 if $time > $totaltime; # uncoverable branch true does not happen anymore (only possible if opens are broken)
 177         $score = ($totaltime - $time) / $totaltime * $score;
 178         $score -= $tries / 10 * $mxscore;
 179         $score = $mxscore * 3 / 10 if $score < $mxscore * 3 / 10;
 180         int $score + 0.5
 181 }
 182
 183 sub standings {
 184         my ($ct) = @_;
 185         $ct = contest_entry $ct;
 186
 187         my @problems = query(contest_problems_sth => $ct->{id})->flat;
 188         my $pblist = problem_list;
 189         my %values = query('problem_values_sth')->map;
 190
 191         my (%scores, %tries, %opens);
 192         my $opens = query(opens_sth => $ct->{id});
 193         while ($opens->into(my ($problem, $owner, $time))) {
 194                 $opens{$problem, $owner} = $time;
 195         }
 196
 197         my $jobs = $db->select('job_entry', '*', {contest => $ct->{id}}, 'id');
 198
 199         while (my $job = $jobs->hash) {
 200                 my $open = $opens{$job->{problem}, $job->{owner}} // $ct->{start};
 201                 my $time = $job->{date} - $open;
 202                 next if $time < 0; # uncoverable branch true job sent before contest is deprecated
 203                 my $value = $values{$job->{problem}};
 204                 my $factor = $job->{result} ? 0 : 1;
 205                 $factor = $1 / 100 if $job->{result_text} =~ /^(\d+ )/s;
 206                 $scores{$job->{owner}}{$job->{problem}} = int ($factor * calc_score ($value, $time, $tries{$job->{owner}}{$job->{problem}}++, $ct->{stop} - $ct->{start}));
 207         }
 208
 209         my @st = sort { $b->{score} <=> $a->{score} or $a->{user} cmp $b->{user} } map { ## no critic (ProhibitReverseSortBlock)
 210                 my $user = $_;
 211                 +{
 212                         user => $user,
 213                         user_name => object_name(users => $user),
 214                         score => sum (values %{$scores{$user}}),
 215                         scores => [map { $scores{$user}{$_} // '-'} @problems],
 216                 }
 217         } keys %scores;
 218
 219         $st[0]->{rank} = 1 if @st;
 220         $st[$_]->{rank} = $st[$_ - 1]->{rank} + ($st[$_]->{score} < $st[$_ - 1]->{score}) for 1 .. $#st;
 221         +{
 222                 st => \@st,
 223                 problems => [map { [ $_, object_name(problems => $_)] } @problems],
 224         }
 225 }
 226
 227 sub update_status {
 228         my $jobs = $db->select('jobs', 'id,owner,problem,result', {-not_bool => 'private'}, 'id');
 229
 230         my %hash;
 231         while ($jobs->into(my ($id, $owner, $problem, $result))) {
 232                 $hash{$problem, $owner} = [$id, $result ? 0 : 1];
 233         }
 234
 235         my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;
 236
 237         my @contest_statuses = map {
 238                 my $ct = $_;
 239                 map { [$ct, $_->{user}, $_->{score}, $_->{rank}] } @{standings($ct)->{st}}
 240         } $db->select('contests', 'id')->flat;
 241
 242         $db->begin;
 243         $db->delete('problem_status');
 244         $db->query('INSERT INTO problem_status (problem,owner,job,solved) VALUES (??)', @$_) for @problem_statuses;
 245         $db->delete('contest_status');
 246         $db->query('INSERT INTO contest_status (contest,owner,score,rank) VALUES (??)', @$_) for @contest_statuses;
 247         $db->commit
 248 }
 249
 250 sub rerun_job {
 251         my ($id) = @_;
 252         query rerun_job_sth => $id;
 253         purge '/log/';
 254         purge "/log/$id";
 255 }
 256
 257 sub take_job {
 258         my ($daemon) = @_;
 259         my $id = query(take_job_sth => $daemon)->list;
 260         return $id ? db->select(jobs => '*', {id => $id})->hash : undef;
 261 }
 262
 263 sub finish_job {
 264         my ($job, $private, %args) = @_;
 265         db->update(jobs => \%args, {id => $job->{id}});
 266         return if $private;
 267         my $status = {
 268                 problem => $job->{problem},
 269                 owner   => $job->{owner},
 270                 job     => $job->{id},
 271                 solved  => ($args{result} ? 0 : 1),
 272         };
 273         eval {
 274                 db->insert(problem_status => $status)
 275         } or db->update(problem_status => $status, {owner => $job->{owner}, problem => $job->{problem}});
 276 }
 277
 278 my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
 279 my $ht = HTTP::Tiny->new;
 280
 281 sub purge {
 282         $ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
 283 }
 284
 285 1;
 286
 287 __END__
 288
 289 =encoding utf-8
 290
 291 =head1 NAME
 292
 293 Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools
 294
 295 =head1 SYNOPSIS
 296
 297   my $db = Gruntmaster::Data->connect('dbi:Pg:');
 298
 299   my $problem = $db->problem('my_problem');
 300   $problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
 301   $problem->rerun; # And rerun all jobs for this problem
 302
 303   # ...
 304
 305   my $contest = $db->contests->create({ # Create a new contest
 306     id => 'my_contest',
 307     name => 'My Awesome Contest',
 308     start => time + 100,
 309     end => time + 1900,
 310   });
 311   $db->contest_problems->create({ # Add a problem to the contest
 312     contest => 'my_contest',
 313     problem => 'my_problem',
 314   });
 315
 316   say 'The contest has not started yet' if $contest->is_pending;
 317
 318   # ...
 319
 320   my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
 321   $_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest
 322
 323 =head1 DESCRIPTION
 324
 325 Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.
 326
 327 In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:
 328
 329 =over
 330
 331 =item contests
 332
 333 Equivalent to C<< $schema->resultset('Contest') >>
 334
 335 =item contest_problems
 336
 337 Equivalent to C<< $schema->resultset('ContestProblem') >>
 338
 339 =item jobs
 340
 341 Equivalent to C<< $schema->resultset('Job') >>
 342
 343 =item problems
 344
 345 Equivalent to C<< $schema->resultset('Problem') >>
 346
 347 =item users
 348
 349 Equivalent to C<< $schema->resultset('User') >>
 350
 351 =item contest($id)
 352
 353 Equivalent to C<< $schema->resultset('Contest')->find($id) >>
 354
 355 =item job($id)
 356
 357 Equivalent to C<< $schema->resultset('Job')->find($id) >>
 358
 359 =item problem($id)
 360
 361 Equivalent to C<< $schema->resultset('Problem')->find($id) >>
 362
 363 =item user($id)
 364
 365 Equivalent to C<< $schema->resultset('User')->find($id) >>
 366
 367 =item user_list
 368
 369 Returns a list of users as an arrayref containing hashrefs.
 370
 371 =item user_entry($id)
 372
 373 Returns a hashref with information about the user $id.
 374
 375 =item problem_list([%args])
 376
 377 Returns a list of problems grouped by level. A hashref with levels as keys.
 378
 379 Takes the following arguments:
 380
 381 =over
 382
 383 =item owner
 384
 385 Only show problems owned by this user
 386
 387 =item contest
 388
 389 Only show problems in this contest
 390
 391 =back
 392
 393 =item problem_entry($id, [$contest, $user])
 394
 395 Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.
 396
 397 =item contest_list([%args])
 398
 399 Returns a list of contests grouped by state. A hashref with the following keys:
 400
 401 =over
 402
 403 =item pending
 404
 405 An arrayref of hashrefs representing pending contests
 406
 407 =item running
 408
 409 An arrayref of hashrefs representing running contests
 410
 411 =item finished
 412
 413 An arrayref of hashrefs representing finished contests
 414
 415 =back
 416
 417 Takes the following arguments:
 418
 419 =over
 420
 421 =item owner
 422
 423 Only show contests owned by this user.
 424
 425 =back
 426
 427 =item contest_entry($id)
 428
 429 Returns a hashref with information about the contest $id.
 430
 431 =item job_list([%args])
 432
 433 Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:
 434
 435 =over
 436
 437 =item owner
 438
 439 Only show jobs submitted by this user.
 440
 441 =item contest
 442
 443 Only show jobs submitted in this contest.
 444
 445 =item problem
 446
 447 Only show jobs submitted for this problem.
 448
 449 =item page
 450
 451 Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.
 452
 453 =back
 454
 455 =item job_entry($id)
 456
 457 Returns a hashref with information about the job $id.
 458
 459 =back
 460
 461 =head1 AUTHOR
 462
 463 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
 464
 465 =head1 COPYRIGHT AND LICENSE
 466
 467 Copyright (C) 2014 by Marius Gavrilescu
 468
 469 This library is free software; you can redistribute it and/or modify
 470 it under the same terms as Perl itself, either Perl version 5.18.1 or,
 471 at your option, any later version of Perl 5 you may have available.
 472
 473
 474 =cut