lib/Gruntmaster/Data.pm

   1 use utf8;
   2 package Gruntmaster::Data;
   3
   4 # Created by DBIx::Class::Schema::Loader
   5 # DO NOT MODIFY THE FIRST PART OF THIS FILE
   6
   7 use strict;
   8 use warnings;
   9
  10 use base 'DBIx::Class::Schema';
  11
  12 __PACKAGE__->load_namespaces;
  13
  14
  15 # Created by DBIx::Class::Schema::Loader v0.07039 @ 2014-03-05 13:11:39
  16 # DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:dAEmtAexvUaNXLgYz2rNEg
  17
  18 use parent qw/Exporter/;
  19 our $VERSION = '5999.000_013';
  20 our @EXPORT = qw/purge/; ## no critic (ProhibitAutomaticExportation)
  21
  22 use Lingua::EN::Inflect qw/PL_N/;
  23 use JSON::MaybeXS qw/decode_json/;
  24 use HTTP::Tiny;
  25 use PerlX::Maybe qw/maybe/;
  26 use Sub::Name qw/subname/;
  27
  28 use constant CONTEST_PUBLIC_COLUMNS => [qw/id name description start stop owner/];
  29 use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private timeout olimit value/];
  30 use constant USER_PUBLIC_COLUMNS => [qw/id admin name town university country level/];
  31 use constant JOBS_PER_PAGE => 10;
  32
  33 sub dynsub{
  34         our ($name, $sub) = @_;
  35         no strict 'refs'; ## no critic (Strict)
  36         *$name = subname $name => $sub
  37 }
  38
  39 BEGIN {
  40         for my $rs (qw/contest contest_problem job open problem user problem_status contest_status/) {
  41                 my $rsname = ucfirst $rs;
  42                 $rsname =~ s/_([a-z])/\u$1/gs;
  43                 dynsub PL_N($rs) => sub { $_[0]->resultset($rsname)              };
  44                 dynsub      $rs  => sub { $_[0]->resultset($rsname)->find($_[1]) };
  45         }
  46 }
  47
  48 sub user_list {
  49         my ($self) = @_;
  50         my $rs = $self->users->search(undef, {columns => USER_PUBLIC_COLUMNS} );
  51         my (%solved, %attempted, %contests);
  52
  53         for my $row ($self->problem_statuses->all) {
  54                 $solved   {$row->rawowner}++ if     $row->solved;
  55                 $attempted{$row->rawowner}++ unless $row->solved;
  56         }
  57         $contests{$_->rawowner}++ for $self->contest_statuses->all;
  58
  59         [ sort { $b->{solved} <=> $a->{solved} or $b->{attempted} <=> $a->{attempted} } map { ## no critic (ProhibitReverseSort)
  60                 my $id = $_->id;
  61                 +{ $_->get_columns,
  62                    solved => ($solved{$id} // 0),
  63                    attempted => ($attempted{$id} // 0),
  64                    contests => ($contests{$id} // 0) }
  65         } $rs->all ]
  66 }
  67
  68 sub user_entry {
  69         my ($self, $id) = @_;
  70         my $user = $self->users->find($id, {columns => USER_PUBLIC_COLUMNS, prefetch => [qw/problem_statuses contest_statuses/]});
  71         my @problems = map { {problem => $_->get_column('problem'), solved => $_->solved} } $user->problem_statuses->search(undef, {order_by => 'problem'});
  72         my @contests = map { {contest => $_->contest->id, contest_name => $_->contest->name, rank => $_->rank, score => $_->score} } $user->contest_statuses->search(undef, {prefetch => 'contest', order_by => 'contest.start DESC'});
  73         +{ $user->get_columns, problems => \@problems, contests => \@contests }
  74 }
  75
  76 sub problem_list {
  77         my ($self, %args) = @_;
  78         my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
  79         push @columns, 'solution' if $args{solution} && $args{contest} && !$self->contest($args{contest})->is_running;
  80         my $rs = $self->problems->search(undef, {order_by => 'me.name', columns => \@columns, prefetch => 'owner'});
  81         $rs = $rs->search({-or => ['contest_problems.contest' => undef, 'contest.stop' => {'<=', time}], 'me.private' => 0}, {join => {'contest_problems' => 'contest'}, distinct => 1}) unless $args{contest} || $args{private};
  82         $rs = $rs->search({'contest_problems.contest' => $args{contest}}, {join => 'contest_problems'}) if $args{contest};
  83         $rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
  84         my %params;
  85         $params{contest} = $args{contest} if $args{contest};
  86         for ($rs->all) {
  87                 $params{$_->level} //= [];
  88                 push @{$params{$_->level}}, {$_->get_columns, owner_name => $_->owner->name} ;
  89         }
  90         \%params
  91 }
  92
  93 sub problem_entry {
  94         my ($self, $id, $contest, $user) = @_;
  95         my $running = $contest && $self->contest($contest)->is_running;
  96         my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
  97         push @columns, 'statement';
  98         push @columns, 'solution' unless $running;
  99         my $pb = $self->problems->find($id, {columns => \@columns, prefetch => 'owner'});
 100         my $open;
 101         $open = $self->opens->find_or_create({
 102                 contest => $contest,
 103                 problem => $id,
 104                 owner => $user,
 105                 time => time,
 106         }) if $running;
 107         $contest &&= $self->contest($contest);
 108         +{
 109                 $pb->get_columns,
 110                 owner_name => $pb->owner->name,
 111                 cansubmit => !$contest || !$contest->is_finished,
 112                 $running ? (
 113                         contest_start => $contest->start,
 114                         contest_stop => $contest->stop,
 115                         open_time => $open->time
 116                 ) : (),
 117         }
 118 }
 119
 120 sub contest_list {
 121         my ($self, %args) = @_;
 122         my $rs = $self->contests->search(undef, {columns => CONTEST_PUBLIC_COLUMNS, order_by => {-desc => 'start'}, prefetch => 'owner'});
 123         $rs = $rs->search({owner => $args{owner}}) if $args{owner};
 124         my %params;
 125         for ($rs->all) {
 126                 my $state = $_->is_pending ? 'pending' : $_->is_running ? 'running' : 'finished';
 127                 $params{$state} //= [];
 128                 push @{$params{$state}}, { $_->get_columns, owner_name => $_->owner->name };
 129         }
 130         \%params
 131 }
 132
 133 sub contest_entry {
 134         my ($self, $id) = @_;
 135         my $ct = $self->contests->find($id,{columns => CONTEST_PUBLIC_COLUMNS});
 136         +{ $ct->get_columns, started => !$ct->is_pending, finished => $ct->is_finished, owner_name => $ct->owner->name }
 137 }
 138
 139 sub job_list {
 140         my ($self, %args) = @_;
 141         $args{page} //= 1;
 142         my $rs = $self->jobs->search(undef, {order_by => {-desc => 'me.id'}, prefetch => ['problem', 'owner', 'contest'], rows => JOBS_PER_PAGE, page => $args{page}});
 143         $rs = $rs->search({contest => $args{contest} || undef}) if exists $args{contest};
 144         $rs = $rs->search({'me.private'=> 0})          unless $args{private};
 145         $rs = $rs->search({'me.owner'  => $args{owner}})   if $args{owner};
 146         $rs = $rs->search({problem     => $args{problem}}) if $args{problem};
 147         return {
 148                 log => [map {
 149                         my %params = $_->get_columns;
 150                         $params{owner_name}   = $_->owner->name;
 151                         $params{problem_name} = $_->problem->name;
 152                         $params{contest_name} = $_->contest->name if $params{contest};
 153                         $params{results} &&= decode_json $params{results};
 154                         $params{size}      = length $params{source};
 155                         delete $params{source};
 156                         \%params
 157                 } $rs->all],
 158                 current_page => $rs->pager->current_page,
 159                 maybe previous_page => $rs->pager->previous_page,
 160                 maybe next_page => $rs->pager->next_page,
 161                 maybe last_page => $rs->pager->last_page,
 162         }
 163 }
 164
 165 sub job_entry {
 166         my ($self, $id) = @_;
 167         my $job = $self->jobs->find($id, {prefetch => ['problem', 'owner', 'contest']});
 168         my %params = $job->get_columns;
 169         $params{owner_name}   = $job->owner->name;
 170         $params{problem_name} = $job->problem->name;
 171         $params{contest_name} = $job->contest->name if $params{contest};
 172         $params{results} &&= decode_json $params{results};
 173         $params{size}      = length $params{source};
 174         delete $params{source};
 175         \%params
 176 }
 177
 178 sub update_status {
 179         my ($self) = @_;
 180         my @jobs = $self->jobs->search({'me.private' => 0}, {cache => 1, prefetch => 'problem'})->all;
 181
 182         my %private;
 183         my %hash;
 184         for (@jobs) {
 185                 my $pb = $_->get_column('problem');
 186                 $private{$pb} //= $_->problem->is_private;
 187                 next if $private{$pb};
 188                 $hash{$pb, $_->get_column('owner')} = [$_->id, $_->result ? 0 : 1];
 189         }
 190
 191         my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;
 192
 193         my @contest_statuses = map {
 194                 my $contest = $_->id;
 195                 map { [$contest, $_->{user}, $_->{score}, $_->{rank}] } $_->standings
 196         } $self->contests->all;
 197
 198         my $txn = sub {
 199                 $self->problem_statuses->delete;
 200                 $self->problem_statuses->populate([[qw/problem owner job solved/], @problem_statuses]);
 201                 $self->contest_statuses->delete;
 202                 $self->contest_statuses->populate([[qw/contest owner score rank/], @contest_statuses]);
 203         };
 204
 205         $self->txn_do($txn);
 206 }
 207
 208 my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
 209 my $ht = HTTP::Tiny->new;
 210
 211 sub purge {
 212         $ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
 213 }
 214
 215 1;
 216
 217 __END__
 218
 219 =encoding utf-8
 220
 221 =head1 NAME
 222
 223 Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools
 224
 225 =head1 SYNOPSIS
 226
 227   my $db = Gruntmaster::Data->connect('dbi:Pg:');
 228
 229   my $problem = $db->problem('my_problem');
 230   $problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
 231   $problem->rerun; # And rerun all jobs for this problem
 232
 233   # ...
 234
 235   my $contest = $db->contests->create({ # Create a new contest
 236     id => 'my_contest',
 237     name => 'My Awesome Contest',
 238     start => time + 100,
 239     end => time + 1900,
 240   });
 241   $db->contest_problems->create({ # Add a problem to the contest
 242     contest => 'my_contest',
 243     problem => 'my_problem',
 244   });
 245
 246   say 'The contest has not started yet' if $contest->is_pending;
 247
 248   # ...
 249
 250   my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
 251   $_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest
 252
 253 =head1 DESCRIPTION
 254
 255 Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.
 256
 257 In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:
 258
 259 =over
 260
 261 =item contests
 262
 263 Equivalent to C<< $schema->resultset('Contest') >>
 264
 265 =item contest_problems
 266
 267 Equivalent to C<< $schema->resultset('ContestProblem') >>
 268
 269 =item jobs
 270
 271 Equivalent to C<< $schema->resultset('Job') >>
 272
 273 =item problems
 274
 275 Equivalent to C<< $schema->resultset('Problem') >>
 276
 277 =item users
 278
 279 Equivalent to C<< $schema->resultset('User') >>
 280
 281 =item contest($id)
 282
 283 Equivalent to C<< $schema->resultset('Contest')->find($id) >>
 284
 285 =item job($id)
 286
 287 Equivalent to C<< $schema->resultset('Job')->find($id) >>
 288
 289 =item problem($id)
 290
 291 Equivalent to C<< $schema->resultset('Problem')->find($id) >>
 292
 293 =item user($id)
 294
 295 Equivalent to C<< $schema->resultset('User')->find($id) >>
 296
 297 =item user_list
 298
 299 Returns a list of users as an arrayref containing hashrefs.
 300
 301 =item user_entry($id)
 302
 303 Returns a hashref with information about the user $id.
 304
 305 =item problem_list([%args])
 306
 307 Returns a list of problems grouped by level. A hashref with levels as keys.
 308
 309 Takes the following arguments:
 310
 311 =over
 312
 313 =item owner
 314
 315 Only show problems owned by this user
 316
 317 =item contest
 318
 319 Only show problems in this contest
 320
 321 =back
 322
 323 =item problem_entry($id, [$contest, $user])
 324
 325 Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.
 326
 327 =item contest_list([%args])
 328
 329 Returns a list of contests grouped by state. A hashref with the following keys:
 330
 331 =over
 332
 333 =item pending
 334
 335 An arrayref of hashrefs representing pending contests
 336
 337 =item running
 338
 339 An arrayref of hashrefs representing running contests
 340
 341 =item finished
 342
 343 An arrayref of hashrefs representing finished contests
 344
 345 =back
 346
 347 Takes the following arguments:
 348
 349 =over
 350
 351 =item owner
 352
 353 Only show contests owned by this user.
 354
 355 =back
 356
 357 =item contest_entry($id)
 358
 359 Returns a hashref with information about the contest $id.
 360
 361 =item job_list([%args])
 362
 363 Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:
 364
 365 =over
 366
 367 =item owner
 368
 369 Only show jobs submitted by this user.
 370
 371 =item contest
 372
 373 Only show jobs submitted in this contest.
 374
 375 =item problem
 376
 377 Only show jobs submitted for this problem.
 378
 379 =item page
 380
 381 Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.
 382
 383 =back
 384
 385 =item job_entry($id)
 386
 387 Returns a hashref with information about the job $id.
 388
 389 =back
 390
 391 =head1 AUTHOR
 392
 393 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
 394
 395 =head1 COPYRIGHT AND LICENSE
 396
 397 Copyright (C) 2014 by Marius Gavrilescu
 398
 399 This library is free software; you can redistribute it and/or modify
 400 it under the same terms as Perl itself, either Perl version 5.18.1 or,
 401 at your option, any later version of Perl 5 you may have available.
 402
 403
 404 =cut