lib/Gruntmaster/Data.pm

   1 use utf8;
   2 package Gruntmaster::Data;
   3
   4 # Created by DBIx::Class::Schema::Loader
   5 # DO NOT MODIFY THE FIRST PART OF THIS FILE
   6
   7 use strict;
   8 use warnings;
   9
  10 use base 'DBIx::Class::Schema';
  11
  12 __PACKAGE__->load_namespaces;
  13
  14
  15 # Created by DBIx::Class::Schema::Loader v0.07039 @ 2014-03-05 13:11:39
  16 # DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:dAEmtAexvUaNXLgYz2rNEg
  17
  18 use parent qw/Exporter/;
  19 our $VERSION = '5999.000_013';
  20 our @EXPORT = qw/purge/; ## no critic (ProhibitAutomaticExportation)
  21
  22 use Lingua::EN::Inflect qw/PL_N/;
  23 use JSON::MaybeXS qw/decode_json/;
  24 use HTTP::Tiny;
  25 use PerlX::Maybe qw/maybe/;
  26 use Sub::Name qw/subname/;
  27
  28 use constant CONTEST_PUBLIC_COLUMNS => [qw/id name description start stop owner/];
  29 use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private timeout olimit value/];
  30 use constant USER_PUBLIC_COLUMNS => [qw/id admin name town university country level/];
  31 use constant JOBS_PER_PAGE => 10;
  32
  33 sub dynsub{
  34         our ($name, $sub) = @_;
  35         no strict 'refs'; ## no critic (Strict)
  36         *$name = subname $name => $sub
  37 }
  38
  39 BEGIN {
  40         for my $rs (qw/contest contest_problem job open problem user problem_status contest_status/) {
  41                 my $rsname = ucfirst $rs;
  42                 $rsname =~ s/_([a-z])/\u$1/gs;
  43                 dynsub PL_N($rs) => sub { $_[0]->resultset($rsname)              };
  44                 dynsub      $rs  => sub { $_[0]->resultset($rsname)->find($_[1]) };
  45         }
  46 }
  47
  48 sub user_list {
  49         my ($self) = @_;
  50         my $rs = $self->users->search(undef, {columns => USER_PUBLIC_COLUMNS} );
  51         my (%solved, %attempted, %contests);
  52
  53         for my $row ($self->problem_statuses->all) {
  54                 $solved   {$row->rawowner}++ if     $row->solved;
  55                 $attempted{$row->rawowner}++ unless $row->solved;
  56         }
  57         $contests{$_->rawowner}++ for $self->contest_statuses->all;
  58
  59         [ sort { $b->{solved} <=> $a->{solved} or $b->{attempted} <=> $a->{attempted} } ## no critic (ProhibitReverseSort)
  60                 grep { $_->{solved} || $_->{attempted} } map {
  61                         my $id = $_->id;
  62                         +{ $_->get_columns,
  63                            solved => ($solved{$id} // 0),
  64                            attempted => ($attempted{$id} // 0),
  65                            contests => ($contests{$id} // 0) }
  66                 } $rs->all ]
  67 }
  68
  69 sub user_entry {
  70         my ($self, $id) = @_;
  71         my $user = $self->users->find($id, {columns => USER_PUBLIC_COLUMNS, prefetch => [qw/problem_statuses contest_statuses/]});
  72         my @problems = map { {problem => $_->get_column('problem'), solved => $_->solved} } $user->problem_statuses->search(undef, {order_by => 'problem'});
  73         my @contests = map { {contest => $_->contest->id, contest_name => $_->contest->name, rank => $_->rank, score => $_->score} } $user->contest_statuses->search(undef, {prefetch => 'contest', order_by => 'contest.start DESC'});
  74         +{ $user->get_columns, problems => \@problems, contests => \@contests }
  75 }
  76
  77 sub problem_list {
  78         my ($self, %args) = @_;
  79         my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
  80         push @columns, 'solution' if $args{solution} && $args{contest} && !$self->contest($args{contest})->is_running;
  81         my $rs = $self->problems->search(undef, {order_by => 'me.name', columns => \@columns, prefetch => 'owner'});
  82         $rs = $rs->search({-or => ['contest_problems.contest' => undef, 'contest.stop' => {'<=', time}], 'me.private' => 0}, {join => {'contest_problems' => 'contest'}, distinct => 1}) unless $args{contest} || $args{private};
  83         $rs = $rs->search({'contest_problems.contest' => $args{contest}}, {join => 'contest_problems'}) if $args{contest};
  84         $rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
  85         my %params;
  86         $params{contest} = $args{contest} if $args{contest};
  87         for ($rs->all) {
  88                 $params{$_->level} //= [];
  89                 push @{$params{$_->level}}, {$_->get_columns, owner_name => $_->owner->name} ;
  90         }
  91         \%params
  92 }
  93
  94 sub problem_entry {
  95         my ($self, $id, $contest, $user) = @_;
  96         my $running = $contest && $self->contest($contest)->is_running;
  97         my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
  98         push @columns, 'statement';
  99         push @columns, 'solution' unless $running;
 100         my $pb = $self->problems->find($id, {columns => \@columns, prefetch => 'owner'});
 101         my $open;
 102         $open = $self->opens->find_or_create({
 103                 contest => $contest,
 104                 problem => $id,
 105                 owner => $user,
 106                 time => time,
 107         }) if $running;
 108         $contest &&= $self->contest($contest);
 109         +{
 110                 $pb->get_columns,
 111                 owner_name => $pb->owner->name,
 112                 cansubmit => !$contest || !$contest->is_finished,
 113                 $running ? (
 114                         contest_start => $contest->start,
 115                         contest_stop => $contest->stop,
 116                         open_time => $open->time
 117                 ) : (),
 118         }
 119 }
 120
 121 sub contest_list {
 122         my ($self, %args) = @_;
 123         my $rs = $self->contests->search(undef, {columns => CONTEST_PUBLIC_COLUMNS, order_by => {-desc => 'start'}, prefetch => 'owner'});
 124         $rs = $rs->search({owner => $args{owner}}) if $args{owner};
 125         my %params;
 126         for ($rs->all) {
 127                 my $state = $_->is_pending ? 'pending' : $_->is_running ? 'running' : 'finished';
 128                 $params{$state} //= [];
 129                 push @{$params{$state}}, { $_->get_columns, owner_name => $_->owner->name };
 130         }
 131         \%params
 132 }
 133
 134 sub contest_entry {
 135         my ($self, $id) = @_;
 136         my $ct = $self->contests->find($id,{columns => CONTEST_PUBLIC_COLUMNS});
 137         +{ $ct->get_columns, started => !$ct->is_pending, finished => $ct->is_finished, owner_name => $ct->owner->name }
 138 }
 139
 140 sub job_list {
 141         my ($self, %args) = @_;
 142         $args{page} //= 1;
 143         my $rs = $self->jobs->search(undef, {order_by => {-desc => 'me.id'}, prefetch => ['problem', 'owner', 'contest'], rows => JOBS_PER_PAGE, page => $args{page}});
 144         $rs = $rs->search({contest => $args{contest} || undef}) if exists $args{contest};
 145         $rs = $rs->search({'me.private'=> 0})          unless $args{private};
 146         $rs = $rs->search({'me.owner'  => $args{owner}})   if $args{owner};
 147         $rs = $rs->search({problem     => $args{problem}}) if $args{problem};
 148         return {
 149                 log => [map {
 150                         my %params = $_->get_columns;
 151                         $params{owner_name}   = $_->owner->name;
 152                         $params{problem_name} = $_->problem->name;
 153                         $params{contest_name} = $_->contest->name if $params{contest};
 154                         $params{results} &&= decode_json $params{results};
 155                         $params{size}      = length $params{source};
 156                         delete $params{source};
 157                         \%params
 158                 } $rs->all],
 159                 current_page => $rs->pager->current_page,
 160                 maybe previous_page => $rs->pager->previous_page,
 161                 maybe next_page => $rs->pager->next_page,
 162                 maybe last_page => $rs->pager->last_page,
 163         }
 164 }
 165
 166 sub job_entry {
 167         my ($self, $id) = @_;
 168         my $job = $self->jobs->find($id, {prefetch => ['problem', 'owner', 'contest']});
 169         my %params = $job->get_columns;
 170         $params{owner_name}   = $job->owner->name;
 171         $params{problem_name} = $job->problem->name;
 172         $params{contest_name} = $job->contest->name if $params{contest};
 173         $params{results} &&= decode_json $params{results};
 174         $params{size}      = length $params{source};
 175         delete $params{source};
 176         \%params
 177 }
 178
 179 sub update_status {
 180         my ($self) = @_;
 181         my @jobs = $self->jobs->search({'me.private' => 0}, {cache => 1, prefetch => 'problem', order_by => 'me.id'})->all;
 182
 183         my %private;
 184         my %hash;
 185         for (@jobs) {
 186                 my $pb = $_->get_column('problem');
 187                 $private{$pb} //= $_->problem->is_private;
 188                 next if $private{$pb};
 189                 $hash{$pb, $_->get_column('owner')} = [$_->id, $_->result ? 0 : 1];
 190         }
 191
 192         my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;
 193
 194         my @contest_statuses = map {
 195                 my $contest = $_->id;
 196                 map { [$contest, $_->{user}, $_->{score}, $_->{rank}] } $_->standings
 197         } $self->contests->all;
 198
 199         my $txn = sub {
 200                 $self->problem_statuses->delete;
 201                 $self->problem_statuses->populate([[qw/problem owner job solved/], @problem_statuses]);
 202                 $self->contest_statuses->delete;
 203                 $self->contest_statuses->populate([[qw/contest owner score rank/], @contest_statuses]);
 204         };
 205
 206         $self->txn_do($txn);
 207 }
 208
 209 my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
 210 my $ht = HTTP::Tiny->new;
 211
 212 sub purge {
 213         $ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
 214 }
 215
 216 1;
 217
 218 __END__
 219
 220 =encoding utf-8
 221
 222 =head1 NAME
 223
 224 Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools
 225
 226 =head1 SYNOPSIS
 227
 228   my $db = Gruntmaster::Data->connect('dbi:Pg:');
 229
 230   my $problem = $db->problem('my_problem');
 231   $problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
 232   $problem->rerun; # And rerun all jobs for this problem
 233
 234   # ...
 235
 236   my $contest = $db->contests->create({ # Create a new contest
 237     id => 'my_contest',
 238     name => 'My Awesome Contest',
 239     start => time + 100,
 240     end => time + 1900,
 241   });
 242   $db->contest_problems->create({ # Add a problem to the contest
 243     contest => 'my_contest',
 244     problem => 'my_problem',
 245   });
 246
 247   say 'The contest has not started yet' if $contest->is_pending;
 248
 249   # ...
 250
 251   my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
 252   $_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest
 253
 254 =head1 DESCRIPTION
 255
 256 Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.
 257
 258 In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:
 259
 260 =over
 261
 262 =item contests
 263
 264 Equivalent to C<< $schema->resultset('Contest') >>
 265
 266 =item contest_problems
 267
 268 Equivalent to C<< $schema->resultset('ContestProblem') >>
 269
 270 =item jobs
 271
 272 Equivalent to C<< $schema->resultset('Job') >>
 273
 274 =item problems
 275
 276 Equivalent to C<< $schema->resultset('Problem') >>
 277
 278 =item users
 279
 280 Equivalent to C<< $schema->resultset('User') >>
 281
 282 =item contest($id)
 283
 284 Equivalent to C<< $schema->resultset('Contest')->find($id) >>
 285
 286 =item job($id)
 287
 288 Equivalent to C<< $schema->resultset('Job')->find($id) >>
 289
 290 =item problem($id)
 291
 292 Equivalent to C<< $schema->resultset('Problem')->find($id) >>
 293
 294 =item user($id)
 295
 296 Equivalent to C<< $schema->resultset('User')->find($id) >>
 297
 298 =item user_list
 299
 300 Returns a list of users as an arrayref containing hashrefs.
 301
 302 =item user_entry($id)
 303
 304 Returns a hashref with information about the user $id.
 305
 306 =item problem_list([%args])
 307
 308 Returns a list of problems grouped by level. A hashref with levels as keys.
 309
 310 Takes the following arguments:
 311
 312 =over
 313
 314 =item owner
 315
 316 Only show problems owned by this user
 317
 318 =item contest
 319
 320 Only show problems in this contest
 321
 322 =back
 323
 324 =item problem_entry($id, [$contest, $user])
 325
 326 Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.
 327
 328 =item contest_list([%args])
 329
 330 Returns a list of contests grouped by state. A hashref with the following keys:
 331
 332 =over
 333
 334 =item pending
 335
 336 An arrayref of hashrefs representing pending contests
 337
 338 =item running
 339
 340 An arrayref of hashrefs representing running contests
 341
 342 =item finished
 343
 344 An arrayref of hashrefs representing finished contests
 345
 346 =back
 347
 348 Takes the following arguments:
 349
 350 =over
 351
 352 =item owner
 353
 354 Only show contests owned by this user.
 355
 356 =back
 357
 358 =item contest_entry($id)
 359
 360 Returns a hashref with information about the contest $id.
 361
 362 =item job_list([%args])
 363
 364 Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:
 365
 366 =over
 367
 368 =item owner
 369
 370 Only show jobs submitted by this user.
 371
 372 =item contest
 373
 374 Only show jobs submitted in this contest.
 375
 376 =item problem
 377
 378 Only show jobs submitted for this problem.
 379
 380 =item page
 381
 382 Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.
 383
 384 =back
 385
 386 =item job_entry($id)
 387
 388 Returns a hashref with information about the job $id.
 389
 390 =back
 391
 392 =head1 AUTHOR
 393
 394 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
 395
 396 =head1 COPYRIGHT AND LICENSE
 397
 398 Copyright (C) 2014 by Marius Gavrilescu
 399
 400 This library is free software; you can redistribute it and/or modify
 401 it under the same terms as Perl itself, either Perl version 5.18.1 or,
 402 at your option, any later version of Perl 5 you may have available.
 403
 404
 405 =cut