app.psgi

   1 #!/usr/bin/perl -w
   2 use v5.14;
   3 no if $] >= 5.017011, warnings => 'experimental::smartmatch';
   4
   5 use Apache2::Authen::Passphrase qw/pwcheck/;
   6 use Apache2::AuthzCaps qw/hascaps/;
   7 use Gruntmaster::Data;
   8 use Plack::App::Gruntmaster;
   9 use Plack::Builder;
  10 use Plack::Request;
  11 use Digest::SHA qw/sha256/;
  12 use Log::Log4perl;
  13
  14 use constant ACCESSLOG_FORMAT => '%{X-Forwarded-For}i|%h %u "%r" %>s %b "%{Referer}i" "%{User-agent}i"';
  15 use constant CONTENT_SECURITY_POLICY => q,default-src 'none'; script-src 'self' www.google-analytics.com; style-src 'self'; img-src 'self'; connect-src 'self',;
  16
  17 $Apache2::AuthzCaps::rootdir = $Apache2::Authen::Passphrase::rootdir;
  18 my $word = qr,(\w+),a;
  19 my $db = Gruntmaster::Data->connect('dbi:Pg:');
  20
  21 sub debug {
  22         local $Log::Log4perl::caller_depth = $Log::Log4perl::caller_depth + 1;
  23         $_[0]->{'psgix.logger'}->({qw/level debug message/ => $_[1]})
  24 }
  25
  26 sub some_auth_required {
  27         my $r = Plack::Request->new($_[0]);
  28         return 1 if $_[0]->{'gruntmaster.reqadmin'} || $r->path eq '/action/passwd' || $r->path eq '/submit';
  29         return 1 if $r->path =~ m,^/ct/$word/pb/$word, && time < $db->contest($1)->stop;
  30         ''
  31 }
  32
  33 sub is_problem_private {
  34         my $pb = $_[0];
  35         return 1 if $db->problem($pb)->private;
  36         my $prv = 0;
  37         for my $cp ($db->problem($pb)->contest_problems) {
  38                 $prv = 1;
  39                 return '' if $cp->contest->start <= time;
  40         }
  41
  42         $prv
  43 }
  44
  45 sub admin_required {
  46         local $_ = $_[0];
  47         my $env = $_[1];
  48         return $db->contest($1)->owner->id if $env->{'gruntmaster.contest'} && $db->contest($env->{'gruntmaster.contest'})->start > time;
  49         return $db->problem($1)->owner->id if m,^/pb/$word, && is_problem_private $1 || $env->{'gruntmaster.problem'} && is_problem_private $env->{'gruntmaster.problem'};
  50         return $db->job    ($1)->owner->id if m,^/log/(?:src/)?$word, && ($db->job($1)->private || is_problem_private $db->job($1)->problem->id || $db->job($1)->contest && $db->contest($db->job($1)->contest)->start > time);
  51         ''
  52 }
  53
  54 sub require_admin {
  55         my $app = $_[0];
  56         sub {
  57                 local *__ANON__ = "require_admin_middleware";
  58                 my $env = $_[0];
  59                 my $r = Plack::Request->new($env);
  60                 $env->{'gruntmaster.reqadmin'} = admin_required $r->path, $env;
  61                 $app->($env)
  62         }
  63 }
  64
  65 sub mangle_request {
  66         my $app = $_[0];
  67         sub {
  68                 local *__ANON__ = 'mangle_request_middleware';
  69                 my $env = $_[0];
  70                 my ($number, $word) = (qr,(\d+),a, qr,(\w+),a);
  71                 for ($env->{PATH_INFO}) {
  72                         $env->{'gruntmaster.page'}    = $1 if s,/page/$number$,/,;
  73                         $env->{'gruntmaster.problem'} = $1 if s,^/pb/$word/,/,;
  74                         $env->{'gruntmaster.contest'} = $1 if s,^/ct/$word/,/,;
  75                         $env->{'gruntmaster.user'}    = $1 if s,^/us/$word/,/,;
  76                         $env->{'gruntmaster.page'}  //= -1 if m,^/log/$,;
  77                 }
  78                 $app->($env);
  79         }
  80 }
  81
  82 my %authen_cache;
  83
  84 sub authenticate {
  85         my ($user, $pass, $env) = @_;
  86         my $cache_key = sha256 "$user:$pass";
  87         my $time = $authen_cache{$cache_key} // 0;
  88         if ($time >= time - 300) {
  89                 return 1;
  90         } else {
  91                 delete $authen_cache{$cache_key};
  92         }
  93
  94         return unless eval {
  95                 pwcheck $user, $pass;
  96                 1
  97         };
  98         $authen_cache{$cache_key} = time;
  99
 100         return if $env->{'gruntmaster.reqadmin'} && $env->{'gruntmaster.reqadmin'} ne $user && !hascaps $user, 'gmadm';
 101         1
 102 }
 103
 104 Log::Log4perl->init('log.conf');
 105 my $access_logger = Log::Log4perl->get_logger('access');
 106 $ENV{DBIC_NULLABLE_KEY_NOWARN} = 1;
 107
 108 builder {
 109         enable_if { $_[0]->{PATH_INFO} eq '/ok' } sub { sub{ [200, [], []] }};
 110         enable 'AccessLog', format => ACCESSLOG_FORMAT, logger => sub { $access_logger->info(@_) };
 111         enable 'ContentLength';
 112         enable Header => set => ['Content-Security-Policy', CONTENT_SECURITY_POLICY];
 113         enable_if { $_[0]->{PATH_INFO} =~ qr,^/static/,} Header => set => ['Cache-Control', 'public, max-age=604800'];
 114         enable 'Static', path => qr,^/static/,;
 115         enable 'Log4perl', category => 'plack';
 116         enable \&mangle_request;
 117         enable \&require_admin;
 118         enable_if \&some_auth_required, 'Auth::Basic', authenticator => \&authenticate, realm => 'Gruntmaster 6000';
 119         enable sub { my $app = $_[0]; sub { $_[0]->{'gruntmaster.dbic'} = $db; $app->($_[0]) } };
 120         Plack::App::Gruntmaster->to_app
 121 }