app.psgi

   1 #!/usr/bin/perl -w
   2 use v5.14;
   3 no if $] >= 5.017011, warnings => 'experimental::smartmatch';
   4
   5 use Apache2::Authen::Passphrase qw/pwcheck/;
   6 use Apache2::AuthzCaps qw/hascaps/;
   7 use Gruntmaster::Data;
   8 use Plack::App::Gruntmaster;
   9 use Plack::Builder;
  10 use Plack::Request;
  11 use Digest::SHA qw/sha256/;
  12 use Log::Log4perl;
  13
  14 use constant ACCESSLOG_FORMAT => '%{X-Forwarded-For}i|%h %u "%r" %>s %b "%{Referer}i" "%{User-agent}i"';
  15 use constant CONTENT_SECURITY_POLICY => q,default-src 'none'; script-src 'self' www.google-analytics.com; style-src 'self'; img-src 'self'; connect-src 'self',;
  16
  17 $Apache2::AuthzCaps::rootdir = $Apache2::Authen::Passphrase::rootdir;
  18 my $word = qr,(\w+),a;
  19 my $db = Gruntmaster::Data->connect('dbi:Pg:');
  20
  21 sub debug {
  22         local $Log::Log4perl::caller_depth = $Log::Log4perl::caller_depth + 1;
  23         $_[0]->{'psgix.logger'}->({qw/level debug message/ => $_[1]})
  24 }
  25
  26 sub some_auth_required {
  27         my $r = Plack::Request->new($_[0]);
  28         return 1 if $_[0]->{'gruntmaster.reqadmin'} || $r->path eq '/action/passwd' || $r->path =~ m,/pb/$word/submit$,;
  29         return 1 if $r->path =~ m,^/ct/$word/pb/$word, && time < $db->contest($1)->stop;
  30         ''
  31 }
  32
  33 sub admin_required {
  34         local $_ = $_[0];
  35         return $db->problem($1)->owner if m,^/pb/$word, && $db->problem($1)->private;
  36         return $db->job    ($1)->owner if m,^/log/(?:job|src)/$word, && $db->job($1)->private;
  37         return $db->contest($1)->owner if m,^/ct/$word/(?:pb|log), && time < $db->contest($1)->start;
  38         return $db->job    ($2)->owner if m,^/ct/$word/log/(?:job|src)/$word, && time < $db->contest($1)->stop;
  39         ''
  40 }
  41
  42 sub require_admin {
  43         my $app = $_[0];
  44         sub {
  45                 local *__ANON__ = "require_admin_middleware";
  46                 my $env = $_[0];
  47                 my $r = Plack::Request->new($env);
  48                 $env->{'gruntmaster.reqadmin'} = admin_required $r->path;
  49                 $app->($env)
  50         }
  51 }
  52
  53 sub mangle_request {
  54         my $app = $_[0];
  55         sub {
  56                 local *__ANON__ = 'mangle_request_middleware';
  57                 my $env = $_[0];
  58                 my ($number, $word) = (qr,(\d+),a, qr,(\w+),a);
  59                 for ($env->{PATH_INFO}) {
  60                         $env->{'gruntmaster.page'}    = $1 if s,/page/$number$,/,;
  61                         $env->{'gruntmaster.problem'} = $1 if s,^/pb/$word/,/,;
  62                         $env->{'gruntmaster.contest'} = $1 if s,^/ct/$word/,/,;
  63                         $env->{'gruntmaster.user'}    = $1 if s,^/us/$word/,/,;
  64                 }
  65                 $app->($env);
  66         }
  67 }
  68
  69 my %authen_cache;
  70
  71 sub authenticate {
  72         my ($user, $pass, $env) = @_;
  73         my $cache_key = sha256 "$user:$pass";
  74         my $time = $authen_cache{$cache_key} // 0;
  75         if ($time >= time - 300) {
  76                 return 1;
  77         } else {
  78                 delete $authen_cache{$cache_key};
  79         }
  80
  81         return unless eval {
  82                 pwcheck $user, $pass;
  83                 1
  84         };
  85         $authen_cache{$cache_key} = time;
  86
  87         return if $env->{'gruntmaster.reqadmin'} && $env->{'gruntmaster.reqadmin'} ne $user && !hascaps $user, 'gmadm';
  88         1
  89 }
  90
  91 Log::Log4perl->init('log.conf');
  92 my $access_logger = Log::Log4perl->get_logger('access');
  93
  94 builder {
  95         enable_if { $_[0]->{PATH_INFO} eq '/ok' } sub { sub{ [200, [], []] }};
  96         enable 'AccessLog', format => ACCESSLOG_FORMAT, logger => sub { $access_logger->info(@_) };
  97         enable 'ContentLength';
  98         enable Header => set => ['Content-Security-Policy', CONTENT_SECURITY_POLICY];
  99         enable_if { $_[0]->{PATH_INFO} =~ qr,^/static/,} Header => set => ['Cache-Control', 'public, max-age=604800'];
 100         enable 'Static', path => qr,^/static/,;
 101         enable 'Log4perl', category => 'plack';
 102         enable \&require_admin;
 103         enable_if \&some_auth_required, 'Auth::Basic', authenticator => \&authenticate, realm => 'Gruntmaster 6000';
 104         enable \&mangle_request;
 105         enable sub { my $app = $_[0]; sub { $_[0]->{'gruntmaster.dbic'} = $db; $app->($_[0]) } };
 106         Plack::App::Gruntmaster->to_app
 107 }