app.psgi

   1 #!/usr/bin/perl -w
   2 use v5.14;
   3 no if $] >= 5.017011, warnings => 'experimental::smartmatch';
   4
   5 use Apache2::Authen::Passphrase qw/pwcheck/;
   6 use Apache2::AuthzCaps qw/hascaps/;
   7 use Gruntmaster::Data;
   8 use Plack::App::Gruntmaster;
   9 use Plack::Builder;
  10 use Plack::Request;
  11 use Digest::SHA qw/sha256/;
  12 use Log::Log4perl;
  13
  14 use constant ACCESSLOG_FORMAT => '%{X-Forwarded-For}i|%h %u "%r" %>s %b "%{Referer}i" "%{User-agent}i"';
  15 use constant CONTENT_SECURITY_POLICY => q,default-src 'none'; script-src 'self' www.google-analytics.com; style-src 'self'; img-src 'self' www.google-analytics.com; connect-src 'self',;
  16
  17 $Apache2::AuthzCaps::rootdir = $Apache2::Authen::Passphrase::rootdir;
  18 my $word   = qr,(\w+),a;
  19 my $number = qr,(\d+),a;
  20 my $db = Gruntmaster::Data->connect('dbi:Pg:');
  21
  22 sub debug {
  23         local $Log::Log4perl::caller_depth = $Log::Log4perl::caller_depth + 1;
  24         $_[0]->{'psgix.logger'}->({qw/level debug message/ => $_[1]})
  25 }
  26
  27 sub some_auth_required {
  28         my $r = Plack::Request->new($_[0]);
  29         return 1 if $_[0]->{'gruntmaster.reqadmin'} || $r->path eq '/action/passwd' || $r->path eq '/submit';
  30         return 1 if $r->path =~ m,^/ct/$word/pb/$word, && time < $db->contest($1)->stop;
  31         ''
  32 }
  33
  34 sub is_problem_private {
  35         my $pb = $_[0];
  36         return 1 if $db->problem($pb)->private;
  37         my $prv = 0;
  38         for my $cp ($db->problem($pb)->contest_problems) {
  39                 $prv = 1;
  40                 return '' if $cp->contest->start <= time;
  41         }
  42
  43         $prv
  44 }
  45
  46 sub admin_required {
  47         local $_ = $_[0];
  48         my $env = $_[1];
  49         return $db->contest($env->{'gruntmaster.contest'})->owner->id if $env->{'gruntmaster.contest'} && $db->contest($env->{'gruntmaster.contest'})->start > time;
  50         return $db->problem($1)->owner->id if m,^/pb/$word, && is_problem_private $1 || $env->{'gruntmaster.problem'} && is_problem_private $env->{'gruntmaster.problem'};
  51         return $db->job    ($1)->owner->id if m,^/log/(?:src/)?$number, && ($db->job($1)->private || is_problem_private $db->job($1)->problem->id || $db->job($1)->contest && $db->contest($db->job($1)->contest)->stop > time);
  52         ''
  53 }
  54
  55 sub require_admin {
  56         my $app = $_[0];
  57         sub {
  58                 local *__ANON__ = "require_admin_middleware";
  59                 my $env = $_[0];
  60                 my $r = Plack::Request->new($env);
  61                 $env->{'gruntmaster.reqadmin'} = admin_required $r->path, $env;
  62                 $app->($env)
  63         }
  64 }
  65
  66 sub mangle_request {
  67         my $app = $_[0];
  68         sub {
  69                 local *__ANON__ = 'mangle_request_middleware';
  70                 my $env = $_[0];
  71                 my ($number, $word) = (qr,(\d+),a, qr,(\w+),a);
  72                 for ($env->{PATH_INFO}) {
  73                         $env->{'gruntmaster.page'}    = $1 if s,/page/$number$,/,;
  74                         $env->{'gruntmaster.contest'} = $1 if s,^/ct/$word/,/,;
  75                         $env->{'gruntmaster.problem'} = $1 if s,^/pb/$word/,/,;
  76                         $env->{'gruntmaster.user'}    = $1 if s,^/us/$word/,/,;
  77                         $env->{'gruntmaster.page'}  //= -1 if m,^/log/$,;
  78                 }
  79                 $app->($env);
  80         }
  81 }
  82
  83 my %authen_cache;
  84
  85 sub authenticate {
  86         my ($user, $pass, $env) = @_;
  87         my $cache_key = sha256 "$user:$pass";
  88         my $time = $authen_cache{$cache_key} // 0;
  89         if ($time >= time - 300) {
  90                 return 1;
  91         } else {
  92                 delete $authen_cache{$cache_key};
  93         }
  94
  95         return unless eval {
  96                 pwcheck $user, $pass;
  97                 1
  98         };
  99         $authen_cache{$cache_key} = time;
 100
 101         return if $env->{'gruntmaster.reqadmin'} && $env->{'gruntmaster.reqadmin'} ne $user && !hascaps $user, 'gmadm';
 102         1
 103 }
 104
 105 Log::Log4perl->init('log.conf');
 106 my $access_logger = Log::Log4perl->get_logger('access');
 107 $ENV{DBIC_NULLABLE_KEY_NOWARN} = 1;
 108
 109 builder {
 110         enable_if { $_[0]->{PATH_INFO} eq '/ok' } sub { sub{ [200, [], []] }};
 111         enable 'AccessLog', format => ACCESSLOG_FORMAT, logger => sub { $access_logger->info(@_) };
 112         enable 'ContentLength';
 113         enable Header => set => ['Content-Security-Policy', CONTENT_SECURITY_POLICY];
 114         enable_if { $_[0]->{PATH_INFO} =~ qr,^/static/,} Header => set => ['Cache-Control', 'public, max-age=604800'];
 115         enable 'Static', path => qr,^/static/,;
 116         enable 'Log4perl', category => 'plack';
 117         enable \&mangle_request;
 118         enable \&require_admin;
 119         enable_if \&some_auth_required, 'Auth::Basic', authenticator => \&authenticate, realm => 'Gruntmaster 6000';
 120         enable sub { my $app = $_[0]; sub { $_[0]->{'gruntmaster.dbic'} = $db; $app->($_[0]) } };
 121         Plack::App::Gruntmaster->to_app
 122 }