lib/Gruntmaster/Page/Generic.pm

   1 package Gruntmaster::Page::Generic;
   2
   3 use 5.014000;
   4 use strict;
   5 use warnings;
   6 our $VERSION = '5999.000_001';
   7
   8 use Gruntmaster::Page::Base;
   9 use JSON qw/encode_json decode_json/;
  10 use Plack::Request;
  11 use Sub::Name qw/subname/;
  12
  13 use constant PAGE_SIZE => 10;
  14
  15 sub putsym {
  16         my ($key, $value) = @_;
  17         no strict 'refs';
  18         subname $key => $value if ref $value eq 'CODE';
  19         *{"$key"} = $value;
  20 }
  21
  22 sub makepkg {
  23         my ($pkg, $id, $title) = @_;
  24         my $fn = $pkg =~ s,::,/,gr;
  25         return if $INC{"$fn.pm"};
  26         $INC{"$fn.pm"} = 1;
  27         Gruntmaster::Page::Base->import_to($pkg, $id, $title);
  28         1
  29 }
  30
  31 sub list {
  32         my ($thing, $lang, $env) = @_;
  33         my %thing = %$thing;
  34         my %params;
  35         #debug $env => "Contest is $ct";
  36         $thing{makers} //= sub { db(shift)->resultset($thing{rsname}) };
  37         my $rs = $thing{makers}->($env);
  38         $rs = $rs->search(undef, {order_by => 'me.id'}) unless $rs->is_ordered;
  39         if (my $page = $env->{'gruntmaster.page'}) {
  40                 my $pages = int ($rs->count / PAGE_SIZE);
  41                 $page = $pages if $page == -1;
  42                 @params{'page', 'pages'} = ($page, $pages);
  43                 $rs = $rs->search(undef, {offset => ($page - 1) * PAGE_SIZE, ($page == $pages ? () : (rows => PAGE_SIZE))});
  44         }
  45         $rs = $rs->search(undef, {prefetch => $thing{prefetch}}) if exists $thing{prefetch};
  46         my @thing = map +{rs => $_, $_->get_columns}, $rs->all;
  47         @thing = map  { $thing{mangle}->(); $_ } @thing if exists $thing{mangle};
  48         @thing = grep { $thing{choose}->() } @thing if exists $thing{choose};
  49         @thing = sort { $thing{sortby}->() } @thing if exists $thing{sortby};
  50         $thing{group} //= sub { $thing{id} };
  51         for (@thing) {
  52                 my $group = $thing{group}->();
  53                 $params{$group} //= [];
  54                 push $params{$group}, $_
  55         }
  56         wantarray ? %params : \%params
  57 }
  58
  59 sub entry {
  60         my ($thing, $lang, $env, $id) = @_;
  61         my %thing = %$thing;
  62         debug $env => "Rsname is $thing{rsname} and id is $id";
  63         $thing{makers} //= sub { db(shift)->resultset($thing{rsname}) };
  64         my %params = map {+ rs => $_, $_->get_columns } $thing{makers}->($env)->find($id);
  65         $thing{mangle}->(local $_ = \%params) if exists $thing{mangle};
  66         wantarray ? %params : \%params
  67 }
  68
  69 sub headers ($) { ['Content-Type' => 'application/json', 'Cache-Control' => 'max-age=' . $_[0]->max_age] }
  70
  71 sub create_thing {
  72         my %thing = @_;
  73         my $ucid = ucfirst $thing{id};
  74         my $pkg = "Gruntmaster::Page::$ucid";
  75
  76         putsym "${pkg}::_generate", sub { $_[1]->param(list \%thing, @_[2..$#_]) } if makepkg $pkg, @thing{qw/id title/};
  77         putsym "${pkg}::Entry::_generate",  sub { $_[1]->param(entry \%thing, @_[2..$#_]) } if makepkg "${pkg}::Entry", "$thing{id}_entry", $thing{entry_title} // '<tmpl_var name>';
  78         putsym "${pkg}::Read::generate", sub { [200, headers shift, [encode_json list \%thing, @_]] } if makepkg "${pkg}::Read";
  79         putsym "${pkg}::Entry::Read::generate", sub { [200, headers shift, [encode_json entry \%thing, @_]] } if makepkg "${pkg}::Entry::Read";
  80 }
  81
  82 sub params;
  83 sub makers (&);
  84 sub choose (&);
  85 sub sortby (&);
  86 sub group  (&);
  87 sub mangle (&);
  88 sub prefetch;
  89
  90 sub thing (&){
  91         my %thing;
  92         no strict 'refs';
  93         local *{"params"} = sub { @thing{qw/id rsname title entry_title/} = @_ };
  94         local *{"choose"} = sub { $thing{choose} = shift };
  95         local *{"sortby"} = sub { $thing{sortby} = shift };
  96         local *{"mangle"} = sub { $thing{mangle} = shift };
  97         local *{"group"} = sub { $thing{group} = shift };
  98         local *{"makers"} = sub { $thing{makers} = shift };
  99         local *{"prefetch"} = sub { $thing{prefetch} = \@_ };
 100         use strict 'refs';
 101
 102         shift->();
 103         create_thing %thing
 104 }
 105
 106 ##################################################
 107
 108 thing {
 109         params qw/us User Users/;
 110         choose { $_->{name} =~ /\w/ };
 111         sortby { lc $a->{name} cmp lc $b->{name} };
 112 };
 113
 114 thing {
 115         params qw/pb Problem Problems/;
 116         prefetch 'owner';
 117         makers {
 118                 my $env = $_[0];
 119                 my $db = db $env;
 120                 return $db->problems->search({owner => $env->{'gruntmaster.user'}}) if exists $env->{'gruntmaster.user'};
 121                 return $db->problems->search({'contest_problems.contest' => $env->{'gruntmaster.contest'}}, {join => 'contest_problems'}) if exists $env->{'gruntmaster.contest'};
 122                 $db->problems->search({-or => ['contest_problems.contest' => undef, 'contest.stop' => {'<=', time}], 'me.private' => 0}, {join => {'contest_problems' => 'contest'}});
 123         };
 124         sortby { $a->{name} cmp $b->{name}};
 125         group { $_->{level} };
 126         mangle {
 127                 my $env = shift;
 128                 $_->{owner_name} = $_->{rs}->owner->name;
 129                 $_->{cansubmit} = $env->{'gruntmaster.contest'} ? time < db($env)->contest($env->{'gruntmaster.contest'})->stop : 1;
 130                 eval {
 131                         db($env)->open->create({
 132                                 contest => $env->{'gruntmaster.contest'},
 133                                 problem => $_->{id},
 134                                 owner   => $env->{REMOTE_USER},
 135                         })
 136                 } if $env->{'gruntmaster.contest'} && time >= db($env)->contest($env->{'gruntmaster.contest'})->start;
 137         };
 138 };
 139
 140 thing {
 141         params qw/ct Contest Contests/;
 142         prefetch 'owner';
 143         sortby { $b->{start} <=> $a->{start} };
 144         group { time < $_->{start} ? 'pending' : time > $_->{stop} ? 'finished' : 'running' };
 145         mangle { $_->{started} = time >= $_->{start}; $_->{owner_name} =  $_->{rs}->owner->name };
 146 };
 147
 148 thing {
 149         params qw/log Job/, 'Job log', 'Job <tmpl_var id>';
 150         prefetch 'owner', 'problem';
 151         makers {
 152                 my $env = $_[0];
 153                 my $db = db $env;
 154                 return $db->jobs->search({'me.owner' => $env->{'gruntmaster.user'}}) if exists $env->{'gruntmaster.user'};
 155                 return $db->jobs->search({problem => $env->{'gruntmaster.problem'}}) if exists $env->{'gruntmaster.problem'};
 156                 $db->jobs->search({contest => $env->{'gruntmaster.contest'}})
 157         };
 158         sortby { $b->{id} <=> $a->{id}};
 159         mangle {
 160                 $_->{results} &&= decode_json $_->{results};
 161                 $_->{owner_name} = $_->{rs}->owner->name;
 162                 $_->{problem_name} = $_->{rs}->problem->name;
 163                 $_->{size} = length $_->{source};
 164                 delete $_->{source};
 165         }
 166 };
 167
 168 putsym 'Gruntmaster::Page::Pb::Entry::vary',    sub { 'Authorization' };
 169 putsym 'Gruntmaster::Page::Pb::Entry::max_age', sub { 600 };
 170
 171 1