lib/Plack/App/Gruntmaster.pm

   1 package Plack::App::Gruntmaster;
   2
   3 use 5.014000;
   4 use strict;
   5 our $VERSION = '5999.000_001';
   6
   7 use CSS::Minifier::XS;
   8 use Encode qw/encode decode/;
   9 use File::Slurp qw/read_file/;
  10 use JavaScript::Minifier::XS;
  11 use JSON::MaybeXS qw/encode_json/;
  12 use PerlX::Maybe;
  13 use Scope::Upper qw/unwind SUB UP/;
  14 use Web::Simple;
  15
  16 use Gruntmaster::Data;
  17 use Plack::App::Gruntmaster::HTML;
  18
  19 use warnings NONFATAL => 'all';
  20 no warnings 'illegalproto';
  21 no if $] >= 5.017011, warnings => 'experimental::smartmatch';
  22
  23 ##################################################
  24
  25 use constant USER_REGEX => qr/^\w{2,20}$/a;
  26
  27 use constant CONTENT_TYPES => +{
  28         c => 'text/x-csrc',
  29         cpp => 'text/x-c++src',
  30         cs => 'text/x-csharp', # Used by GNOME. Not in mime.types.
  31         go => 'text/plain', # ?
  32         hs => 'text/x-haskell',
  33         java => 'text/x-java',
  34         pas => 'text/x-pascal',
  35         pl => 'text/x-perl',
  36         py => 'text/x-python',
  37 };
  38
  39 use constant FORMAT_EXTENSION => {
  40         C => 'c',
  41         CPP => 'cpp',
  42         GCCGO => 'go',
  43         GOLANG => 'go',
  44         HASKELL => 'hs',
  45         MONO => 'cs',
  46         JAVA => 'java',
  47         PASCAL => 'pas',
  48         PERL => 'pl',
  49         PYTHON => 'py',
  50 };
  51
  52 use constant NOT_FOUND => [404, ['Content-Type' => 'text/plain'], ['Not found']];
  53 use constant FORBIDDEN => [401, ['Content-Type' => 'text/plain', 'WWW-Authenticate' => 'Basic realm="Gruntmaster 6000"'], ['Forbidden']];
  54
  55 my $env;
  56
  57 sub db { $env->{'gruntmaster.dbic'} }
  58
  59 sub remote_user {
  60         my $user = $env->{'gruntmaster.user'};
  61         $user &&= db->user($user);
  62         $user
  63 }
  64
  65 sub admin   { remote_user && remote_user->admin }
  66 sub contest { db->contest ($_{contest}) }
  67 sub problem { db->problem ($_{problem}) }
  68 sub job     { db->job     ($_{job})     }
  69 sub user    { db->user    ($_{user})    }
  70
  71 sub redirect { [301, ['X-Forever' => 1, 'Location' => $_[0]], []] }
  72 sub reply    { [200, ['Content-Type' => 'text/plain'], \@_] }
  73 sub response {
  74         my ($template, $title, $params) = @_;
  75         unless ($params) {
  76                 $params = $title;
  77                 $title = 'No title';
  78         }
  79         $params->{time} = time;
  80         bless {template => $template, title => $title, params => $params}, __PACKAGE__.'::Response'
  81 }
  82
  83 sub forbid   {
  84         return if !shift || admin;
  85         unwind FORBIDDEN, SUB UP
  86 }
  87
  88 sub dispatch_request{
  89         $env = $_[PSGI_ENV];
  90         sub (GET) {
  91                 sub (/css/:theme) {
  92                         my $theme = $_{theme};
  93                         return NOT_FOUND unless -e "css/themes/$theme.css";
  94                         my $css = read_file "css/themes/$theme.css";
  95                         $css .= read_file $_ for <css/*.css>;
  96                         my @headers = ('X-Forever' => 1, 'Cache-Control' => 'public, max-age=604800', 'Content-Type' => 'text/css');
  97                         [200, \@headers, [CSS::Minifier::XS::minify $css]]
  98                 },
  99
 100                 sub (/js.js) {
 101                         my $js;
 102                         $js .= read_file $_ for <js/*.js>;
 103                         my @headers = ('X-Forever' => 1, 'Cache-Control' => 'public, max-age=604800', 'Content-Type' => 'application/javascript');
 104                         [200, \@headers, [JavaScript::Minifier::XS::minify $js]]
 105                 },
 106
 107                 sub (/src/:job) {
 108                         return NOT_FOUND if !job;
 109                         forbid job->private || job->problem->private || job->contest && job->contest->private;
 110                         my @headers = ('X-Forever' => 1, 'Cache-Control' => 'public, max-age=604800', 'Content-Type' => CONTENT_TYPES->{job->format});
 111                         [200, \@headers, [job->source]]
 112                 },
 113
 114                 sub (?:contest=) {
 115                         return NOT_FOUND if !contest;
 116                         forbid contest->is_pending;
 117                         response_filter { return shift }
 118                 },
 119
 120                 sub (?:problem=) {
 121                         return NOT_FOUND if !problem;
 122                         forbid problem->is_private;
 123                         response_filter { return shift }
 124                 },
 125
 126                 sub () {
 127                         response_filter {
 128                                 my ($r) = @_;
 129                                 return $r if ref $r ne 'Plack::App::Gruntmaster::Response';
 130                                 return [200, ['Content-Type' => 'application/json', 'X-Forever' => 1], [encode 'UTF-8', encode_json $r->{params}]] if $env->{HTTP_ACCEPT} =~ m,^\s*application/json\s*$,g;
 131                                 my $ret = render $r->{template}, 'en', title => $r->{title}, %{$r->{params}};
 132                                 [200, ['Content-Type' => 'text/html'], [encode 'UTF-8', $ret]]
 133                         },
 134                 },
 135
 136                 sub (/st/) {
 137                         response st => 'Standings', { st => [db->standings] }
 138                 },
 139
 140                 sub (/st/:contest) {
 141                         response st => 'Standings', {
 142                                 st => [ db->standings($_{contest}) ],
 143                                 problems => [map { $_->problem } contest->contest_problems]
 144                         }
 145                 },
 146
 147                 sub (/ct/:contest/log/st) { redirect "/st/$_{contest}" },
 148
 149                 sub (/us/)                                        { response us => 'Users', {us => db->user_list} },
 150                 sub (/ct/  + ?:owner~)                            { response ct => 'Contests', db->contest_list(%_) },
 151                 sub (/log/ + ?:contest~&:owner~&:page~&:problem~) { response log => 'Job list', {%{db->job_list(%_)}, maybe contest => $_{contest}} },
 152                 sub (/pb/  + ?:owner~&:contest~)                  { response pb => 'Problems', {%{db->problem_list(%_)}, maybe contest => $_{contest}} },
 153
 154                 sub (/us/:user)    { response us_entry => user->name, db->user_entry($_{user}) },
 155                 sub (/ct/:contest) { response ct_entry => contest->name, db->contest_entry($_{contest}) },
 156                 sub (/log/:job)    { response log_entry => "Job  $_{job}", db->job_entry($_{job}) },
 157                 sub (/pb/:problem + ?contest~) {
 158                         my (undef, undef, $contest) = @_;
 159                         $_{contest} = $contest;
 160                         return NOT_FOUND if !contest && !problem->is_in_archive || contest && !db->contest_problems->find($_{contest}, $_{problem});
 161                         forbid problem->is_private;
 162                         response pb_entry => problem->name, db->problem_entry($_{problem}, $_{contest}, remote_user && remote_user->id);
 163                 },
 164                 sub (/sol/:problem) {
 165                         forbid !problem->is_in_archive;
 166                         response sol => 'Solution of ' . problem->name, {solution => db->problem($_{problem})->solution};
 167                 },
 168
 169                 sub (/) { redispatch_to '/index' },
 170                 sub (/:article) { [200, ['Content-Type' => 'text/html'], [render_article $_{article}, 'en']] }
 171         },
 172
 173         sub (POST) {
 174                 sub (/action/register + %:username=&:password=&:confirm_password=&:name=&:email=&:phone=&:town=&:university=&:level=) {
 175                         return reply 'Parameter too long' if grep { length > 200 } values %_;
 176                         return reply 'Bad username. Allowed characters are letters, digits and underscores, and the username must be between 2 and 20 characters long.' unless $_{username} =~ USER_REGEX;
 177                         return reply 'Username already in use' if db->user($_{username});
 178                         return reply 'The two passwords do not match' unless $_{password} eq $_{confirm_password};
 179
 180                         db->users->create({id => $_{username}, name => $_{name}, email => $_{email}, phone => $_{phone}, town => $_{town}, university => $_{university}, level => $_{level}});
 181                         db->user($_{username})->set_passphrase($_{password});
 182
 183                         reply 'Registered successfully';
 184                 },
 185
 186                 sub (/action/passwd + %:password=&:new_password=&:confirm_new_password=) {
 187                         forbid !remote_user;
 188                         return reply 'Incorrect password' unless remote_user->check_passphrase($_{password});
 189                         return reply 'The two passwords do not match' unless $_{new_password} eq $_{confirm_new_password};
 190                         remote_user->set_passphrase($_{new_password});
 191                         reply 'Password changed successfully';
 192                 },
 193
 194                 sub (/action/submit + %:problem=&:contest~&:prog_format=&:private~&:source_code~ + *:prog~) {
 195                         forbid !remote_user;
 196                         return reply 'This contest has finished' if contest && contest->is_finished;
 197                         return reply 'This contest has not yet started' if !admin && contest && contest->is_pending;
 198                         return reply 'Maximum source size is 10KB' if ($_{prog} ? $_{prog}->size : length $_{source_code}) > 10 * 1024;
 199                         return reply 'You must wait 30 seconds between jobs' if !admin && time <= remote_user->lastjob + 30;
 200                         remote_user->update({lastjob => time});
 201
 202                         my $prog = $_{prog} ? read_file $_{prog}->path : $_{source_code};
 203                         unlink $_{prog}->path if $_{prog};
 204                         db->jobs->create({
 205                                 maybe contest => $_{contest},
 206                                 maybe private => $_{private},
 207                                 date => time,
 208                                 extension => FORMAT_EXTENSION->{$_{prog_format}},
 209                                 format => $_{prog_format},
 210                                 problem => $_{problem},
 211                                 source => $prog,
 212                                 owner => remote_user->id,
 213                         });
 214
 215                         redirect $_{contest} ? "/log/?contest=$_{contest}" : '/log/';
 216                 }
 217         }
 218 }
 219
 220
 221 1;
 222 __END__