lib/Plack/App/Gruntmaster/HTML.pm

   1 package Plack::App::Gruntmaster::HTML;
   2 use v5.14;
   3 use parent qw/Exporter/;
   4 our @EXPORT = qw/render render_article/;
   5
   6 use File::Slurp qw/read_file/;
   7 use HTML::Element::Library;
   8 use HTML::TreeBuilder;
   9 use POSIX qw//;
  10 use Data::Dumper qw/Dumper/;
  11
  12 sub ftime ($)   { POSIX::strftime '%c', localtime shift }
  13 sub literal ($) {
  14         my ($html) = @_;
  15         return unless $html;
  16         my $b = HTML::TreeBuilder->new;
  17         $b->ignore_unknown(0);
  18         $b->parse($html);
  19         HTML::Element::Library::super_literal $b->guts->as_HTML;
  20 }
  21
  22 sub HTML::Element::edit_href {
  23         my ($self, $sub) = @_;
  24         local $_ = $self->attr('href');
  25         $sub->();
  26         $self->attr(href => $_);
  27 }
  28
  29 sub HTML::Element::iter3 {
  30         my ($self, $data, $code) = @_;
  31         my $orig = $self;
  32         my $prev = $orig;
  33         for my $el (@$data) {
  34                 my $current = $orig->clone;
  35                 $code->($el, $current);
  36                 $prev->postinsert($current);
  37                 $prev = $current;
  38         }
  39         $orig->detach;
  40 }
  41
  42 sub HTML::Element::fid    { shift->look_down(id    => shift) }
  43 sub HTML::Element::fclass { shift->look_down(class => qr/\b$_[0]\b/) }
  44
  45 sub HTML::Element::namedlink {
  46         my ($self, $id, $name) = @_;
  47         $name = $id unless $name =~ /[[:graph:]]/;
  48         $self = $self->find('a');
  49         $self->edit_href(sub {s/id/$id/});
  50         $self->replace_content($name);
  51 }
  52
  53 my %page_cache;
  54 for (<tmpl/*>) {
  55         my ($tmpl, $lang) = m,tmpl/(\w+)\.(\w+),;
  56         my $builder = HTML::TreeBuilder->new;
  57         $builder->ignore_unknown(0);
  58         $page_cache{$tmpl, $lang} = $builder->parse_file($_);
  59 }
  60
  61 sub render {
  62         my ($tmpl, $lang, %args) = @_;
  63         $lang //= 'en';
  64         my $meat = _render($tmpl, $lang, %args);
  65         _render('skel', $lang, %args, meat => $meat)
  66 }
  67
  68 sub render_article {
  69         my ($art, $lang, %args) = @_;
  70         $lang //= 'en';
  71         my $title = read_file "a/$art.$lang.title";
  72         my $meat  = read_file "a/$art.$lang";
  73         _render('skel', $lang, title => $title , meat => $meat, %args)
  74 }
  75
  76 sub _render {
  77         my ($tmpl, $lang, %args) = @_;
  78         my $tree = $page_cache{$tmpl, $lang}->clone or die "No such template/language combination: $tmpl/$lang\n";
  79         $tree = $tree->guts unless $tmpl eq 'skel';
  80         $tree->defmap(smap => \%args);
  81         my $process = __PACKAGE__->can("process_$tmpl");
  82         $process->($tree, %args) if $process;
  83         $_->detach for $tree->look_down(static => $args{static} ? 'no' : 'yes');
  84         $_->attr('static', undef) for $tree->look_down(sub {$_[0]->attr('static')});
  85         $_->attr('smap', undef) for $tree->look_down(sub {$_[0]->attr('smap')});
  86         $tree->as_HTML;
  87 }
  88
  89 my $logo = read_file 'mclogo.svg';
  90 $logo =~ y/\n//d;
  91 $logo =~ s/(\s+)/ /g;
  92
  93 sub process_skel {
  94         my ($tree, %args) = @_;
  95         $tree->fid('logo')->replace_with(HTML::Element::Library::super_literal $logo);
  96         $tree->content_handler(
  97                 title   =>         $args{title},
  98                 content => literal $args{meat});
  99 }
 100
 101 sub process_us_entry {
 102         my ($tree, %args) = @_;
 103         $tree->fid($_)->attr('href', "/$_/?owner=$args{id}") for qw/log pb/;
 104         $tree->fid('track_user')->attr('data-user', $args{id});
 105         my @solved = map { $_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
 106         my @attempted = map { !$_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
 107
 108         my $pbiter = sub {
 109                 my ($data, $li) = @_;
 110                 $li->find('a')->namedlink($data);
 111         };
 112         $tree->fid('solved')->find('li')->iter3(\@solved, $pbiter);
 113         $tree->fid('attempted')->find('li')->iter3(\@attempted, $pbiter);
 114         $tree->fid('solved_count')->replace_content(scalar @solved);
 115         $tree->fid('attempted_count')->replace_content(scalar @attempted);
 116
 117         my $ctiter = sub {
 118                 my ($data, $td) = @_;
 119                 $td->fclass('contest')->namedlink($data->{contest}, $data->{contest_name});
 120                 $td->fclass('score')->replace_content($data->{score});
 121                 $td->fclass('rank')->replace_content($data->{rank});
 122         };
 123         $tree->find('table')->find('tbody')->find('tr')->iter3($args{contests}, $ctiter);
 124 }
 125
 126 sub process_us {
 127         my ($tree, %args) = @_;
 128         my $iter = sub {
 129                 my ($data, $tr) = @_;
 130                 $tr->fclass('user')->namedlink($data->{id}, $data->{name});
 131                 $tr->fclass($_)->replace_content($data->{$_}) for qw/solved attempted contests/;
 132         };
 133         $tree->find('tbody')->find('tr')->iter3($args{us}, $iter);
 134 }
 135
 136 sub process_ct_entry {
 137         my ($tree, %args) = @_;
 138         $_->edit_href (sub {s/contest_id/$args{id}/}) for $tree->find('a');
 139         $tree->fid('editorial')->detach unless $args{finished};
 140         $tree->fid('links')->detach unless $args{started};
 141         my $status = ($args{time} < $args{start} ? 'starts' : 'ends');
 142         $tree->fclass('timer')->attr('data-stop', $status eq 'ends' ? $args{stop} : $args{start});
 143         $tree->content_handler(
 144                 start       => ftime   $args{start},
 145                 stop        => ftime   $args{stop},
 146                 status      => $status,
 147                 description => literal $args{description});
 148         $tree->fid('ctcountdown')->detach if $args{time} >= $args{stop};
 149 }
 150
 151 sub process_ct {
 152         my ($tree, %args) = @_;
 153         my $iter = sub {
 154                 my ($data, $tr) = @_;
 155                 $data->{$_} = ftime $data->{$_} for qw/start stop/;
 156                 $tr->hashmap(class => $data, [qw/name owner/]);
 157                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 158                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 159         };
 160         $args{$_} ? $tree->fid($_)->find('tbody')->find('tr')->iter3($args{$_}, $iter) : $tree->fid($_)->detach for qw/running pending finished/;
 161 }
 162
 163 sub process_pb_entry {
 164         my ($tree, %args) = @_;
 165         $tree->fid('owner')->edit_href(sub{s/owner_id/$args{owner}/});
 166         $tree->fid('job_log')->edit_href(sub{s/problem_id/$args{id}/});
 167         $tree->fid('solution')->edit_href(sub{s/problem_id/$args{id}/});
 168         $tree->content_handler(
 169                 statement => literal $args{statement},
 170                 level     => ucfirst $args{level},
 171                 author    =>         $args{author},
 172                 owner     =>         $args{owner_name} || $args{owner});
 173         if ($args{limits}) {
 174                 my @limits = (@{$args{limits}}, {format => 'Other', timeout => $args{timeout} });
 175                 @limits = map { sprintf '%s (%s)', @{$_}{qw/timeout format/} } @limits;
 176                 $tree->look_down(smap => 'timeout')->replace_content(join ', ', @limits);
 177         }
 178         if ($args{contest_stop}) {
 179                 $tree->fid('solution')->detach;
 180                 $tree->fid('solution_modal')->detach;
 181                 $tree->fid('score')->replace_content($args{value});
 182                 $tree->fid('countdown')->attr('data-stop' => $args{contest_stop});
 183         } else {
 184                 $tree->fid('job_log')->edit_href(sub{$_ .= "&private=$args{private}"}) if $args{private};
 185                 $tree->fid('solution')->detach unless $args{solution};
 186                 $_->detach for $tree->fclass('rc'); # requires contest
 187                 $tree->fid('solution_modal')->fclass('modal-body')->replace_content(literal $args{solution});
 188         }
 189         if ($args{cansubmit}) {
 190                 $tree->fid('nosubmit')->detach;
 191                 $tree->look_down(name => 'problem')->attr(value => $args{id});
 192                 my $contest = $tree->look_down(name => 'contest');
 193                 $contest->attr(value => $args{args}{contest}) if $args{args}{contest};
 194                 $contest->detach unless $args{args}{contest}
 195         } else {
 196                 $tree->fid('nosubmit')->find('a')->edit_href(sub{s/id/$args{id}/});
 197                 $tree->fid('submit')->detach
 198         }
 199 }
 200
 201 sub process_sol {
 202         my ($tree, %args) = @_;
 203         $tree->content_handler(solution => literal $args{solution});
 204 }
 205
 206 sub process_pb {
 207         my ($tree, %args) = @_;
 208         my $titer = sub {
 209                 my ($data, $tr) = @_;
 210                 $tr->set_child_content(class => 'author', $data->{author});
 211                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 212                 $tr->fclass('name')->find('a')->edit_href(sub {$_ .= "?contest=$args{contest}"}) if $args{contest};
 213                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 214                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private} && !$args{contest};
 215         };
 216         my $iter = sub {
 217                 my ($data, $div) = @_;
 218                 $div->attr(id => $data);
 219                 $div->find('h2')->replace_content(ucfirst $data);
 220                 $div->find('tbody')->find('tr')->iter3($args{$data}, $titer);
 221         };
 222         $tree->fid('beginner')->iter3([grep {$args{$_}} qw/beginner easy medium hard/], $iter);
 223         $tree->fid('open-alert')->detach unless $args{contest};
 224 }
 225
 226 sub process_log_entry {
 227         my ($tree, %args) = @_;
 228         $tree->fid('problem')->namedlink(@args{qw/problem problem_name/});
 229         $tree->fid('owner')->namedlink(@args{qw/owner owner_name/});
 230         $tree->fid('source')->namedlink("$args{id}.$args{extension}", sprintf '%.2fKB', $args{size}/1024);
 231         if ($args{contest}) {
 232                 $tree->fid('contest')->namedlink(@args{qw/contest contest_name/});
 233                 $tree->fid('problem')->find('a')->edit_href(sub {$_.="?contest=$args{contest}"});
 234         } else {
 235                 $tree->fid('contest')->left->detach;
 236                 $tree->fid('contest')->detach;
 237         }
 238
 239         $args{errors} ? $tree->fid('errors')->find('pre')->replace_content($args{errors}) : $tree->fid('errors')->detach;
 240         my $iter = sub {
 241                 my ($data, $tr) = @_;
 242                 $data->{time} = sprintf '%.4fs', $data->{time};
 243                 $tr->defmap(class => $data);
 244                 $tr->fclass('result_text')->attr(class => "r$data->{result}")
 245         };
 246         $tree->fclass('result_text')->replace_content($args{result_text});
 247         $tree->fclass('result_text')->attr(class => "r$args{result}");
 248         $args{results} ? $tree->fid('results')->find('tbody')->find('tr')->iter3($args{results}, $iter) : $tree->fid('results')->detach;
 249         $tree->fid('no_results')->detach if $tree->fid('results') || $tree->fid('errors');
 250 }
 251
 252 sub process_log {
 253         my ($tree, %args) = @_;
 254         my $iter = sub {
 255                 my ($data, $tr) = @_;
 256                 $tr->fclass('id')->namedlink($data->{id});
 257                 $tr->fclass('problem')->namedlink($data->{problem}, $data->{problem_name});
 258                 $tr->fclass('problem')->find('a')->edit_href(sub{$_ .= "?contest=$args{args}{contest}"}) if $args{args}{contest};
 259                 $tr->fclass('contest')->namedlink($data->{contest}, $data->{contest_name}) if $data->{contest};
 260                 $tr->fclass('contest')->replace_content('None') unless $data->{contest};
 261                 $tr->fclass('date')->replace_content(ftime $data->{date});
 262                 $tr->fclass('source')->namedlink("$data->{id}.$data->{extension}", sprintf "%.2fKB %s", $data->{size}/1024, Plack::App::Gruntmaster::FORMAT_EXTENSION()->{$data->{format}});
 263                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 264                 $tr->fclass('result_text')->replace_content($data->{result_text});
 265                 $tr->fclass('result_text')->attr(class => "r$data->{result}");
 266                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private};
 267         };
 268         $tree->find('table')->find('tbody')->find('tr')->iter3($args{log}, $iter);
 269         $args{next_page} ? $tree->fclass('next')->namedlink($args{next_page}, 'Next') : $tree->fclass('next')->detach;
 270         $args{previous_page} ? $tree->fclass('previous')->namedlink($args{previous_page}, 'Previous') : $tree->fclass('previous')->detach;
 271         for my $cls (qw/next previous/) {
 272                 my $elem = $tree->fclass($cls);
 273                 next unless $elem;
 274                 delete $args{args}{page};
 275                 my $str = join '&', map { $_ . '=' . $args{args}{$_} } keys %{$args{args}};
 276                 $elem->find('a')->edit_href(sub{s/$/&$str/}) if $str;
 277         }
 278         $tree->fclass('current')->replace_content("Page $args{current_page} of $args{last_page}");
 279
 280         my @detach;
 281         push @detach, $args{args}{$_} ? $tree->fclass($_) : () for qw/problem contest owner/;
 282         $_->detach for @detach;
 283 }
 284
 285 sub process_st {
 286         my ($tree, %args) = @_;
 287         $args{problems} //= [];
 288         my $pbiter = sub {
 289                 my ($data, $th) = @_;
 290                 $th->attr(class => undef);
 291                 $th->namedlink(@$data);
 292                 $th->find('a')->edit_href(sub{s/$/?contest=$args{args}{contest}/});
 293         };
 294         $tree->fclass('problem')->iter3($args{problems}, $pbiter);
 295         my $iter = sub {
 296                 my ($st, $tr) = @_;
 297                 $tr->set_child_content(class => 'rank', $st->{rank});
 298                 $tr->set_child_content(class => 'score', $st->{score});
 299                 $tr->fclass('user')->namedlink($st->{user}, $st->{user_name});
 300                 my $pbscore = $tr->fclass('pbscore');
 301                 $pbscore->iter($pbscore => @{$st->{scores}});
 302         };
 303         $tree->find('tbody')->find('tr')->iter3($args{st}, $iter);
 304 }
 305
 306 sub process_ed {
 307         my ($tree, %args) = @_;
 308         $tree->content_handler(editorial => literal $args{editorial});
 309         my $iter = sub {
 310                 my ($data, $div) = @_;
 311                 $div->set_child_content(class => 'value', $data->{value});
 312                 $div->set_child_content(class => 'solution', literal $data->{solution});
 313                 $div->fclass('problem')->namedlink($data->{id}, $data->{name});
 314         };
 315         my @pb = map { @{$args{$_} // []} } qw/beginner easy medium hard/;
 316         $tree->fclass('well')->iter3(\@pb, $iter);
 317 }
 318
 319 1;
 320 __END__