lib/Plack/App/Gruntmaster/HTML.pm

   1 package Plack::App::Gruntmaster::HTML;
   2 use v5.14;
   3 use parent qw/Exporter/;
   4 our @EXPORT = qw/render render_article/;
   5
   6 use File::Slurp qw/read_file/;
   7 use HTML::Element::Library;
   8 use HTML::TreeBuilder;
   9 use POSIX qw//;
  10 use Data::Dumper qw/Dumper/;
  11 use Sort::ByExample
  12   sorter => {-as => 'pb_sort', example => [qw/beginner easy medium hard/], xform => sub {$_->{level}}},
  13   sorter => {-as => 'ct_sort', example => [qw/Running Pending Finished/], xform => sub {$_->{status}}};
  14
  15 my $optional_end_tags = {%HTML::Tagset::optionalEndTag, tr => 1, td => 1, th => 1};
  16
  17 sub ftime ($)   { POSIX::strftime '%c', localtime shift }
  18 sub literal ($) {
  19         my ($html) = @_;
  20         return '' unless $html;
  21         my $b = HTML::TreeBuilder->new;
  22         $b->ignore_unknown(0);
  23         $b->parse($html);
  24         HTML::Element::Library::super_literal $b->guts->as_HTML(undef, undef, $optional_end_tags);
  25 }
  26
  27 sub HTML::Element::edit_href {
  28         my ($self, $sub) = @_;
  29         local $_ = $self->attr('href');
  30         $sub->();
  31         $self->attr(href => $_);
  32 }
  33
  34 sub HTML::Element::iter3 {
  35         my ($self, $data, $code) = @_;
  36         my $orig = $self;
  37         my $prev = $orig;
  38         for my $el (@$data) {
  39                 my $current = $orig->clone;
  40                 $code->($el, $current);
  41                 $prev->postinsert($current);
  42                 $prev = $current;
  43         }
  44         $orig->detach;
  45 }
  46
  47 sub HTML::Element::fid    { shift->look_down(id    => shift) }
  48 sub HTML::Element::fclass { shift->look_down(class => qr/\b$_[0]\b/) }
  49
  50 sub HTML::Element::namedlink {
  51         my ($self, $id, $name) = @_;
  52         $name = $id unless $name && $name =~ /[[:graph:]]/;
  53         $self = $self->find('a');
  54         $self->edit_href(sub {s/id/$id/});
  55         $self->replace_content($name);
  56 }
  57
  58 my %page_cache;
  59 for (<tmpl/*>) {
  60         my ($tmpl, $lang) = m,tmpl/(\w+)\.(\w+),;
  61         my $builder = HTML::TreeBuilder->new;
  62         $builder->ignore_unknown(0);
  63         $page_cache{$tmpl, $lang} = $builder->parse_file($_);
  64 }
  65
  66 sub render {
  67         my ($tmpl, $lang, %args) = @_;
  68         $lang //= 'en';
  69         my $meat = _render($tmpl, $lang, %args);
  70         my $html = _render('skel', $lang, %args, meat => $meat);
  71         if ($tmpl eq 'pb_entry') { # Move sidebar to correct position
  72                 my $builder = HTML::TreeBuilder->new;
  73                 $builder->ignore_unknown(0);
  74                 my $tree = $builder->parse_content($html);
  75                 $tree->fid('content')->postinsert($tree->fid('sidebar'));
  76                 $html = $tree->as_HTML(undef, undef, $optional_end_tags)
  77         }
  78         $html
  79 }
  80
  81 sub render_article {
  82         my ($art, $lang, %args) = @_;
  83         $lang //= 'en';
  84         my $title = read_file "a/$art.$lang.title";
  85         chomp $title;
  86         my $meat  = read_file "a/$art.$lang";
  87         _render('skel', $lang, title => $title , meat => $meat, %args)
  88 }
  89
  90 sub _render {
  91         my ($tmpl, $lang, %args) = @_;
  92         my $tree = $page_cache{$tmpl, $lang}->clone or die "No such template/language combination: $tmpl/$lang\n";
  93         $tree = $tree->guts unless $tmpl eq 'skel';
  94         $tree->defmap(smap => \%args);
  95         my $process = __PACKAGE__->can("process_$tmpl");
  96         $process->($tree, %args) if $process;
  97         $_->attr('smap', undef) for $tree->look_down(sub {$_[0]->attr('smap')});
  98         $tree->as_HTML(undef, undef, $optional_end_tags);
  99 }
 100
 101 sub process_skel {
 102         my ($tree, %args) = @_;
 103         $tree->content_handler(
 104                 title   =>         $args{title},
 105                 content => literal $args{meat});
 106 }
 107
 108 sub process_us_entry {
 109         my ($tree, %args) = @_;
 110         $tree->fid($_)->attr('href', "/$_/?owner=$args{id}") for qw/log pb/;
 111         $tree->fid('track_user')->attr('data-user', $args{id});
 112         my @solved = map { $_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
 113         my @attempted = map { !$_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
 114
 115         my $pbiter = sub {
 116                 my ($data, $li) = @_;
 117                 $li->find('a')->namedlink($data);
 118         };
 119         $tree->fid('solved')->find('li')->iter3(\@solved, $pbiter);
 120         $tree->fid('attempted')->find('li')->iter3(\@attempted, $pbiter);
 121         $tree->fid('solved_count')->replace_content(scalar @solved);
 122         $tree->fid('attempted_count')->replace_content(scalar @attempted);
 123
 124         my $ctiter = sub {
 125                 my ($data, $td) = @_;
 126                 $td->fclass('contest')->namedlink($data->{contest}, $data->{contest_name});
 127                 $td->fclass('score')->replace_content($data->{score});
 128                 $td->fclass('rank')->replace_content($data->{rank});
 129         };
 130         $tree->find('table')->find('tbody')->find('tr')->iter3($args{contests}, $ctiter);
 131 }
 132
 133 sub process_us {
 134         my ($tree, %args) = @_;
 135         my $iter = sub {
 136                 my ($data, $tr) = @_;
 137                 $tr->fclass('user')->namedlink($data->{id}, $data->{name});
 138                 $tr->fclass($_)->replace_content($data->{$_}) for qw/solved attempted contests/;
 139         };
 140         $tree->find('tbody')->find('tr')->iter3($args{us}, $iter);
 141 }
 142
 143 sub process_ct_entry {
 144         my ($tree, %args) = @_;
 145         $_->edit_href (sub {s/contest_id/$args{id}/}) for $tree->find('a');
 146         $tree->fid('editorial')->detach unless $args{finished};
 147         $tree->fid('links')->detach unless $args{started};
 148         my $status = ($args{time} < $args{start} ? 'starts' : 'ends');
 149         $tree->fclass('timer')->attr('data-stop', $status eq 'ends' ? $args{stop} : $args{start});
 150         $tree->content_handler(
 151                 start       => ftime   $args{start},
 152                 stop        => ftime   $args{stop},
 153                 status      => $status,
 154                 description => literal $args{description});
 155         $tree->fid('ctcountdown')->detach if $args{time} >= $args{stop};
 156 }
 157
 158 sub process_ct {
 159         my ($tree, %args) = @_;
 160         my $iter = sub {
 161                 my ($data, $tr) = @_;
 162                 $data->{$_} = ftime $data->{$_} for qw/start stop/;
 163                 $tr->hashmap(class => $data, [qw/name owner/]);
 164                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 165                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 166         };
 167         $_->{status} = $_->{finished} ? 'Finished' : $_->{started} ? 'Running' : 'Pending' for @{$args{ct}};
 168         $tree->find('tbody')->find('tr')->iter3([ct_sort @{$args{ct}}], $iter);
 169 }
 170
 171 sub process_pb_entry {
 172         my ($tree, %args) = @_;
 173         $tree->fid('owner')->edit_href(sub{s/owner_id/$args{owner}/});
 174         $tree->fid('job_log')->edit_href(sub{s/problem_id/$args{id}/});
 175         $tree->fid('solution')->edit_href(sub{s/problem_id/$args{id}/});
 176         $tree->content_handler(
 177                 statement => literal $args{statement},
 178                 level     => ucfirst $args{level},
 179                 author    =>         $args{author},
 180                 owner     =>         $args{owner_name} || $args{owner});
 181         if ($args{limits}) {
 182                 my @limits = (@{$args{limits}}, {format => 'Other', timeout => $args{timeout} });
 183                 @limits = map { sprintf '%s (%s)', @{$_}{qw/timeout format/} } @limits;
 184                 $tree->look_down(smap => 'timeout')->replace_content(join ', ', @limits);
 185         }
 186         if ($args{contest_stop}) {
 187                 $tree->fid('solution')->detach;
 188                 $tree->fid('solution_modal')->detach;
 189                 my $score = $tree->fid('score');
 190                 $score->attr('data-start' => $args{open_time});
 191                 $score->attr('data-stop'  => $args{contest_stop});
 192                 $score->attr('data-value'  => $args{value});
 193                 $tree->fid('countdown')->attr('data-stop' => $args{contest_stop});
 194         } else {
 195                 $tree->fid('job_log')->edit_href(sub{$_ .= "&private=$args{private}"}) if $args{private};
 196                 $tree->fid('solution')->detach unless $args{solution};
 197                 $_->detach for $tree->fclass('rc'); # requires contest
 198                 $tree->fid('solution_modal')->replace_content(literal $args{solution});
 199         }
 200
 201         $tree->look_down(name => 'problem')->attr(value => $args{id});
 202         my $contest = $tree->look_down(name => 'contest');
 203         $contest->attr(value => $args{args}{contest}) if $args{args}{contest};
 204         $contest->detach unless $args{args}{contest}
 205 }
 206
 207 sub process_sol {
 208         my ($tree, %args) = @_;
 209         $tree->content_handler(solution => literal $args{solution});
 210 }
 211
 212 sub process_pb {
 213         my ($tree, %args) = @_;
 214         my $iter = sub {
 215                 my ($data, $tr) = @_;
 216                 $tr->set_child_content(class => 'author', $data->{author});
 217                 $tr->set_child_content(class => 'level', ucfirst $data->{level});
 218                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 219                 $tr->fclass('name')->find('a')->edit_href(sub {$_ .= "?contest=$args{args}{contest}"}) if $args{args}{contest};
 220                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 221                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private} && !$args{args}{contest};
 222         };
 223
 224         $tree->find('tbody')->find('tr')->iter3([pb_sort @{$args{pb}}], $iter);
 225         $tree->fid('open-alert')->detach unless $args{args}{contest};
 226 }
 227
 228 sub process_log_entry {
 229         my ($tree, %args) = @_;
 230         $tree->fid('problem')->namedlink(@args{qw/problem problem_name/});
 231         $tree->fid('owner')->namedlink(@args{qw/owner owner_name/});
 232         $tree->fid('source')->namedlink("$args{id}.$args{extension}", sprintf '%.2fKB', $args{size}/1024);
 233         if ($args{contest}) {
 234                 $tree->fid('contest')->namedlink(@args{qw/contest contest_name/});
 235                 $tree->fid('problem')->find('a')->edit_href(sub {$_.="?contest=$args{contest}"});
 236         } else {
 237                 $tree->fid('contest')->left->detach;
 238                 $tree->fid('contest')->detach;
 239         }
 240
 241         $args{errors} ? $tree->fid('errors')->find('pre')->replace_content($args{errors}) : $tree->fid('errors')->detach;
 242         my $iter = sub {
 243                 my ($data, $tr) = @_;
 244                 $data->{time} = sprintf '%.4fs', $data->{time};
 245                 $tr->defmap(class => $data);
 246                 $tr->fclass('result_text')->attr(class => "r$data->{result}")
 247         };
 248         $tree->fclass('result_text')->replace_content($args{result_text});
 249         $tree->fclass('result_text')->attr(class => "r$args{result}");
 250         $args{results} ? $tree->fid('results')->find('tbody')->find('tr')->iter3($args{results}, $iter) : $tree->fid('results')->detach;
 251         $tree->fid('no_results')->detach if $tree->fid('results') || $tree->fid('errors');
 252 }
 253
 254 sub process_log {
 255         my ($tree, %args) = @_;
 256         my $iter = sub {
 257                 my ($data, $tr) = @_;
 258                 $tr->fclass('id')->namedlink($data->{id});
 259                 $tr->fclass('problem')->namedlink($data->{problem}, $data->{problem_name});
 260                 $tr->fclass('problem')->find('a')->edit_href(sub{$_ .= "?contest=$args{args}{contest}"}) if $args{args}{contest};
 261                 $tr->fclass('contest')->namedlink($data->{contest}, $data->{contest_name}) if $data->{contest};
 262                 $tr->fclass('contest')->replace_content('None') unless $data->{contest};
 263                 $tr->fclass('date')->replace_content(ftime $data->{date});
 264                 $tr->fclass('source')->namedlink("$data->{id}.$data->{extension}", sprintf "%.2fKB %s", $data->{size}/1024, Plack::App::Gruntmaster::FORMAT_EXTENSION()->{$data->{format}});
 265                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 266                 $tr->fclass('result_text')->replace_content($data->{result_text});
 267                 $tr->fclass('result_text')->attr(class => "r$data->{result}");
 268                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private};
 269         };
 270         $tree->find('table')->find('tbody')->find('tr')->iter3($args{log}, $iter);
 271         $args{next_page} ? $tree->fclass('next')->namedlink($args{next_page}, 'Next') : $tree->fclass('next')->detach;
 272         $args{previous_page} ? $tree->fclass('previous')->namedlink($args{previous_page}, 'Previous') : $tree->fclass('previous')->detach;
 273         for my $cls (qw/next previous/) {
 274                 my $elem = $tree->fclass($cls);
 275                 next unless $elem;
 276                 delete $args{args}{page};
 277                 my $str = join '&', map { $_ . '=' . $args{args}{$_} } keys %{$args{args}};
 278                 $elem->find('a')->edit_href(sub{s/$/&$str/}) if $str;
 279         }
 280         $tree->fclass('current')->replace_content("Page $args{current_page} of $args{last_page}");
 281 }
 282
 283 sub process_st {
 284         my ($tree, %args) = @_;
 285         $args{problems} //= [];
 286         my $pbiter = sub {
 287                 my ($data, $th) = @_;
 288                 $th->attr(class => undef);
 289                 $th->namedlink(@$data);
 290                 $th->find('a')->edit_href(sub{s/$/?contest=$args{args}{contest}/});
 291         };
 292         $tree->fclass('problem')->iter3($args{problems}, $pbiter);
 293         my $iter = sub {
 294                 my ($st, $tr) = @_;
 295                 $tr->set_child_content(class => 'rank', $st->{rank});
 296                 $tr->set_child_content(class => 'score', $st->{score});
 297                 $tr->fclass('user')->namedlink($st->{user}, $st->{user_name});
 298                 my $pbscore = $tr->fclass('pbscore');
 299                 $pbscore->iter($pbscore => @{$st->{scores}});
 300         };
 301         $tree->find('tbody')->find('tr')->iter3($args{st}, $iter);
 302 }
 303
 304 sub process_ed {
 305         my ($tree, %args) = @_;
 306         $tree->content_handler(editorial => literal $args{editorial});
 307         my $iter = sub {
 308                 my ($data, $div) = @_;
 309                 $div->set_child_content(class => 'value', $data->{value});
 310                 $div->set_child_content(class => 'solution', literal $data->{solution});
 311                 $div->fclass('problem')->namedlink($data->{id}, $data->{name});
 312         };
 313         my @pb = sort { $a->{value} <=> $b->{value} } @{$args{pb}};
 314         $tree->fclass('well')->iter3(\@pb, $iter);
 315 }
 316
 317 1;
 318 __END__