lib/Plack/App/Gruntmaster/HTML.pm

   1 package Plack::App::Gruntmaster::HTML;
   2 use v5.14;
   3 use parent qw/Exporter/;
   4 our @EXPORT = qw/render render_article/;
   5
   6 use File::Slurp qw/read_file/;
   7 use HTML::Seamstress;
   8 use POSIX qw//;
   9 use Data::Dumper qw/Dumper/;
  10
  11 sub ftime ($)   { POSIX::strftime '%c', localtime shift }
  12 sub literal ($) { HTML::Element::Library::super_literal shift // '' }
  13
  14 sub HTML::Element::edit_href {
  15         my ($self, $sub) = @_;
  16         local $_ = $self->attr('href');
  17         $sub->();
  18         $self->attr(href => $_);
  19 }
  20
  21 sub HTML::Element::iter3 {
  22         my ($self, $data, $code) = @_;
  23         my $orig = $self;
  24         my $prev = $orig;
  25         for my $el (@$data) {
  26                 my $current = $orig->clone;
  27                 $code->($el, $current);
  28                 $prev->postinsert($current);
  29                 $prev = $current;
  30         }
  31         $orig->detach;
  32 }
  33
  34 sub HTML::Element::fid    { shift->look_down(id    => shift) }
  35 sub HTML::Element::fclass { shift->look_down(class => qr/\b$_[0]\b/) }
  36
  37 sub HTML::Element::namedlink {
  38         my ($self, $id, $name) = @_;
  39         $name = $id unless $name =~ /[[:graph:]]/;
  40         $self = $self->find('a');
  41         $self->edit_href(sub {s/id/$id/});
  42         $self->replace_content($name);
  43 }
  44
  45 sub render {
  46         my ($tmpl, $lang, %args) = @_;
  47         $lang //= 'en';
  48         my $meat = _render($tmpl, $lang, %args);
  49         _render('skel', $lang, %args, meat => $meat)
  50 }
  51
  52 sub render_article {
  53         my ($art, $lang) = @_;
  54         $lang //= 'en';
  55         my $title = read_file "a/$art.$lang.title";
  56         my $meat  = read_file "a/$art.$lang";
  57         _render('skel', $lang, title => $title , meat => $meat)
  58 }
  59
  60 sub _render {
  61         my ($tmpl, $lang, %args) = @_;
  62         my $builder = HTML::Seamstress->new;
  63         $builder->ignore_unknown(0);
  64         my $tree = $builder->parse_file("tmpl/$tmpl.$lang");
  65         $tree = $tree->guts unless $tmpl eq 'skel';
  66         $tree->defmap(smap => \%args);
  67         my $process = __PACKAGE__->can("process_$tmpl");
  68         $process->($tree, %args) if $process;
  69         $tree->as_HTML;
  70 }
  71
  72 sub process_skel {
  73         my ($tree, %args) = @_;
  74         $tree->content_handler(
  75                 title   =>         $args{title},
  76                 content => literal $args{meat});
  77 }
  78
  79 sub process_us_entry {
  80         my ($tree, %args) = @_;
  81         $tree->fid($_)->attr('href', "/$_/?owner=$args{id}") for qw/log pb/;
  82         $tree->fid('track_user')->attr('data-user', $args{id});
  83         my @solved = map { $_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
  84         my @attempted = map { !$_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
  85
  86         my $pbiter = sub {
  87                 my ($data, $li) = @_;
  88                 $li->find('a')->namedlink($data);
  89         };
  90         $tree->fid('solved')->find('li')->iter3(\@solved, $pbiter);
  91         $tree->fid('attempted')->find('li')->iter3(\@attempted, $pbiter);
  92         $tree->fid('solved_count')->replace_content(scalar @solved);
  93         $tree->fid('attempted_count')->replace_content(scalar @attempted);
  94
  95         my $ctiter = sub {
  96                 my ($data, $td) = @_;
  97                 $td->fclass('contest')->namedlink($data->{contest}, $data->{contest_name});
  98                 $td->fclass('score')->replace_content($data->{score});
  99                 $td->fclass('rank')->replace_content($data->{rank});
 100         };
 101         $tree->find('table')->find('tbody')->find('tr')->iter3($args{contests}, $ctiter);
 102 }
 103
 104 sub process_us {
 105         my ($tree, %args) = @_;
 106         my $iter = sub {
 107                 my ($data, $tr) = @_;
 108                 $tr->fclass('user')->namedlink($data->{id}, $data->{name});
 109                 $tr->fclass($_)->replace_content($data->{$_}) for qw/solved attempted contests/;
 110         };
 111         $tree->find('tbody')->find('tr')->iter3($args{us}, $iter);
 112 }
 113
 114 sub process_ct_entry {
 115         my ($tree, %args) = @_;
 116         $_->edit_href (sub {s/contest_id/$args{id}/}) for $tree->find('a');
 117         $tree->fid('links')->detach unless $args{started};
 118         my $status = ($args{time} < $args{start} ? 'starts' : 'ends');
 119         $tree->fclass('timer')->attr('data-stop', $status eq 'ends' ? $args{stop} : $args{start});
 120         $tree->content_handler(
 121                 start       => ftime   $args{start},
 122                 stop        => ftime   $args{stop},
 123                 status      => $status,
 124                 description => literal $args{description});
 125 }
 126
 127 sub process_ct {
 128         my ($tree, %args) = @_;
 129         my $iter = sub {
 130                 my ($data, $tr) = @_;
 131                 $data->{$_} = ftime $data->{$_} for qw/start stop/;
 132                 $tr->hashmap(class => $data, [qw/name owner/]);
 133                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 134                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 135         };
 136         $args{$_} ? $tree->fid($_)->find('tbody')->find('tr')->iter3($args{$_}, $iter) : $tree->fid($_)->detach for qw/running pending finished/;
 137 }
 138
 139 sub process_pb_entry {
 140         my ($tree, %args) = @_;
 141         $tree->fid('owner')->edit_href(sub{s/owner_id/$args{owner}/});
 142         $tree->fid('job_log')->edit_href(sub{s/problem_id/$args{id}/});
 143         $tree->fid('solution')->edit_href(sub{s/problem_id/$args{id}/});
 144         $tree->fid('job_log')->edit_href(sub{$_ .= "&private=$args{private}"}) if $args{private};
 145         $tree->content_handler(
 146                 statement => literal $args{statement},
 147                 level     => ucfirst $args{level},
 148                 author    =>         $args{author},
 149                 owner     =>         $args{owner_name} || $args{owner});
 150         if ($args{contest_stop}) {
 151                 $tree->fid('solution')->detach;
 152                 $tree->fid('solution_modal')->detach;
 153                 my $score = $tree->fid('score');
 154                 $score->attr('data-start' => $args{open_time});
 155                 $score->attr('data-stop'  => $args{contest_stop});
 156                 $score->attr('data-value'  => $args{value});
 157                 $tree->fid('countdown')->attr('data-stop' => $args{contest_stop});
 158         } else {
 159                 $tree->fid('solution')->detach unless $args{solution};
 160                 $_->detach for $tree->fclass('rc'); # requires contest
 161                 $tree->fid('solution_modal')->fclass('modal-body')->replace_content(literal $args{solution});
 162         }
 163         if ($args{cansubmit}) {
 164                 $tree->look_down(name => 'problem')->attr(value => $args{id});
 165                 my $contest = $tree->look_down(name => 'contest');
 166                 $contest->attr(value => $args{contest}) if $args{contest};
 167                 $contest->detach unless $args{contest}
 168         } else {
 169                 $tree->fid('submit')->detach
 170         }
 171 }
 172
 173 sub process_sol {
 174         my ($tree, %args) = @_;
 175         $tree->content_handler(solution => literal $args{solution});
 176 }
 177
 178 sub process_pb {
 179         my ($tree, %args) = @_;
 180         my $titer = sub {
 181                 my ($data, $tr) = @_;
 182                 $tr->set_child_content(class => 'author', $data->{author});
 183                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 184                 $tr->fclass('name')->find('a')->edit_href(sub {$_ .= "?contest=$args{contest}"}) if $args{contest};
 185                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 186                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private};
 187         };
 188         my $iter = sub {
 189                 my ($data, $div) = @_;
 190                 $div->attr(id => $data);
 191                 $div->find('h2')->replace_content(ucfirst $data);
 192                 $div->find('tbody')->find('tr')->iter3($args{$data}, $titer);
 193         };
 194         $tree->fid('beginner')->iter3([grep {$args{$_}} qw/beginner easy medium hard/], $iter);
 195 }
 196
 197 sub process_log_entry {
 198         my ($tree, %args) = @_;
 199         $tree->fid('problem')->namedlink(@args{qw/problem problem_name/});
 200         $tree->fid('owner')->namedlink(@args{qw/owner owner_name/});
 201         $tree->fid('source')->namedlink("$args{id}.$args{extension}", sprintf '%.2fKB', $args{size}/1024);
 202         if ($args{contest}) {
 203                 $tree->fid('contest')->namedlink(@args{qw/contest contest_name/});
 204                 $tree->fid('problem')->find('a')->edit_href(sub {$_.="?contest=$args{contest}"});
 205         } else {
 206                 $tree->fid('contest')->left->detach;
 207                 $tree->fid('contest')->detach;
 208         }
 209
 210         $args{errors} ? $tree->fid('errors')->find('pre')->replace_content($args{errors}) : $tree->fid('errors')->detach;
 211         my $iter = sub {
 212                 my ($data, $tr) = @_;
 213                 $data->{time} = sprintf '%.4fs', $data->{time};
 214                 $tr->defmap(class => $data);
 215                 $tr->fclass('result_text')->attr(class => "r$data->{result}")
 216         };
 217         $tree->fclass('result_text')->replace_content($args{result_text});
 218         $tree->fclass('result_text')->attr(class => "r$args{result}");
 219         $args{results} ? $tree->fid('results')->find('tbody')->find('tr')->iter3($args{results}, $iter) : $tree->fid('results')->detach;
 220         $tree->fid('no_results')->detach if $tree->fid('results') || $tree->fid('errors');
 221 }
 222
 223 sub process_log {
 224         my ($tree, %args) = @_;
 225         my $iter = sub {
 226                 my ($data, $tr) = @_;
 227                 $tr->fclass('id')->namedlink($data->{id});
 228                 $tr->fclass('problem')->namedlink($data->{problem}, $data->{problem_name});
 229                 $tr->fclass('problem')->find('a')->edit_href(sub{$_ .= "?contest=$args{contest}"}) if $args{contest};
 230                 $tr->fclass('contest')->namedlink($data->{contest}, $data->{contest_name}) if $data->{contest};
 231                 $tr->fclass('contest')->replace_content('None') unless $data->{contest};
 232                 $tr->fclass('date')->replace_content(ftime $data->{date});
 233                 $tr->fclass('format')->replace_content($data->{format});
 234                 $tr->fclass('size')->namedlink("$data->{id}.$data->{extension}", sprintf "%.2fKB", $data->{size}/1024);
 235                 $tr->fclass('size')->attr('data-private', '') if $data->{private};
 236                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 237                 $tr->fclass('result_text')->replace_content($data->{result_text});
 238                 $tr->fclass('result_text')->attr(class => "r$data->{result}");
 239                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private};
 240         };
 241         $tree->find('table')->find('tbody')->find('tr')->iter3($args{log}, $iter);
 242         $args{next_page} ? $tree->fclass('next')->namedlink($args{next_page}, 'Next') : $tree->fclass('next')->detach;
 243         $args{previous_page} ? $tree->fclass('previous')->namedlink($args{previous_page}, 'Previous') : $tree->fclass('previous')->detach;
 244         for my $cls (qw/next previous/) {
 245                 my $elem = $tree->fclass($cls);
 246                 next unless $elem;
 247                 delete $args{args}{page};
 248                 my $str = join '&', map { $_ . '=' . $args{args}{$_} } keys %{$args{args}};
 249                 $elem->find('a')->edit_href(sub{s/$/&$str/});
 250         }
 251         $tree->fclass('current')->replace_content("Page $args{current_page} of $args{last_page}");
 252 }
 253
 254 sub process_st {
 255         my ($tree, %args) = @_;
 256         $args{problems} //= [];
 257         my $pbiter = sub {
 258                 my ($data, $th) = @_;
 259                 $th->attr(class => undef);
 260                 $th->namedlink(@$data);
 261                 $th->find('a')->edit_href(sub{s/$/?contest=$args{args}{contest}/});
 262         };
 263         $tree->fclass('problem')->iter3($args{problems}, $pbiter);
 264         my $iter = sub {
 265                 my ($st, $tr) = @_;
 266                 $tr->set_child_content(class => 'rank', $st->{rank});
 267                 $tr->set_child_content(class => 'score', $st->{score});
 268                 $tr->fclass('user')->namedlink($st->{user}, $st->{user_name});
 269                 my $pbscore = $tr->fclass('pbscore');
 270                 $pbscore->iter($pbscore => @{$st->{scores}});
 271         };
 272         $tree->find('tbody')->find('tr')->iter3($args{st}, $iter);
 273 }
 274
 275 sub process_ed {
 276         my ($tree, %args) = @_;
 277         my $iter = sub {
 278                 my ($data, $div) = @_;
 279                 $div->set_child_content(class => 'value', $data->{value});
 280                 $div->set_child_content(class => 'solution', literal $data->{solution});
 281                 $div->fclass('problem')->namedlink($data->{id}, $data->{name});
 282         };
 283         my @pb = map { @{$args{$_}} } qw/beginner easy medium hard/;
 284         $tree->fclass('well')->iter3(\@pb, $iter);
 285 }