lib/Plack/App/Gruntmaster/HTML.pm

   1 package Plack::App::Gruntmaster::HTML;
   2 use v5.14;
   3 use parent qw/Exporter/;
   4 our @EXPORT = qw/render render_article/;
   5
   6 use File::Slurp qw/read_file/;
   7 use HTML::Seamstress;
   8 use POSIX qw//;
   9 use Data::Dumper qw/Dumper/;
  10
  11 sub ftime ($)   { POSIX::strftime '%c', localtime shift }
  12 sub literal ($) { HTML::Element::Library::super_literal shift // '' }
  13
  14 sub HTML::Element::edit_href {
  15         my ($self, $sub) = @_;
  16         local $_ = $self->attr('href');
  17         $sub->();
  18         $self->attr(href => $_);
  19 }
  20
  21 sub HTML::Element::iter3 {
  22         my ($self, $data, $code) = @_;
  23         my $orig = $self;
  24         my $prev = $orig;
  25         for my $el (@$data) {
  26                 my $current = $orig->clone;
  27                 $code->($el, $current);
  28                 $prev->postinsert($current);
  29                 $prev = $current;
  30         }
  31         $orig->detach;
  32 }
  33
  34 sub HTML::Element::fid    { shift->look_down(id    => shift) }
  35 sub HTML::Element::fclass { shift->look_down(class => qr/\b$_[0]\b/) }
  36
  37 sub HTML::Element::namedlink {
  38         my ($self, $id, $name) = @_;
  39         $name = $id unless $name =~ /[[:graph:]]/;
  40         $self = $self->find('a');
  41         $self->edit_href(sub {s/id/$id/});
  42         $self->replace_content($name);
  43 }
  44
  45 sub render {
  46         my ($tmpl, $lang, %args) = @_;
  47         $lang //= 'en';
  48         my $meat = _render($tmpl, $lang, %args);
  49         _render('skel', $lang, %args, meat => $meat)
  50 }
  51
  52 sub render_article {
  53         my ($art, $lang, %args) = @_;
  54         $lang //= 'en';
  55         my $title = read_file "a/$art.$lang.title";
  56         my $meat  = read_file "a/$art.$lang";
  57         _render('skel', $lang, title => $title , meat => $meat, %args)
  58 }
  59
  60 sub _render {
  61         my ($tmpl, $lang, %args) = @_;
  62         my $builder = HTML::Seamstress->new;
  63         $builder->ignore_unknown(0);
  64         my $tree = $builder->parse_file("tmpl/$tmpl.$lang");
  65         $tree = $tree->guts unless $tmpl eq 'skel';
  66         $tree->defmap(smap => \%args);
  67         my $process = __PACKAGE__->can("process_$tmpl");
  68         $process->($tree, %args) if $process;
  69         $_->detach for $tree->look_down(static => $args{static} ? 'no' : 'yes');
  70         $_->attr('static', undef) for $tree->look_down(sub {$_[0]->attr('static')});
  71         $tree->as_HTML;
  72 }
  73
  74 sub process_skel {
  75         my ($tree, %args) = @_;
  76         $tree->content_handler(
  77                 title   =>         $args{title},
  78                 content => literal $args{meat});
  79 }
  80
  81 sub process_us_entry {
  82         my ($tree, %args) = @_;
  83         $tree->fid($_)->attr('href', "/$_/?owner=$args{id}") for qw/log pb/;
  84         $tree->fid('track_user')->attr('data-user', $args{id});
  85         my @solved = map { $_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
  86         my @attempted = map { !$_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
  87
  88         my $pbiter = sub {
  89                 my ($data, $li) = @_;
  90                 $li->find('a')->namedlink($data);
  91         };
  92         $tree->fid('solved')->find('li')->iter3(\@solved, $pbiter);
  93         $tree->fid('attempted')->find('li')->iter3(\@attempted, $pbiter);
  94         $tree->fid('solved_count')->replace_content(scalar @solved);
  95         $tree->fid('attempted_count')->replace_content(scalar @attempted);
  96
  97         my $ctiter = sub {
  98                 my ($data, $td) = @_;
  99                 $td->fclass('contest')->namedlink($data->{contest}, $data->{contest_name});
 100                 $td->fclass('score')->replace_content($data->{score});
 101                 $td->fclass('rank')->replace_content($data->{rank});
 102         };
 103         $tree->find('table')->find('tbody')->find('tr')->iter3($args{contests}, $ctiter);
 104 }
 105
 106 sub process_us {
 107         my ($tree, %args) = @_;
 108         my $iter = sub {
 109                 my ($data, $tr) = @_;
 110                 $tr->fclass('user')->namedlink($data->{id}, $data->{name});
 111                 $tr->fclass($_)->replace_content($data->{$_}) for qw/solved attempted contests/;
 112         };
 113         $tree->find('tbody')->find('tr')->iter3($args{us}, $iter);
 114 }
 115
 116 sub process_ct_entry {
 117         my ($tree, %args) = @_;
 118         $_->edit_href (sub {s/contest_id/$args{id}/}) for $tree->find('a');
 119         $tree->fid('editorial')->detach unless $args{finished};
 120         $tree->fid('links')->detach unless $args{started};
 121         my $status = ($args{time} < $args{start} ? 'starts' : 'ends');
 122         $tree->fclass('timer')->attr('data-stop', $status eq 'ends' ? $args{stop} : $args{start});
 123         $tree->content_handler(
 124                 start       => ftime   $args{start},
 125                 stop        => ftime   $args{stop},
 126                 status      => $status,
 127                 description => literal $args{description});
 128         $tree->fid('ctcountdown')->detach if $args{time} >= $args{stop};
 129 }
 130
 131 sub process_ct {
 132         my ($tree, %args) = @_;
 133         my $iter = sub {
 134                 my ($data, $tr) = @_;
 135                 $data->{$_} = ftime $data->{$_} for qw/start stop/;
 136                 $tr->hashmap(class => $data, [qw/name owner/]);
 137                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 138                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 139         };
 140         $args{$_} ? $tree->fid($_)->find('tbody')->find('tr')->iter3($args{$_}, $iter) : $tree->fid($_)->detach for qw/running pending finished/;
 141 }
 142
 143 sub process_pb_entry {
 144         my ($tree, %args) = @_;
 145         $tree->fid('owner')->edit_href(sub{s/owner_id/$args{owner}/});
 146         $tree->fid('job_log')->edit_href(sub{s/problem_id/$args{id}/});
 147         $tree->fid('solution')->edit_href(sub{s/problem_id/$args{id}/});
 148         $tree->fid('job_log')->edit_href(sub{$_ .= "&private=$args{private}"}) if $args{private};
 149         $tree->content_handler(
 150                 statement => literal $args{statement},
 151                 level     => ucfirst $args{level},
 152                 author    =>         $args{author},
 153                 owner     =>         $args{owner_name} || $args{owner});
 154         if ($args{limits}) {
 155                 my @limits = (@{$args{limits}}, {format => 'Other', timeout => $args{timeout} });
 156                 @limits = map { sprintf '%s (%s)', @{$_}{qw/timeout format/} } @limits;
 157                 $tree->look_down(smap => 'timeout')->replace_content(join ', ', @limits);
 158         }
 159         if ($args{contest_stop}) {
 160                 $tree->fid('solution')->detach;
 161                 $tree->fid('solution_modal')->detach;
 162                 my $score = $tree->fid('score');
 163                 $score->attr('data-start' => $args{open_time});
 164                 $score->attr('data-stop'  => $args{contest_stop});
 165                 $score->attr('data-value'  => $args{value});
 166                 $tree->fid('countdown')->attr('data-stop' => $args{contest_stop});
 167         } else {
 168                 $tree->fid('solution')->detach unless $args{solution};
 169                 $_->detach for $tree->fclass('rc'); # requires contest
 170                 $tree->fid('solution_modal')->fclass('modal-body')->replace_content(literal $args{solution});
 171         }
 172         if ($args{cansubmit}) {
 173                 $tree->fid('nosubmit')->detach;
 174                 $tree->look_down(name => 'problem')->attr(value => $args{id});
 175                 my $contest = $tree->look_down(name => 'contest');
 176                 $contest->attr(value => $args{args}{contest}) if $args{args}{contest};
 177                 $contest->detach unless $args{args}{contest}
 178         } else {
 179                 $tree->fid('nosubmit')->find('a')->edit_href(sub{s/id/$args{id}/});
 180                 $tree->fid('submit')->detach
 181         }
 182 }
 183
 184 sub process_sol {
 185         my ($tree, %args) = @_;
 186         $tree->content_handler(solution => literal $args{solution});
 187 }
 188
 189 sub process_pb {
 190         my ($tree, %args) = @_;
 191         my $titer = sub {
 192                 my ($data, $tr) = @_;
 193                 $tr->set_child_content(class => 'author', $data->{author});
 194                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 195                 $tr->fclass('name')->find('a')->edit_href(sub {$_ .= "?contest=$args{contest}"}) if $args{contest};
 196                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 197                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private} && !$args{contest};
 198         };
 199         my $iter = sub {
 200                 my ($data, $div) = @_;
 201                 $div->attr(id => $data);
 202                 $div->find('h2')->replace_content(ucfirst $data);
 203                 $div->find('tbody')->find('tr')->iter3($args{$data}, $titer);
 204         };
 205         $tree->fid('beginner')->iter3([grep {$args{$_}} qw/beginner easy medium hard/], $iter);
 206         $tree->fid('open-alert')->detach unless $args{contest};
 207 }
 208
 209 sub process_log_entry {
 210         my ($tree, %args) = @_;
 211         $tree->fid('problem')->namedlink(@args{qw/problem problem_name/});
 212         $tree->fid('owner')->namedlink(@args{qw/owner owner_name/});
 213         $tree->fid('source')->namedlink("$args{id}.$args{extension}", sprintf '%.2fKB', $args{size}/1024);
 214         if ($args{contest}) {
 215                 $tree->fid('contest')->namedlink(@args{qw/contest contest_name/});
 216                 $tree->fid('problem')->find('a')->edit_href(sub {$_.="?contest=$args{contest}"});
 217         } else {
 218                 $tree->fid('contest')->left->detach;
 219                 $tree->fid('contest')->detach;
 220         }
 221
 222         $args{errors} ? $tree->fid('errors')->find('pre')->replace_content($args{errors}) : $tree->fid('errors')->detach;
 223         my $iter = sub {
 224                 my ($data, $tr) = @_;
 225                 $data->{time} = sprintf '%.4fs', $data->{time};
 226                 $tr->defmap(class => $data);
 227                 $tr->fclass('result_text')->attr(class => "r$data->{result}")
 228         };
 229         $tree->fclass('result_text')->replace_content($args{result_text});
 230         $tree->fclass('result_text')->attr(class => "r$args{result}");
 231         $args{results} ? $tree->fid('results')->find('tbody')->find('tr')->iter3($args{results}, $iter) : $tree->fid('results')->detach;
 232         $tree->fid('no_results')->detach if $tree->fid('results') || $tree->fid('errors');
 233 }
 234
 235 sub process_log {
 236         my ($tree, %args) = @_;
 237         my $iter = sub {
 238                 my ($data, $tr) = @_;
 239                 $tr->fclass('id')->namedlink($data->{id});
 240                 $tr->fclass('problem')->namedlink($data->{problem}, $data->{problem_name});
 241                 $tr->fclass('problem')->find('a')->edit_href(sub{$_ .= "?contest=$args{args}{contest}"}) if $args{args}{contest};
 242                 $tr->fclass('contest')->namedlink($data->{contest}, $data->{contest_name}) if $data->{contest};
 243                 $tr->fclass('contest')->replace_content('None') unless $data->{contest};
 244                 $tr->fclass('date')->replace_content(ftime $data->{date});
 245                 $tr->fclass('source')->namedlink("$data->{id}.$data->{extension}", sprintf "%.2fKB %s", $data->{size}/1024, $data->{format});
 246                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 247                 $tr->fclass('result_text')->replace_content($data->{result_text});
 248                 $tr->fclass('result_text')->attr(class => "r$data->{result}");
 249                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private};
 250         };
 251         $tree->find('table')->find('tbody')->find('tr')->iter3($args{log}, $iter);
 252         $args{next_page} ? $tree->fclass('next')->namedlink($args{next_page}, 'Next') : $tree->fclass('next')->detach;
 253         $args{previous_page} ? $tree->fclass('previous')->namedlink($args{previous_page}, 'Previous') : $tree->fclass('previous')->detach;
 254         for my $cls (qw/next previous/) {
 255                 my $elem = $tree->fclass($cls);
 256                 next unless $elem;
 257                 delete $args{args}{page};
 258                 my $str = join '&', map { $_ . '=' . $args{args}{$_} } keys %{$args{args}};
 259                 $elem->find('a')->edit_href(sub{s/$/&$str/}) if $str;
 260         }
 261         $tree->fclass('current')->replace_content("Page $args{current_page} of $args{last_page}");
 262 }
 263
 264 sub process_st {
 265         my ($tree, %args) = @_;
 266         $args{problems} //= [];
 267         my $pbiter = sub {
 268                 my ($data, $th) = @_;
 269                 $th->attr(class => undef);
 270                 $th->namedlink(@$data);
 271                 $th->find('a')->edit_href(sub{s/$/?contest=$args{args}{contest}/});
 272         };
 273         $tree->fclass('problem')->iter3($args{problems}, $pbiter);
 274         my $iter = sub {
 275                 my ($st, $tr) = @_;
 276                 $tr->set_child_content(class => 'rank', $st->{rank});
 277                 $tr->set_child_content(class => 'score', $st->{score});
 278                 $tr->fclass('user')->namedlink($st->{user}, $st->{user_name});
 279                 my $pbscore = $tr->fclass('pbscore');
 280                 $pbscore->iter($pbscore => @{$st->{scores}});
 281         };
 282         $tree->find('tbody')->find('tr')->iter3($args{st}, $iter);
 283 }
 284
 285 sub process_ed {
 286         my ($tree, %args) = @_;
 287         $tree->content_handler(editorial => literal $args{editorial});
 288         my $iter = sub {
 289                 my ($data, $div) = @_;
 290                 $div->set_child_content(class => 'value', $data->{value});
 291                 $div->set_child_content(class => 'solution', literal $data->{solution});
 292                 $div->fclass('problem')->namedlink($data->{id}, $data->{name});
 293         };
 294         my @pb = map { @{$args{$_} // []} } qw/beginner easy medium hard/;
 295         $tree->fclass('well')->iter3(\@pb, $iter);
 296 }