make_static.PL

   1 #!/usr/bin/perl
   2 use v5.14;
   3 use warnings;
   4
   5 use CSS::Minifier::XS qw/minify/;
   6 use Digest::SHA qw/sha256_base64/;
   7 use IO::Compress::Gzip qw/gzip/;
   8 use File::Slurp qw/read_file write_file edit_file_lines/;
   9 use SVG::SpriteMaker;
  10 use File::Which;
  11 use List::Util qw/first/;
  12
  13 mkdir 'static';
  14 mkdir 'static/css';
  15 mkdir 'static/js';
  16 mkdir 'static/logos';
  17
  18 sub gzip_file {
  19         my ($file) = @_;
  20         my $zopfli = which 'zopfli';
  21         system $zopfli => $file if $zopfli;
  22         gzip $file => "$file.gz", -Level => 9, Minimal => 1 unless $zopfli;
  23 }
  24
  25 sub write_gzfile {
  26         my ($file, @content) = @_;
  27         write_file $file, @content;
  28         gzip_file $file
  29 }
  30
  31 sub sprite_name {
  32         my ($name) = $_[0] =~ m,/(.*)\.svg,;
  33         "logo-$name"
  34 }
  35
  36 sub make_logos {
  37         my @logos = <logos/*>;
  38         my $logos = make_sprite \&sprite_name, @logos;
  39         my @logos_light;
  40         for (<logos/*>) {
  41                 my $light = s/logos/logos-light/r;
  42                 push @logos_light, -f $light ? $light : $_;
  43         }
  44         my $logos_light = make_sprite \&sprite_name, @logos_light;
  45
  46         write_gzfile 'static/logos/dark.svg', $logos->render;
  47         write_gzfile 'static/logos/light.svg', $logos_light->render;
  48 }
  49
  50 sub read_css_into_blocks {
  51         my ($file) = @_;
  52         my (@blocks, $block);
  53         for (read_file $file) {
  54                 $block .= $_;
  55                 if (/^}/) {
  56                         push @blocks, $block;
  57                         $block = '';
  58                 }
  59         }
  60         \@blocks
  61 }
  62
  63 sub make_css {
  64         my %css;
  65         $css{common} .= read_file $_ for <css/*.css>;
  66
  67         my (%themes, $rndtheme);
  68         for (<css/themes/*>) {
  69                 ($rndtheme) = m,themes/(.*)\.css,;
  70                 $themes{$rndtheme} = read_css_into_blocks $_;
  71         }
  72
  73         while (grep { scalar @$_ } values %themes) {
  74                 my %blocks = map { $_ => (shift @{$themes{$_}}) // '' } keys %themes;
  75                 if (grep { $_ ne $blocks{$rndtheme} } values %blocks) {
  76                         $css{$_} .= $blocks{$_} for keys %themes;
  77                 } else {
  78                         $css{common} .= $blocks{$rndtheme};
  79                 }
  80         }
  81
  82         write_gzfile "static/css/$_.css", minify $css{$_} for keys %css
  83 }
  84
  85 sub make_js {
  86         system java => -jar => 'compiler.jar', qw,-O SIMPLE --create_source_map static/js/js.map --js_output_file static/js/all.js --language_in ECMASCRIPT6_STRICT --language_out ECMASCRIPT5_STRICT --source_map_location_mapping js/|/static/js/,, <js/*>;
  87         my $js = read_file 'static/js/all.js';
  88         write_gzfile 'static/js/all.js', '//# sourceMappingURL=/static/js/js.map', "\n", $js;
  89         system 'cp', '-rp', 'js', 'static/';
  90 }
  91
  92 my $sprite_mtime = -M 'static/logos/dark.svg' // 0;
  93 for (<logos/*>, <logos-light/*>) {
  94         if (!$sprite_mtime || $sprite_mtime > -M) {
  95                 make_logos;
  96                 last
  97         }
  98 }
  99
 100 my $css_mtime = -M 'static/css/slate.css' // 0;
 101 for (<css/*>, <css/themes/*>) {
 102         if (!$css_mtime || $css_mtime > -M) {
 103                 make_css;
 104                 last
 105         }
 106 }
 107
 108 my $js_mtime = -M 'static/js/all.js' // 0;
 109 for (<js/*>) {
 110         if (!$js_mtime || $js_mtime > -M) {
 111                 make_js;
 112                 last
 113         }
 114 }
 115
 116 edit_file_lines {
 117         my ($file) = m,(static.*\.(?:css|js)),;
 118         return unless $file;
 119         my $hash = sha256_base64 scalar read_file $file;
 120         s/integrity=".*"/integrity="sha256-$hash="/;
 121 } 'tmpl/skel.en';