Do not return 404 for favicon.ico

[plack-app-gruntmaster.git] / app.psgi

#!/usr/bin/perl -w
use v5.14;
no if $] >= 5.017011, warnings => 'experimental::smartmatch';

use Gruntmaster::Data;
use Plack::App::Gruntmaster;
use Plack::Builder;
use Plack::Request;
use Plack::Util;
use Digest::SHA qw/sha256/;
use Log::Log4perl;
use Tie::Hash::Expire;

use constant AUTH_TIMEOUT => 5 * 60;
use constant ACCESSLOG_FORMAT => 'combined';

sub CONTENT_SECURITY_POLICY () {
	my $csp = <<CSP;
default-src 'none'
connect-src 'self'
form-action 'self'
frame-ancestors 'none'
img-src 'self'
referrer origin-when-cross-origin
script-src 'self'
style-src 'self'
CSP
	chomp $csp;
	$csp =~ s/\n/; /gr;
}

our $db //= Gruntmaster::Data->connect($ENV{GRUNTMASTER_DSN} // 'dbi:Pg:');

tie my %auth, 'Tie::Hash::Expire', {expire_seconds => AUTH_TIMEOUT};

sub authenticate {
	my ($user, $pass, $env) = @_;
	my $key = sha256 "$user:$pass";
	$env->{'gruntmaster.user'} = $user;
	return 1 if exists $auth{$key};
	return unless $db->user($user) && $db->user($user)->check_passphrase($pass);
	$auth{key} = 1;
}

sub add_headers {
	my $app = $_[0];
	sub {
		my $resp = $app->($_[0]);
		my $hdrs = Plack::Util::headers($resp->[1]);
		$hdrs->set('Content-Security-Policy', CONTENT_SECURITY_POLICY);
		$hdrs->set('Cache-Control', 'public, max-age=604800') if $_[0]->{PATH_INFO} =~ qr,^/static/,;
		$resp->[1] = $hdrs->headers;
		$resp;
	}
}

Log::Log4perl->init_once('log.conf');
my $access_logger = Log::Log4perl->get_logger('access');
$ENV{DBIC_NULLABLE_KEY_NOWARN} = 1;

builder {
	enable_if { $_[0]->{PATH_INFO} eq '/ok' } sub { sub{ [200, [], []] }};
	enable 'AccessLog', format => ACCESSLOG_FORMAT, logger => sub { $access_logger->info(@_) };
	enable 'ContentLength';
	enable \&add_headers;
	enable 'Static', path => qr,^/static/,;
	enable 'Log4perl', category => 'plack';
	enable_if { shift->{HTTP_AUTHORIZATION} } 'Auth::Basic', authenticator => \&authenticate, realm => 'Gruntmaster 6000';
	enable sub { my $app = $_[0]; sub { $_[0]->{'gruntmaster.dbic'} = $db; $app->($_[0]) } };
	Plack::App::Gruntmaster->run_if_script
}