[plack-app-gruntmaster.git] / lib / Plack / App / Gruntmaster.pm

package Plack::App::Gruntmaster;

use 5.014000;
use strict;
our $VERSION = '5999.000_001';

use CSS::Minifier::XS;
use Encode qw/encode decode/;
use File::Slurp qw/read_file/;
use JavaScript::Minifier::XS;
use JSON::MaybeXS qw/encode_json/;
use PerlX::Maybe;
use Scope::Upper qw/unwind SUB UP/;
use Web::Simple;

use Gruntmaster::Data;
use Plack::App::Gruntmaster::HTML;

use warnings NONFATAL => 'all';
no warnings 'illegalproto';
no if $] >= 5.017011, warnings => 'experimental::smartmatch';

##################################################

use constant USER_REGEX => qr/^\w{2,20}$/a;

use constant CONTENT_TYPES => +{
	c => 'text/x-csrc',
	cpp => 'text/x-c++src',
	cs => 'text/x-csharp', # Used by GNOME. Not in mime.types.
	go => 'text/plain', # ?
	hs => 'text/x-haskell',
	java => 'text/x-java',
	pas => 'text/x-pascal',
	pl => 'text/x-perl',
	py => 'text/x-python',
};

use constant FORMAT_EXTENSION => {
	C => 'c',
	CPP => 'cpp',
	GCCGO => 'go',
	GOLANG => 'go',
	HASKELL => 'hs',
	MONO => 'cs',
	JAVA => 'java',
	PASCAL => 'pas',
	PERL => 'pl',
	PYTHON => 'py',
};

use constant NOT_FOUND => [404, ['Content-Type' => 'text/plain'], ['Not found']];
use constant FORBIDDEN => [401, ['Content-Type' => 'text/plain', 'WWW-Authenticate' => 'Basic realm="Gruntmaster 6000"'], ['Forbidden']];

sub development() { ($ENV{PLACK_ENV} // 'development') eq 'development' }

my ($env, $privacy);

sub db { $env->{'gruntmaster.dbic'} }

sub remote_user {
	my $user = $env->{'gruntmaster.user'};
	$user &&= db->user($user);
	$user
}

sub admin   { remote_user && remote_user->admin }
sub contest { db->contest ($_{contest}) }
sub problem { db->problem ($_{problem}) }
sub job     { db->job     ($_{job})     }
sub user    { db->user    ($_{user})    }

sub redirect { [301, ['X-Forever' => 1, 'Location' => $_[0]], []] }
sub reply    { [200, ['Content-Type' => 'text/plain'], \@_] }
sub response {
	my ($template, $title, $params, $maxage) = @_;
	unless ($params) {
		$params = $title;
		$title = 'No title';
	}
	$params->{time} = time;
	$params->{args} = {%_};
	bless {template => $template, title => $title, params => $params, maxage => ($maxage // 1)}, __PACKAGE__.'::Response'
}

sub forbid {
	my ($condition) = @_;
	$privacy = 'private' if $condition;
	return if !$condition || admin;
	unwind FORBIDDEN, SUB UP
}

sub dispatch_request{
	$env = $_[PSGI_ENV];
	$privacy = 'public';

	sub (GET) {
		sub (/css/:theme) {
			my $theme = $_{theme};
			return NOT_FOUND unless -e "css/themes/$theme.css";
			my $css = read_file "css/themes/$theme.css";
			$css .= read_file $_ for <css/*.css>;
			my @headers = ('X-Forever' => 1, 'Cache-Control' => 'public, max-age=604800', 'Content-Type' => 'text/css');
			[200, \@headers, [development ? $css : CSS::Minifier::XS::minify $css]]
		},

		sub (/js.js) {
			my $js;
			$js .= read_file $_ for <js/*.js>;
			my @headers = ('X-Forever' => 1, 'Cache-Control' => 'public, max-age=604800', 'Content-Type' => 'application/javascript');
			[200, \@headers, [development ? $js : JavaScript::Minifier::XS::minify $js]]
		},

		sub (/src/:job) {
			return NOT_FOUND if !job;
			forbid job->private || job->problem->private || job->contest && job->contest->is_running;
			my @headers = ('X-Forever' => 1, 'Cache-Control' => 'public, max-age=604800', 'Content-Type' => CONTENT_TYPES->{job->format});
			[200, \@headers, [job->source]]
		},

		sub (?:contest=) {
			return NOT_FOUND if !contest;
			forbid contest->is_pending;
			response_filter { return shift }
		},

		sub (?:problem=) {
			return NOT_FOUND if !problem;
			forbid problem->is_private;
			response_filter { return shift }
		},

		sub (?:format~) {
			my $format = lc ($_{format} // '');
			response_filter {
				my ($r) = @_;
				return $r if ref $r ne 'Plack::App::Gruntmaster::Response';
				my @hdrs = ('X-Forever' => 1, 'Cache-Control' => "$privacy, max-age=$r->{maxage}");
				return [200, ['Content-Type' => 'application/json', @hdrs], [encode_json $r->{params}]] if $format eq 'json';
				my $ret = render $r->{template}, 'en', title => $r->{title}, %{$r->{params}};
				[200, ['Content-Type' => 'text/html', @hdrs], [encode 'UTF-8', $ret]]
			},
		},

		sub (/st/:contest) {
			response st => 'Standings', {
				st => [ contest->standings ],
				problems => [
					map { [$_->id, $_->name] }
					sort { $a->value <=> $b->value }
					map { $_->problem } contest->contest_problems],
			}, 10
		},

		sub (/login) {
			forbid !remote_user;

			my $return = $env->{HTTP_REFERER} // '/';
			[303, ['Set-Cookie' => "username=".remote_user->id, Location => $return], []]
		},

		sub (/ct/:contest/log/st) { redirect "/st/$_{contest}" },

		sub (/us/)                                        { response us => 'Users', {us => db->user_list} },
		sub (/ct/  + ?:owner~)                            { response ct => 'Contests', db->contest_list(%_) },
		sub (/log/ + ?:contest~&:owner~&:page~&:problem~&:private~) {
			forbid $_{private};
			response log => 'Job list', {%{db->job_list(%_)}, maybe contest => $_{contest},}
		},
		sub (/pb/  + ?:owner~&:contest~&:private~)                  {
			forbid $_{private};
			response pb => 'Problems', {%{db->problem_list(%_)}, maybe contest => $_{contest}}
		},

		sub (/us/:user)    { response us_entry => user->name, db->user_entry($_{user}) },
		sub (/ct/:contest) { response ct_entry => contest->name, db->contest_entry($_{contest}) },
		sub (/log/:job)    {
			forbid job->private;
			response log_entry => "Job  $_{job}", db->job_entry($_{job})
		},
		sub (/pb/:problem + ?contest~) {
			my (undef, undef, $contest) = @_;
			$_{contest} = $contest;
			return NOT_FOUND if !contest && !problem->is_in_archive || contest && !db->contest_problems->find($_{contest}, $_{problem});
			forbid problem->is_private;
			if (contest && contest->is_running) {
				forbid !remote_user;
				$privacy = 'private';
			}
			response pb_entry => problem->name, {%{db->problem_entry($_{problem}, $_{contest}, remote_user && remote_user->id)}, maybe contest => $_{contest}};
		},
		sub (/sol/:problem) {
			forbid !problem->is_in_archive;
			response sol => 'Solution of ' . problem->name, {solution => db->problem($_{problem})->solution};
		},

		sub (/) { redispatch_to '/index' },
		sub (/favicon.ico) { redirect '/static/favicon.ico' },
		sub (/:article) { [200, ['Content-Type' => 'text/html', 'Cache-Control' => 'public, max-age=60', 'X-Forever' => 1], [render_article $_{article}, 'en']] }
	},

	sub (POST) {
		sub (/action/register + %:username=&:password=&:confirm_password=&:name=&:email=&:phone=&:town=&:university=&:country=&:level=) {
			return reply 'Parameter too long' if grep { length > 200 } values %_;
			return reply 'Bad username. Allowed characters are letters, digits and underscores, and the username must be between 2 and 20 characters long.' unless $_{username} =~ USER_REGEX;
			return reply 'Username already in use' if db->user($_{username});
			return reply 'The two passwords do not match' unless $_{password} eq $_{confirm_password};

			db->users->create({id => $_{username}, name => $_{name}, email => $_{email}, phone => $_{phone}, town => $_{town}, university => $_{university}, country => $_{country}, level => $_{level}});
			db->user($_{username})->set_passphrase($_{password});

			purge '/us/';
			reply 'Registered successfully';
		},

		sub (/action/passwd + %:password=&:new_password=&:confirm_new_password=) {
			forbid !remote_user;
			return reply 'Incorrect password' unless remote_user->check_passphrase($_{password});
			return reply 'The two passwords do not match' unless $_{new_password} eq $_{confirm_new_password};
			remote_user->set_passphrase($_{new_password});
			reply 'Password changed successfully';
		},

		sub (/action/submit + %:problem=&:contest~&:prog_format=&:source_code~ + *prog~) {
			my (undef, undef, $prog) = @_;
			forbid !remote_user;
			return reply 'This contest has finished' if contest && contest->is_finished;
			return reply 'This contest has not yet started' if !admin && contest && contest->is_pending;
			return reply 'This problem does not belong to this contest' if !contest && !problem->is_in_archive || contest && !db->contest_problems->find($_{contest}, $_{problem});
			return reply 'Maximum source size is 10KB' if ($prog ? $prog->size : length $_{source_code}) > 10 * 1024;
			return reply 'You must wait 30 seconds between jobs' if !admin && time <= remote_user->lastjob + 30;
			remote_user->update({lastjob => time});

			my $source = $prog ? read_file $prog->path : $_{source_code};
			unlink $prog->path if $prog;
			my $newjob = db->jobs->create({
				maybe contest => $_{contest},
				maybe private => problem->private && !$_{contest},
				date => time,
				extension => FORMAT_EXTENSION->{$_{prog_format}},
				format => $_{prog_format},
				problem => $_{problem},
				source => $source,
				owner => remote_user->id,
			});

			purge '/log/';
			[303, [Location => '/log/' . $newjob->id], []]
		}
	}
}


1;
__END__
Commit	Line	Data
7dc32473 MG	1	package Plack::App::Gruntmaster;
	2
	3	use 5.014000;
	4	use strict;
7dc32473 MG	5	our $VERSION = '5999.000_001';
7dc32473 MG	6
e03e380b	7	use CSS::Minifier::XS;
3b69df7a	8	use Encode qw/encode decode/;
f34254b8	9	use File::Slurp qw/read_file/;
e03e380b	10	use JavaScript::Minifier::XS;
3b69df7a	11	use JSON::MaybeXS qw/encode_json/;
594d53ba MG	12	use PerlX::Maybe;
594d53ba MG	13	use Scope::Upper qw/unwind SUB UP/;
3b69df7a	14	use Web::Simple;
594d53ba MG	15
594d53ba MG	16	use Gruntmaster::Data;
3b69df7a MG	17	use Plack::App::Gruntmaster::HTML;
	18
	19	use warnings NONFATAL => 'all';
	20	no warnings 'illegalproto';
594d53ba	21	no if $] >= 5.017011, warnings => 'experimental::smartmatch';
f34254b8	22
594d53ba MG	23	##################################################
594d53ba MG	24
594d53ba MG	25	use constant USER_REGEX => qr/^\w{2,20}$/a;
594d53ba MG	26
e03e380b MG	27	use constant CONTENT_TYPES => +{
	28	c => 'text/x-csrc',
	29	cpp => 'text/x-c++src',
	30	cs => 'text/x-csharp', # Used by GNOME. Not in mime.types.
a5e355d6 MG	31	go => 'text/plain', # ?
a5e355d6 MG	32	hs => 'text/x-haskell',
e03e380b MG	33	java => 'text/x-java',
	34	pas => 'text/x-pascal',
	35	pl => 'text/x-perl',
	36	py => 'text/x-python',
	37	};
594d53ba MG	38
	39	use constant FORMAT_EXTENSION => {
	40	C => 'c',
	41	CPP => 'cpp',
a5e355d6 MG	42	GCCGO => 'go',
	43	GOLANG => 'go',
	44	HASKELL => 'hs',
594d53ba MG	45	MONO => 'cs',
	46	JAVA => 'java',
	47	PASCAL => 'pas',
	48	PERL => 'pl',
	49	PYTHON => 'py',
	50	};
	51
e03e380b	52	use constant NOT_FOUND => [404, ['Content-Type' => 'text/plain'], ['Not found']];
3b69df7a	53	use constant FORBIDDEN => [401, ['Content-Type' => 'text/plain', 'WWW-Authenticate' => 'Basic realm="Gruntmaster 6000"'], ['Forbidden']];
594d53ba	54
1bb102ef MG	55	sub development() { ($ENV{PLACK_ENV} // 'development') eq 'development' }
1bb102ef MG	56
c039d63e	57	my ($env, $privacy);
594d53ba MG	58
	59	sub db { $env->{'gruntmaster.dbic'} }
	60
	61	sub remote_user {
	62	my $user = $env->{'gruntmaster.user'};
	63	$user &&= db->user($user);
	64	$user
	65	}
	66
3b69df7a	67	sub admin { remote_user && remote_user->admin }
594d53ba MG	68	sub contest { db->contest ($_{contest}) }
	69	sub problem { db->problem ($_{problem}) }
	70	sub job { db->job ($_{job}) }
	71	sub user { db->user ($_{user}) }
	72
	73	sub redirect { [301, ['X-Forever' => 1, 'Location' => $_[0]], []] }
	74	sub reply { [200, ['Content-Type' => 'text/plain'], \@_] }
	75	sub response {
c039d63e	76	my ($template, $title, $params, $maxage) = @_;
594d53ba MG	77	unless ($params) {
	78	$params = $title;
	79	$title = 'No title';
	80	}
9a4806b3	81	$params->{time} = time;
39e2d01a	82	$params->{args} = {%_};
c039d63e	83	bless {template => $template, title => $title, params => $params, maxage => ($maxage // 1)}, __PACKAGE__.'::Response'
594d53ba	84	}
3b69df7a	85
c039d63e MG	86	sub forbid {
	87	my ($condition) = @_;
	88	$privacy = 'private' if $condition;
	89	return if !$condition \|\| admin;
594d53ba MG	90	unwind FORBIDDEN, SUB UP
594d53ba MG	91	}
31d70015	92
594d53ba MG	93	sub dispatch_request{
594d53ba MG	94	$env = $_[PSGI_ENV];
c039d63e MG	95	$privacy = 'public';
c039d63e MG	96
594d53ba MG	97	sub (GET) {
	98	sub (/css/:theme) {
	99	my $theme = $_{theme};
	100	return NOT_FOUND unless -e "css/themes/$theme.css";
	101	my $css = read_file "css/themes/$theme.css";
	102	$css .= read_file $_ for <css/*.css>;
	103	my @headers = ('X-Forever' => 1, 'Cache-Control' => 'public, max-age=604800', 'Content-Type' => 'text/css');
1bb102ef	104	[200, \@headers, [development ? $css : CSS::Minifier::XS::minify $css]]
594d53ba MG	105	},
	106
	107	sub (/js.js) {
	108	my $js;
	109	$js .= read_file $_ for <js/*.js>;
	110	my @headers = ('X-Forever' => 1, 'Cache-Control' => 'public, max-age=604800', 'Content-Type' => 'application/javascript');
1bb102ef	111	[200, \@headers, [development ? $js : JavaScript::Minifier::XS::minify $js]]
594d53ba MG	112	},
	113
	114	sub (/src/:job) {
	115	return NOT_FOUND if !job;
34a258ae	116	forbid job->private \|\| job->problem->private \|\| job->contest && job->contest->is_running;
594d53ba MG	117	my @headers = ('X-Forever' => 1, 'Cache-Control' => 'public, max-age=604800', 'Content-Type' => CONTENT_TYPES->{job->format});
	118	[200, \@headers, [job->source]]
	119	},
	120
	121	sub (?:contest=) {
	122	return NOT_FOUND if !contest;
	123	forbid contest->is_pending;
	124	response_filter { return shift }
	125	},
	126
	127	sub (?:problem=) {
	128	return NOT_FOUND if !problem;
	129	forbid problem->is_private;
	130	response_filter { return shift }
	131	},
	132
d3892d73	133	sub (?:format~) {
feaa8f5a	134	my $format = lc ($_{format} // '');
594d53ba MG	135	response_filter {
	136	my ($r) = @_;
	137	return $r if ref $r ne 'Plack::App::Gruntmaster::Response';
c039d63e MG	138	my @hdrs = ('X-Forever' => 1, 'Cache-Control' => "$privacy, max-age=$r->{maxage}");
c039d63e MG	139	return [200, ['Content-Type' => 'application/json', @hdrs], [encode_json $r->{params}]] if $format eq 'json';
3b69df7a	140	my $ret = render $r->{template}, 'en', title => $r->{title}, %{$r->{params}};
c039d63e	141	[200, ['Content-Type' => 'text/html', @hdrs], [encode 'UTF-8', $ret]]
594d53ba MG	142	},
	143	},
	144
594d53ba MG	145	sub (/st/:contest) {
594d53ba MG	146	response st => 'Standings', {
7468a6a7	147	st => [ contest->standings ],
ebca729d MG	148	problems => [
	149	map { [$_->id, $_->name] }
	150	sort { $a->value <=> $b->value }
	151	map { $_->problem } contest->contest_problems],
c039d63e	152	}, 10
594d53ba MG	153	},
594d53ba MG	154
462db4aa MG	155	sub (/login) {
	156	forbid !remote_user;
	157
4f3b70b7 MG	158	my $return = $env->{HTTP_REFERER} // '/';
4f3b70b7 MG	159	[303, ['Set-Cookie' => "username=".remote_user->id, Location => $return], []]
462db4aa MG	160	},
462db4aa MG	161
594d53ba MG	162	sub (/ct/:contest/log/st) { redirect "/st/$_{contest}" },
	163
	164	sub (/us/) { response us => 'Users', {us => db->user_list} },
	165	sub (/ct/ + ?:owner~) { response ct => 'Contests', db->contest_list(%_) },
b8a0fa71 MG	166	sub (/log/ + ?:contest~&:owner~&:page~&:problem~&:private~) {
b8a0fa71 MG	167	forbid $_{private};
39e2d01a	168	response log => 'Job list', {%{db->job_list(%_)}, maybe contest => $_{contest},}
b8a0fa71	169	},
87ffd88b	170	sub (/pb/ + ?:owner~&:contest~&:private~) {
b8a0fa71 MG	171	forbid $_{private};
	172	response pb => 'Problems', {%{db->problem_list(%_)}, maybe contest => $_{contest}}
	173	},
594d53ba MG	174
	175	sub (/us/:user) { response us_entry => user->name, db->user_entry($_{user}) },
	176	sub (/ct/:contest) { response ct_entry => contest->name, db->contest_entry($_{contest}) },
28e89d6c MG	177	sub (/log/:job) {
	178	forbid job->private;
	179	response log_entry => "Job $_{job}", db->job_entry($_{job})
	180	},
84ca7535 MG	181	sub (/pb/:problem + ?contest~) {
	182	my (undef, undef, $contest) = @_;
	183	$_{contest} = $contest;
594d53ba MG	184	return NOT_FOUND if !contest && !problem->is_in_archive \|\| contest && !db->contest_problems->find($_{contest}, $_{problem});
594d53ba MG	185	forbid problem->is_private;
5b76a57d MG	186	if (contest && contest->is_running) {
	187	forbid !remote_user;
	188	$privacy = 'private';
	189	}
33ea2780	190	response pb_entry => problem->name, {%{db->problem_entry($_{problem}, $_{contest}, remote_user && remote_user->id)}, maybe contest => $_{contest}};
594d53ba	191	},
e4d5bdf5 MG	192	sub (/sol/:problem) {
	193	forbid !problem->is_in_archive;
	194	response sol => 'Solution of ' . problem->name, {solution => db->problem($_{problem})->solution};
	195	},
594d53ba MG	196
594d53ba MG	197	sub (/) { redispatch_to '/index' },
cb0122d7	198	sub (/favicon.ico) { redirect '/static/favicon.ico' },
c039d63e	199	sub (/:article) { [200, ['Content-Type' => 'text/html', 'Cache-Control' => 'public, max-age=60', 'X-Forever' => 1], [render_article $_{article}, 'en']] }
594d53ba MG	200	},
	201
	202	sub (POST) {
ca0c7ea2	203	sub (/action/register + %:username=&:password=&:confirm_password=&:name=&:email=&:phone=&:town=&:university=&:country=&:level=) {
594d53ba MG	204	return reply 'Parameter too long' if grep { length > 200 } values %_;
	205	return reply 'Bad username. Allowed characters are letters, digits and underscores, and the username must be between 2 and 20 characters long.' unless $_{username} =~ USER_REGEX;
	206	return reply 'Username already in use' if db->user($_{username});
	207	return reply 'The two passwords do not match' unless $_{password} eq $_{confirm_password};
	208
ca0c7ea2	209	db->users->create({id => $_{username}, name => $_{name}, email => $_{email}, phone => $_{phone}, town => $_{town}, university => $_{university}, country => $_{country}, level => $_{level}});
594d53ba MG	210	db->user($_{username})->set_passphrase($_{password});
594d53ba MG	211
c039d63e	212	purge '/us/';
594d53ba MG	213	reply 'Registered successfully';
	214	},
	215
	216	sub (/action/passwd + %:password=&:new_password=&:confirm_new_password=) {
	217	forbid !remote_user;
	218	return reply 'Incorrect password' unless remote_user->check_passphrase($_{password});
	219	return reply 'The two passwords do not match' unless $_{new_password} eq $_{confirm_new_password};
	220	remote_user->set_passphrase($_{new_password});
	221	reply 'Password changed successfully';
	222	},
	223
08794667 MG	224	sub (/action/submit + %:problem=&:contest~&:prog_format=&:source_code~ + *prog~) {
08794667 MG	225	my (undef, undef, $prog) = @_;
594d53ba	226	forbid !remote_user;
3b69df7a MG	227	return reply 'This contest has finished' if contest && contest->is_finished;
3b69df7a MG	228	return reply 'This contest has not yet started' if !admin && contest && contest->is_pending;
31f5eb01	229	return reply 'This problem does not belong to this contest' if !contest && !problem->is_in_archive \|\| contest && !db->contest_problems->find($_{contest}, $_{problem});
08794667	230	return reply 'Maximum source size is 10KB' if ($prog ? $prog->size : length $_{source_code}) > 10 * 1024;
594d53ba MG	231	return reply 'You must wait 30 seconds between jobs' if !admin && time <= remote_user->lastjob + 30;
	232	remote_user->update({lastjob => time});
	233
08794667 MG	234	my $source = $prog ? read_file $prog->path : $_{source_code};
08794667 MG	235	unlink $prog->path if $prog;
31dc8096	236	my $newjob = db->jobs->create({
594d53ba	237	maybe contest => $_{contest},
34a258ae	238	maybe private => problem->private && !$_{contest},
594d53ba MG	239	date => time,
	240	extension => FORMAT_EXTENSION->{$_{prog_format}},
	241	format => $_{prog_format},
	242	problem => $_{problem},
08794667	243	source => $source,
594d53ba MG	244	owner => remote_user->id,
	245	});
	246
c039d63e	247	purge '/log/';
31dc8096	248	[303, [Location => '/log/' . $newjob->id], []]
594d53ba MG	249	}
594d53ba MG	250	}
7dc32473 MG	251	}
7dc32473 MG	252
594d53ba	253
7dc32473 MG	254	1;
7dc32473 MG	255	__END__