lib/Plack/App/Gruntmaster/HTML.pm

   1 package Plack::App::Gruntmaster::HTML;
   2 use v5.14;
   3 use parent qw/Exporter/;
   4 our @EXPORT = qw/render render_article/;
   5
   6 use File::Slurp qw/read_file/;
   7 use HTML::Seamstress;
   8 use POSIX qw//;
   9 use Data::Dumper qw/Dumper/;
  10
  11 sub ftime ($)   { POSIX::strftime '%c', localtime shift }
  12 sub literal ($) { HTML::Element::Library::super_literal shift // '' }
  13
  14 sub HTML::Element::edit_href {
  15         my ($self, $sub) = @_;
  16         local $_ = $self->attr('href');
  17         $sub->();
  18         $self->attr(href => $_);
  19 }
  20
  21 sub HTML::Element::iter3 {
  22         my ($self, $data, $code) = @_;
  23         my $orig = $self;
  24         my $prev = $orig;
  25         for my $el (@$data) {
  26                 my $current = $orig->clone;
  27                 $code->($el, $current);
  28                 $prev->postinsert($current);
  29                 $prev = $current;
  30         }
  31         $orig->detach;
  32 }
  33
  34 sub HTML::Element::fid    { shift->look_down(id    => shift) }
  35 sub HTML::Element::fclass { shift->look_down(class => qr/\b$_[0]\b/) }
  36
  37 sub HTML::Element::namedlink {
  38         my ($self, $id, $name) = @_;
  39         $name = $id unless $name =~ /[[:graph:]]/;
  40         $self = $self->find('a');
  41         $self->edit_href(sub {s/id/$id/});
  42         $self->replace_content($name);
  43 }
  44
  45 sub render {
  46         my ($tmpl, $lang, %args) = @_;
  47         $lang //= 'en';
  48         my $meat = _render($tmpl, $lang, %args);
  49         _render('skel', $lang, %args, meat => $meat)
  50 }
  51
  52 sub render_article {
  53         my ($art, $lang) = @_;
  54         $lang //= 'en';
  55         my $title = read_file "a/$art.$lang.title";
  56         my $meat  = read_file "a/$art.$lang";
  57         _render('skel', $lang, title => $title , meat => $meat)
  58 }
  59
  60 sub _render {
  61         my ($tmpl, $lang, %args) = @_;
  62         my $builder = HTML::Seamstress->new;
  63         $builder->ignore_unknown(0);
  64         my $tree = $builder->parse_file("tmpl/$tmpl.$lang");
  65         $tree = $tree->guts unless $tmpl eq 'skel';
  66         $tree->defmap(smap => \%args);
  67         my $process = __PACKAGE__->can("process_$tmpl");
  68         $process->($tree, %args) if $process;
  69         $tree->as_HTML;
  70 }
  71
  72 sub process_skel {
  73         my ($tree, %args) = @_;
  74         $tree->content_handler(
  75                 title   =>         $args{title},
  76                 content => literal $args{meat});
  77 }
  78
  79 sub process_us_entry {
  80         my ($tree, %args) = @_;
  81         $tree->fid($_)->attr('href', "/$_/?owner=$args{id}") for qw/log pb/;
  82         $tree->fid('track_user')->attr('data-user', $args{id});
  83         my @solved = map { $_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
  84         my @attempted = map { !$_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
  85
  86         my $pbiter = sub {
  87                 my ($data, $li) = @_;
  88                 $li->find('a')->namedlink($data);
  89         };
  90         $tree->fid('solved')->find('li')->iter3(\@solved, $pbiter);
  91         $tree->fid('attempted')->find('li')->iter3(\@attempted, $pbiter);
  92         $tree->fid('solved_count')->replace_content(scalar @solved);
  93         $tree->fid('attempted_count')->replace_content(scalar @attempted);
  94
  95         my $ctiter = sub {
  96                 my ($data, $td) = @_;
  97                 $td->fclass('contest')->namedlink($data->{contest}, $data->{contest_name});
  98                 $td->fclass('score')->replace_content($data->{score});
  99                 $td->fclass('rank')->replace_content($data->{rank});
 100         };
 101         $tree->find('table')->find('tbody')->find('tr')->iter3($args{contests}, $ctiter);
 102 }
 103
 104 sub process_us {
 105         my ($tree, %args) = @_;
 106         my $iter = sub {
 107                 my ($data, $tr) = @_;
 108                 $tr->fclass('user')->namedlink($data->{id}, $data->{name});
 109                 $tr->fclass($_)->replace_content($data->{$_}) for qw/solved attempted contests/;
 110         };
 111         $tree->find('tbody')->find('tr')->iter3($args{us}, $iter);
 112 }
 113
 114 sub process_ct_entry {
 115         my ($tree, %args) = @_;
 116         $_->edit_href (sub {s/contest_id/$args{id}/}) for $tree->find('a');
 117         $tree->fid('links')->detach unless $args{started};
 118         my $status = ($args{time} < $args{start} ? 'starts' : 'ends');
 119         $tree->fclass('timer')->attr('data-stop', $status eq 'ends' ? $args{stop} : $args{start});
 120         $tree->content_handler(
 121                 start       => ftime   $args{start},
 122                 stop        => ftime   $args{stop},
 123                 status      => $status,
 124                 description => literal $args{description});
 125         $tree->fid('ctcountdown')->detach if $args{time} >= $args{stop};
 126 }
 127
 128 sub process_ct {
 129         my ($tree, %args) = @_;
 130         my $iter = sub {
 131                 my ($data, $tr) = @_;
 132                 $data->{$_} = ftime $data->{$_} for qw/start stop/;
 133                 $tr->hashmap(class => $data, [qw/name owner/]);
 134                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 135                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 136         };
 137         $args{$_} ? $tree->fid($_)->find('tbody')->find('tr')->iter3($args{$_}, $iter) : $tree->fid($_)->detach for qw/running pending finished/;
 138 }
 139
 140 sub process_pb_entry {
 141         my ($tree, %args) = @_;
 142         $tree->fid('owner')->edit_href(sub{s/owner_id/$args{owner}/});
 143         $tree->fid('job_log')->edit_href(sub{s/problem_id/$args{id}/});
 144         $tree->fid('solution')->edit_href(sub{s/problem_id/$args{id}/});
 145         $tree->fid('job_log')->edit_href(sub{$_ .= "&private=$args{private}"}) if $args{private};
 146         $tree->content_handler(
 147                 statement => literal $args{statement},
 148                 level     => ucfirst $args{level},
 149                 author    =>         $args{author},
 150                 owner     =>         $args{owner_name} || $args{owner});
 151         if ($args{contest_stop}) {
 152                 $tree->fid('solution')->detach;
 153                 $tree->fid('solution_modal')->detach;
 154                 my $score = $tree->fid('score');
 155                 $score->attr('data-start' => $args{open_time});
 156                 $score->attr('data-stop'  => $args{contest_stop});
 157                 $score->attr('data-value'  => $args{value});
 158                 $tree->fid('countdown')->attr('data-stop' => $args{contest_stop});
 159         } else {
 160                 $tree->fid('solution')->detach unless $args{solution};
 161                 $_->detach for $tree->fclass('rc'); # requires contest
 162                 $tree->fid('solution_modal')->fclass('modal-body')->replace_content(literal $args{solution});
 163         }
 164         if ($args{cansubmit}) {
 165                 $tree->fid('nosubmit')->detach;
 166                 $tree->look_down(name => 'problem')->attr(value => $args{id});
 167                 my $contest = $tree->look_down(name => 'contest');
 168                 $contest->attr(value => $args{contest}) if $args{contest};
 169                 $contest->detach unless $args{contest}
 170         } else {
 171                 $tree->fid('nosubmit')->find('a')->edit_href(sub{s/id/$args{id}/});
 172                 $tree->fid('submit')->detach
 173         }
 174 }
 175
 176 sub process_sol {
 177         my ($tree, %args) = @_;
 178         $tree->content_handler(solution => literal $args{solution});
 179 }
 180
 181 sub process_pb {
 182         my ($tree, %args) = @_;
 183         my $titer = sub {
 184                 my ($data, $tr) = @_;
 185                 $tr->set_child_content(class => 'author', $data->{author});
 186                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 187                 $tr->fclass('name')->find('a')->edit_href(sub {$_ .= "?contest=$args{contest}"}) if $args{contest};
 188                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 189                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private} && !$args{contest};
 190         };
 191         my $iter = sub {
 192                 my ($data, $div) = @_;
 193                 $div->attr(id => $data);
 194                 $div->find('h2')->replace_content(ucfirst $data);
 195                 $div->find('tbody')->find('tr')->iter3($args{$data}, $titer);
 196         };
 197         $tree->fid('beginner')->iter3([grep {$args{$_}} qw/beginner easy medium hard/], $iter);
 198         $tree->fid('open-alert')->detach unless $args{contest};
 199 }
 200
 201 sub process_log_entry {
 202         my ($tree, %args) = @_;
 203         $tree->fid('problem')->namedlink(@args{qw/problem problem_name/});
 204         $tree->fid('owner')->namedlink(@args{qw/owner owner_name/});
 205         $tree->fid('source')->namedlink("$args{id}.$args{extension}", sprintf '%.2fKB', $args{size}/1024);
 206         if ($args{contest}) {
 207                 $tree->fid('contest')->namedlink(@args{qw/contest contest_name/});
 208                 $tree->fid('problem')->find('a')->edit_href(sub {$_.="?contest=$args{contest}"});
 209         } else {
 210                 $tree->fid('contest')->left->detach;
 211                 $tree->fid('contest')->detach;
 212         }
 213
 214         $args{errors} ? $tree->fid('errors')->find('pre')->replace_content($args{errors}) : $tree->fid('errors')->detach;
 215         my $iter = sub {
 216                 my ($data, $tr) = @_;
 217                 $data->{time} = sprintf '%.4fs', $data->{time};
 218                 $tr->defmap(class => $data);
 219                 $tr->fclass('result_text')->attr(class => "r$data->{result}")
 220         };
 221         $tree->fclass('result_text')->replace_content($args{result_text});
 222         $tree->fclass('result_text')->attr(class => "r$args{result}");
 223         $args{results} ? $tree->fid('results')->find('tbody')->find('tr')->iter3($args{results}, $iter) : $tree->fid('results')->detach;
 224         $tree->fid('no_results')->detach if $tree->fid('results') || $tree->fid('errors');
 225 }
 226
 227 sub process_log {
 228         my ($tree, %args) = @_;
 229         my $iter = sub {
 230                 my ($data, $tr) = @_;
 231                 $tr->fclass('id')->namedlink($data->{id});
 232                 $tr->fclass('problem')->namedlink($data->{problem}, $data->{problem_name});
 233                 $tr->fclass('problem')->find('a')->edit_href(sub{$_ .= "?contest=$args{contest}"}) if $args{contest};
 234                 $tr->fclass('contest')->namedlink($data->{contest}, $data->{contest_name}) if $data->{contest};
 235                 $tr->fclass('contest')->replace_content('None') unless $data->{contest};
 236                 $tr->fclass('date')->replace_content(ftime $data->{date});
 237                 $tr->fclass('source')->namedlink("$data->{id}.$data->{extension}", sprintf "%.2fKB %s", $data->{size}/1024, $data->{format});
 238                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 239                 $tr->fclass('result_text')->replace_content($data->{result_text});
 240                 $tr->fclass('result_text')->attr(class => "r$data->{result}");
 241                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private};
 242         };
 243         $tree->find('table')->find('tbody')->find('tr')->iter3($args{log}, $iter);
 244         $args{next_page} ? $tree->fclass('next')->namedlink($args{next_page}, 'Next') : $tree->fclass('next')->detach;
 245         $args{previous_page} ? $tree->fclass('previous')->namedlink($args{previous_page}, 'Previous') : $tree->fclass('previous')->detach;
 246         for my $cls (qw/next previous/) {
 247                 my $elem = $tree->fclass($cls);
 248                 next unless $elem;
 249                 delete $args{args}{page};
 250                 my $str = join '&', map { $_ . '=' . $args{args}{$_} } keys %{$args{args}};
 251                 $elem->find('a')->edit_href(sub{s/$/&$str/}) if $str;
 252         }
 253         $tree->fclass('current')->replace_content("Page $args{current_page} of $args{last_page}");
 254 }
 255
 256 sub process_st {
 257         my ($tree, %args) = @_;
 258         $args{problems} //= [];
 259         my $pbiter = sub {
 260                 my ($data, $th) = @_;
 261                 $th->attr(class => undef);
 262                 $th->namedlink(@$data);
 263                 $th->find('a')->edit_href(sub{s/$/?contest=$args{args}{contest}/});
 264         };
 265         $tree->fclass('problem')->iter3($args{problems}, $pbiter);
 266         my $iter = sub {
 267                 my ($st, $tr) = @_;
 268                 $tr->set_child_content(class => 'rank', $st->{rank});
 269                 $tr->set_child_content(class => 'score', $st->{score});
 270                 $tr->fclass('user')->namedlink($st->{user}, $st->{user_name});
 271                 my $pbscore = $tr->fclass('pbscore');
 272                 $pbscore->iter($pbscore => @{$st->{scores}});
 273         };
 274         $tree->find('tbody')->find('tr')->iter3($args{st}, $iter);
 275 }
 276
 277 sub process_ed {
 278         my ($tree, %args) = @_;
 279         $tree->content_handler(editorial => literal $args{editorial});
 280         my $iter = sub {
 281                 my ($data, $div) = @_;
 282                 $div->set_child_content(class => 'value', $data->{value});
 283                 $div->set_child_content(class => 'solution', literal $data->{solution});
 284                 $div->fclass('problem')->namedlink($data->{id}, $data->{name});
 285         };
 286         my @pb = map { @{$args{$_} // []} } qw/beginner easy medium hard/;
 287         $tree->fclass('well')->iter3(\@pb, $iter);
 288 }