lib/Plack/App/Gruntmaster/HTML.pm

   1 package Plack::App::Gruntmaster::HTML;
   2 use v5.14;
   3 use parent qw/Exporter/;
   4 our @EXPORT = qw/render render_article/;
   5
   6 use File::Slurp qw/read_file/;
   7 use HTML::Element::Library;
   8 use HTML::TreeBuilder;
   9 use POSIX qw//;
  10 use Data::Dumper qw/Dumper/;
  11
  12 sub ftime ($)   { POSIX::strftime '%c', localtime shift }
  13 sub literal ($) {
  14         my ($html) = @_;
  15         return unless $html;
  16         my $b = HTML::TreeBuilder->new;
  17         $b->ignore_unknown(0);
  18         $b->parse($html);
  19         HTML::Element::Library::super_literal $b->guts->as_HTML;
  20 }
  21
  22 sub HTML::Element::edit_href {
  23         my ($self, $sub) = @_;
  24         local $_ = $self->attr('href');
  25         $sub->();
  26         $self->attr(href => $_);
  27 }
  28
  29 sub HTML::Element::iter3 {
  30         my ($self, $data, $code) = @_;
  31         my $orig = $self;
  32         my $prev = $orig;
  33         for my $el (@$data) {
  34                 my $current = $orig->clone;
  35                 $code->($el, $current);
  36                 $prev->postinsert($current);
  37                 $prev = $current;
  38         }
  39         $orig->detach;
  40 }
  41
  42 sub HTML::Element::fid    { shift->look_down(id    => shift) }
  43 sub HTML::Element::fclass { shift->look_down(class => qr/\b$_[0]\b/) }
  44
  45 sub HTML::Element::namedlink {
  46         my ($self, $id, $name) = @_;
  47         $name = $id unless $name =~ /[[:graph:]]/;
  48         $self = $self->find('a');
  49         $self->edit_href(sub {s/id/$id/});
  50         $self->replace_content($name);
  51 }
  52
  53 my %page_cache;
  54 for (<tmpl/*>) {
  55         my ($tmpl, $lang) = m,tmpl/(\w+)\.(\w+),;
  56         my $builder = HTML::TreeBuilder->new;
  57         $builder->ignore_unknown(0);
  58         $page_cache{$tmpl, $lang} = $builder->parse_file($_);
  59 }
  60
  61 sub render {
  62         my ($tmpl, $lang, %args) = @_;
  63         $lang //= 'en';
  64         my $meat = _render($tmpl, $lang, %args);
  65         _render('skel', $lang, %args, meat => $meat)
  66 }
  67
  68 sub render_article {
  69         my ($art, $lang, %args) = @_;
  70         $lang //= 'en';
  71         my $title = read_file "a/$art.$lang.title";
  72         my $meat  = read_file "a/$art.$lang";
  73         _render('skel', $lang, title => $title , meat => $meat, %args)
  74 }
  75
  76 sub _render {
  77         my ($tmpl, $lang, %args) = @_;
  78         my $tree = $page_cache{$tmpl, $lang}->clone or die "No such template/language combination: $tmpl/$lang\n";
  79         $tree = $tree->guts unless $tmpl eq 'skel';
  80         $tree->defmap(smap => \%args);
  81         my $process = __PACKAGE__->can("process_$tmpl");
  82         $process->($tree, %args) if $process;
  83         $_->detach for $tree->look_down(static => $args{static} ? 'no' : 'yes');
  84         $_->attr('static', undef) for $tree->look_down(sub {$_[0]->attr('static')});
  85         $_->attr('smap', undef) for $tree->look_down(sub {$_[0]->attr('smap')});
  86         $tree->as_HTML;
  87 }
  88
  89 sub process_skel {
  90         my ($tree, %args) = @_;
  91         $tree->content_handler(
  92                 title   =>         $args{title},
  93                 content => literal $args{meat});
  94 }
  95
  96 sub process_us_entry {
  97         my ($tree, %args) = @_;
  98         $tree->fid($_)->attr('href', "/$_/?owner=$args{id}") for qw/log pb/;
  99         $tree->fid('track_user')->attr('data-user', $args{id});
 100         my @solved = map { $_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
 101         my @attempted = map { !$_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
 102
 103         my $pbiter = sub {
 104                 my ($data, $li) = @_;
 105                 $li->find('a')->namedlink($data);
 106         };
 107         $tree->fid('solved')->find('li')->iter3(\@solved, $pbiter);
 108         $tree->fid('attempted')->find('li')->iter3(\@attempted, $pbiter);
 109         $tree->fid('solved_count')->replace_content(scalar @solved);
 110         $tree->fid('attempted_count')->replace_content(scalar @attempted);
 111
 112         my $ctiter = sub {
 113                 my ($data, $td) = @_;
 114                 $td->fclass('contest')->namedlink($data->{contest}, $data->{contest_name});
 115                 $td->fclass('score')->replace_content($data->{score});
 116                 $td->fclass('rank')->replace_content($data->{rank});
 117         };
 118         $tree->find('table')->find('tbody')->find('tr')->iter3($args{contests}, $ctiter);
 119 }
 120
 121 sub process_us {
 122         my ($tree, %args) = @_;
 123         my $iter = sub {
 124                 my ($data, $tr) = @_;
 125                 $tr->fclass('user')->namedlink($data->{id}, $data->{name});
 126                 $tr->fclass($_)->replace_content($data->{$_}) for qw/solved attempted contests/;
 127         };
 128         $tree->find('tbody')->find('tr')->iter3($args{us}, $iter);
 129 }
 130
 131 sub process_ct_entry {
 132         my ($tree, %args) = @_;
 133         $_->edit_href (sub {s/contest_id/$args{id}/}) for $tree->find('a');
 134         $tree->fid('editorial')->detach unless $args{finished};
 135         $tree->fid('links')->detach unless $args{started};
 136         my $status = ($args{time} < $args{start} ? 'starts' : 'ends');
 137         $tree->fclass('timer')->attr('data-stop', $status eq 'ends' ? $args{stop} : $args{start});
 138         $tree->content_handler(
 139                 start       => ftime   $args{start},
 140                 stop        => ftime   $args{stop},
 141                 status      => $status,
 142                 description => literal $args{description});
 143         $tree->fid('ctcountdown')->detach if $args{time} >= $args{stop};
 144 }
 145
 146 sub process_ct {
 147         my ($tree, %args) = @_;
 148         my $iter = sub {
 149                 my ($data, $tr) = @_;
 150                 $data->{$_} = ftime $data->{$_} for qw/start stop/;
 151                 $tr->hashmap(class => $data, [qw/name owner/]);
 152                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 153                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 154         };
 155         $args{$_} ? $tree->fid($_)->find('tbody')->find('tr')->iter3($args{$_}, $iter) : $tree->fid($_)->detach for qw/running pending finished/;
 156 }
 157
 158 sub process_pb_entry {
 159         my ($tree, %args) = @_;
 160         $tree->fid('owner')->edit_href(sub{s/owner_id/$args{owner}/});
 161         $tree->fid('job_log')->edit_href(sub{s/problem_id/$args{id}/});
 162         $tree->fid('solution')->edit_href(sub{s/problem_id/$args{id}/});
 163         $tree->content_handler(
 164                 statement => literal $args{statement},
 165                 level     => ucfirst $args{level},
 166                 author    =>         $args{author},
 167                 owner     =>         $args{owner_name} || $args{owner});
 168         if ($args{limits}) {
 169                 my @limits = (@{$args{limits}}, {format => 'Other', timeout => $args{timeout} });
 170                 @limits = map { sprintf '%s (%s)', @{$_}{qw/timeout format/} } @limits;
 171                 $tree->look_down(smap => 'timeout')->replace_content(join ', ', @limits);
 172         }
 173         if ($args{contest_stop}) {
 174                 $tree->fid('solution')->detach;
 175                 $tree->fid('solution_modal')->detach;
 176                 my $score = $tree->fid('score');
 177                 $score->attr('data-start' => $args{open_time});
 178                 $score->attr('data-stop'  => $args{contest_stop});
 179                 $score->attr('data-value'  => $args{value});
 180                 $tree->fid('countdown')->attr('data-stop' => $args{contest_stop});
 181         } else {
 182                 $tree->fid('job_log')->edit_href(sub{$_ .= "&private=$args{private}"}) if $args{private};
 183                 $tree->fid('solution')->detach unless $args{solution};
 184                 $_->detach for $tree->fclass('rc'); # requires contest
 185                 $tree->fid('solution_modal')->fclass('modal-body')->replace_content(literal $args{solution});
 186         }
 187         if ($args{cansubmit}) {
 188                 $tree->fid('nosubmit')->detach;
 189                 $tree->look_down(name => 'problem')->attr(value => $args{id});
 190                 my $contest = $tree->look_down(name => 'contest');
 191                 $contest->attr(value => $args{args}{contest}) if $args{args}{contest};
 192                 $contest->detach unless $args{args}{contest}
 193         } else {
 194                 $tree->fid('nosubmit')->find('a')->edit_href(sub{s/id/$args{id}/});
 195                 $tree->fid('submit')->detach
 196         }
 197 }
 198
 199 sub process_sol {
 200         my ($tree, %args) = @_;
 201         $tree->content_handler(solution => literal $args{solution});
 202 }
 203
 204 sub process_pb {
 205         my ($tree, %args) = @_;
 206         my $titer = sub {
 207                 my ($data, $tr) = @_;
 208                 $tr->set_child_content(class => 'author', $data->{author});
 209                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 210                 $tr->fclass('name')->find('a')->edit_href(sub {$_ .= "?contest=$args{contest}"}) if $args{contest};
 211                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 212                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private} && !$args{contest};
 213         };
 214         my $iter = sub {
 215                 my ($data, $div) = @_;
 216                 $div->attr(id => $data);
 217                 $div->find('h2')->replace_content(ucfirst $data);
 218                 $div->find('tbody')->find('tr')->iter3($args{$data}, $titer);
 219         };
 220         $tree->fid('beginner')->iter3([grep {$args{$_}} qw/beginner easy medium hard/], $iter);
 221         $tree->fid('open-alert')->detach unless $args{contest};
 222 }
 223
 224 sub process_log_entry {
 225         my ($tree, %args) = @_;
 226         $tree->fid('problem')->namedlink(@args{qw/problem problem_name/});
 227         $tree->fid('owner')->namedlink(@args{qw/owner owner_name/});
 228         $tree->fid('source')->namedlink("$args{id}.$args{extension}", sprintf '%.2fKB', $args{size}/1024);
 229         if ($args{contest}) {
 230                 $tree->fid('contest')->namedlink(@args{qw/contest contest_name/});
 231                 $tree->fid('problem')->find('a')->edit_href(sub {$_.="?contest=$args{contest}"});
 232         } else {
 233                 $tree->fid('contest')->left->detach;
 234                 $tree->fid('contest')->detach;
 235         }
 236
 237         $args{errors} ? $tree->fid('errors')->find('pre')->replace_content($args{errors}) : $tree->fid('errors')->detach;
 238         my $iter = sub {
 239                 my ($data, $tr) = @_;
 240                 $data->{time} = sprintf '%.4fs', $data->{time};
 241                 $tr->defmap(class => $data);
 242                 $tr->fclass('result_text')->attr(class => "r$data->{result}")
 243         };
 244         $tree->fclass('result_text')->replace_content($args{result_text});
 245         $tree->fclass('result_text')->attr(class => "r$args{result}");
 246         $args{results} ? $tree->fid('results')->find('tbody')->find('tr')->iter3($args{results}, $iter) : $tree->fid('results')->detach;
 247         $tree->fid('no_results')->detach if $tree->fid('results') || $tree->fid('errors');
 248 }
 249
 250 sub process_log {
 251         my ($tree, %args) = @_;
 252         my $iter = sub {
 253                 my ($data, $tr) = @_;
 254                 $tr->fclass('id')->namedlink($data->{id});
 255                 $tr->fclass('problem')->namedlink($data->{problem}, $data->{problem_name});
 256                 $tr->fclass('problem')->find('a')->edit_href(sub{$_ .= "?contest=$args{args}{contest}"}) if $args{args}{contest};
 257                 $tr->fclass('contest')->namedlink($data->{contest}, $data->{contest_name}) if $data->{contest};
 258                 $tr->fclass('contest')->replace_content('None') unless $data->{contest};
 259                 $tr->fclass('date')->replace_content(ftime $data->{date});
 260                 $tr->fclass('source')->namedlink("$data->{id}.$data->{extension}", sprintf "%.2fKB %s", $data->{size}/1024, Plack::App::Gruntmaster::FORMAT_EXTENSION()->{$data->{format}});
 261                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 262                 $tr->fclass('result_text')->replace_content($data->{result_text});
 263                 $tr->fclass('result_text')->attr(class => "r$data->{result}");
 264                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private};
 265         };
 266         $tree->find('table')->find('tbody')->find('tr')->iter3($args{log}, $iter);
 267         $args{next_page} ? $tree->fclass('next')->namedlink($args{next_page}, 'Next') : $tree->fclass('next')->detach;
 268         $args{previous_page} ? $tree->fclass('previous')->namedlink($args{previous_page}, 'Previous') : $tree->fclass('previous')->detach;
 269         for my $cls (qw/next previous/) {
 270                 my $elem = $tree->fclass($cls);
 271                 next unless $elem;
 272                 delete $args{args}{page};
 273                 my $str = join '&', map { $_ . '=' . $args{args}{$_} } keys %{$args{args}};
 274                 $elem->find('a')->edit_href(sub{s/$/&$str/}) if $str;
 275         }
 276         $tree->fclass('current')->replace_content("Page $args{current_page} of $args{last_page}");
 277
 278         my @detach;
 279         push @detach, $args{args}{$_} ? $tree->fclass($_) : () for qw/problem contest owner/;
 280         $_->detach for @detach;
 281 }
 282
 283 sub process_st {
 284         my ($tree, %args) = @_;
 285         $args{problems} //= [];
 286         my $pbiter = sub {
 287                 my ($data, $th) = @_;
 288                 $th->attr(class => undef);
 289                 $th->namedlink(@$data);
 290                 $th->find('a')->edit_href(sub{s/$/?contest=$args{args}{contest}/});
 291         };
 292         $tree->fclass('problem')->iter3($args{problems}, $pbiter);
 293         my $iter = sub {
 294                 my ($st, $tr) = @_;
 295                 $tr->set_child_content(class => 'rank', $st->{rank});
 296                 $tr->set_child_content(class => 'score', $st->{score});
 297                 $tr->fclass('user')->namedlink($st->{user}, $st->{user_name});
 298                 my $pbscore = $tr->fclass('pbscore');
 299                 $pbscore->iter($pbscore => @{$st->{scores}});
 300         };
 301         $tree->find('tbody')->find('tr')->iter3($args{st}, $iter);
 302 }
 303
 304 sub process_ed {
 305         my ($tree, %args) = @_;
 306         $tree->content_handler(editorial => literal $args{editorial});
 307         my $iter = sub {
 308                 my ($data, $div) = @_;
 309                 $div->set_child_content(class => 'value', $data->{value});
 310                 $div->set_child_content(class => 'solution', literal $data->{solution});
 311                 $div->fclass('problem')->namedlink($data->{id}, $data->{name});
 312         };
 313         my @pb = map { @{$args{$_} // []} } qw/beginner easy medium hard/;
 314         $tree->fclass('well')->iter3(\@pb, $iter);
 315 }
 316
 317 1;
 318 __END__