authcomplex-passwd

   1 #!/usr/bin/perl
   2 use 5.014000;
   3 use strict;
   4 use warnings;
   5
   6 use IO::Prompter;
   7 use Plack::Middleware::Auth::Complex;
   8
   9 if (@ARGV < 1) {
  10         say STDERR "$0 USERNAME [DSN [DB_USER [DB_PASSWD]]]";
  11         exit 1;
  12 }
  13
  14 my ($username, $dsn, $dbuser, $dbpasswd) = @ARGV;
  15 $dsn //= $ENV{AUTHCOMPLEX_DSN};
  16 $dbuser //= $ENV{AUTHCOMPLEX_DBUSER};
  17 $dbpasswd //= $ENV{AUTHCOMPLEX_DBPASSWD};
  18
  19 $dsn //= 'dbi:Pg:';
  20 $dbuser //= '';
  21 $dbpasswd //= '';
  22
  23 my $password = prompt 'Password: ', -echo => '*', -in => *STDIN;
  24 my $confirm  = prompt 'Confirm password: ', -echo => '*', -in => *STDIN;
  25
  26 if ($password ne $confirm) {
  27         say STDERR 'The passwords do not match';
  28         exit 1;
  29 }
  30
  31 my $ac = Plack::Middleware::Auth::Complex->new({
  32         dbi_connect => [$dsn, $dbuser, $dbpasswd]
  33 });
  34
  35 $ac->init;
  36 $ac->set_passphrase($username, $password) or die "$@\n";
  37 say 'Password changed successfully';
  38
  39 1;
  40 __END__
  41
  42 =encoding utf-8
  43
  44 =head1 NAME
  45
  46 authcomplex-passwd - change user password
  47
  48 =head1 SYNOPSIS
  49
  50   authcomplex-passwd USERNAME [DSN [DB_USER [DB_PASSWD]]]
  51
  52   # For example:
  53   authcomplex-passwd myuser # dsn defaults to 'dbi:Pg:'
  54   authcomplex-passwd myuser 'dbi:Pg:dbname=www-data'
  55   authcomplex-passwd myuser 'dbi:Pg:dbname=www-data' db_superuser password123
  56
  57 =head1 DESCRIPTION
  58
  59 The authcomplex-passwd script changes the password for an user.
  60 Takes one mandatory argument, the user whose password should be changed.
  61
  62 The DBI Data Source Name is the second argument to the script, or the
  63 value of the AUTHCOMPLEX_DSN environment variable if set, or
  64 C<dbi:Pg:> otherwise.
  65
  66 The username for the database is the third argument to the script, or
  67 the value of the AUTHCOMPLEX_DBUSER environment variable if set, or an
  68 empty string otherwise.
  69
  70 The password for the database is the fourth argument to the script, or
  71 the value of the AUTHCOMPLEX_DBPASSWD environment variable if set, or
  72 an empty string otherwise.
  73
  74 =head1 AUTHOR
  75
  76 Marius Gavrilescu, E<lt>marius@ieval.roE<gt>
  77
  78 =head1 COPYRIGHT AND LICENSE
  79
  80 Copyright (C) 2015-2017 by Marius Gavrilescu
  81
  82 This library is free software; you can redistribute it and/or modify
  83 it under the same terms as Perl itself, either Perl version 5.20.1 or,
  84 at your option, any later version of Perl 5 you may have available.
  85
  86
  87 =cut