lib/WebService/Strike.pm

   1 package WebService::Strike;
   2
   3 use 5.014000;
   4 use strict;
   5 use warnings;
   6 use parent qw/Exporter/;
   7
   8 our @EXPORT    = qw/strike strike_search/; ## no critic (ProhibitAutomaticExportation)
   9 our @EXPORT_OK = qw/strike_query strike strike_search/;
  10 our $VERSION = '0.001002';
  11 our $BASE_URL = 'http://getstrike.net/api/torrents/';
  12
  13 use JSON::MaybeXS qw/decode_json/;
  14 use HTTP::Tiny;
  15 use Sort::ByExample qw/sbe/;
  16 use WebService::Strike::Torrent;
  17
  18 sub _ht { HTTP::Tiny->new(agent => "WebService-Strike/$VERSION") }
  19
  20 sub _query {
  21         my ($url) = @_;
  22
  23         my $ht = _ht;
  24         my $response = $ht->get($url);
  25         die $response unless $response->{success}; ## no critic (RequireCarping)
  26         $response = decode_json $response->{content};
  27
  28         die $response unless ref $response eq 'ARRAY'; ## no critic (RequireCarping)
  29         map { WebService::Strike::Torrent->new($_) } @{$response->[1]};
  30 }
  31
  32 sub strike_query {
  33         my (@hashes) = @_;
  34         my $url = "$BASE_URL/info/?hashes=" . join ',', map { uc } @hashes;
  35
  36         my $sorter = sbe(\@hashes, {xform => sub { $_[0]->hash }});
  37         my @torrents = $sorter->(_query $url);
  38         wantarray ? @torrents : $torrents[0]
  39 }
  40
  41 sub strike_search {
  42         my ($query, $full, %args) = @_;
  43         $args{q} = $query;
  44         my $url = "$BASE_URL/search/?" . HTTP::Tiny->www_form_urlencode(\%args);
  45
  46         my @torrents = _query $url;
  47         @torrents = $torrents[0] unless wantarray;
  48         @torrents = strike_query map { $_->hash } @torrents if $full;
  49         wantarray ? @torrents : $torrents[0]
  50 }
  51
  52 BEGIN { *strike = \&strike_query }
  53
  54 1;
  55 __END__
  56
  57 =encoding utf-8
  58
  59 =head1 NAME
  60
  61 WebService::Strike - Get torrent info from getstrike.net API
  62
  63 =head1 SYNOPSIS
  64
  65   use WebService::Strike;
  66   my $t = strike 'B425907E5755031BDA4A8D1B6DCCACA97DA14C04';
  67   say $t->title;               # Arch Linux 2015.01.01 (x86\/x64)
  68   say $t->magnet;              # Returns a magnet link
  69   my $torrent = $t->torrent;   # Returns the torrent file
  70   $t->torrent('file.torrent'); # Downloads the torrent file to 'file.torrent'
  71
  72   my @debian = strike_search 'Debian';
  73   say 'Found ' . @debian . ' torrents matching "Debian"';
  74   say 'First torrent has info hash ' . $debian[0]->hash;
  75
  76   my $mp = strike_search 'Modern perl', 1;
  77   say 'Torrent has ' . $mp->count . ' files. They are:';
  78   say join ' ', @{$mp->file_names};
  79
  80 =head1 DESCRIPTION
  81
  82 Strike API is a service for getting information about a torrent given
  83 its info hash. WebService::Strike is a wrapper for this service.
  84
  85 =over
  86
  87 =item B<strike>(I<@info_hashes>)
  88
  89 Returns a list of L<WebService::Strike::Torrent> objects in list
  90 context or the first such object in scalar context. Dies in case of
  91 error.
  92
  93 =item B<strike_query>
  94
  95 Alias for B<strike>. Not exported by default.
  96
  97 =item B<strike_search>(I<$search_term>, [I<$full>])
  98
  99 Searches for torrents given a search term. Returns a list of
 100 L<WebService::Strike::Torrent> objects in list context or the first
 101 such object in scalar context.
 102
 103 If I<$full> is false (default), the returned objects will be
 104 incomplete: their B<file_names> and B<file_lengths> accessors will
 105 return undef.
 106
 107 If I<$full> is true, B<strike> will be called with the info hashes of
 108 the found torrents, thus obtaining complete objects.
 109
 110 =back
 111
 112 =head1 SEE ALSO
 113
 114 L<WebService::Strike::Torrent>, L<http://getstrike.net/api/>, L<WWW::Search::Torrentz>
 115
 116 =head1 AUTHOR
 117
 118 Marius Gavrilescu, E<lt>marius@ieval.roE<gt>
 119
 120 =head1 COPYRIGHT AND LICENSE
 121
 122 Copyright (C) 2015 by Marius Gavrilescu
 123
 124 This library is free software; you can redistribute it and/or modify
 125 it under the same terms as Perl itself, either Perl version 5.20.2 or,
 126 at your option, any later version of Perl 5 you may have available.
 127
 128
 129 =cut