[gruntmaster-daemon.git] / gruntmaster-exec

#!/usr/bin/perl
use v5.14;
use strict;
use warnings;

use constant +{
	# Accepted
	AC => 0,

	# Internal server error
	ERR => -1,

	# All other errors
	WA => 1,
	NZX => 2,
	TLE => 3,
	OLE => 4,
	DIED => 5,
	REJ => 10,
};

use BSD::Resource qw/setrlimit RLIMIT_AS RLIMIT_FSIZE RLIMIT_NPROC/;
use IPC::Signal qw/sig_name sig_num/;
use sigtrap qw/XFSZ/;

use Getopt::Long;
use POSIX qw//;
use Text::ParseWords qw/shellwords/;
use Time::HiRes qw/alarm/;

my (@fds, $timeout, $mlimit, $olimit, $sudo, $keep_stderr);

GetOptions(
	"fd=s"         => \@fds,
	"timeout=f"    => \$timeout,
	"mlimit=i"     => \$mlimit,
	"olimit=i"     => \$olimit,
	"keep-stderr!" => \$keep_stderr,
	"sudo!"        => \$sudo,
);

sub test_pipe_read {
	my $data = '';
	sysread STDIN, $data, 4096 and syswrite STDOUT, "recvd\n" until $data =~ /done/;
	syswrite STDOUT, 'done';
}

sub test_pipe_write {
	my ($rin, $rout);
	vec($rin, fileno STDIN, 1) = 1;
	syswrite STDOUT, "data\n" until select $rout = $rin, undef, undef, 0.05;
	syswrite STDOUT, 'done';
	my $data = '';
	sysread STDIN, $data, 4096 until $data =~ /done/;
}

sub test_pipes {
	$ARGV[0] =~ /prog/ ? test_pipe_read : test_pipe_write
}

my $killuser = $ENV{GRUNTMASTER_KILL_USER};
my @sudo;
@sudo = (shellwords ($ENV{GRUNTMASTER_SUDO}), '--') if $ENV{GRUNTMASTER_SUDO} && $sudo;
undef $mlimit if @sudo; # sudo wants a lot of address space

my $ret = fork // die 'Cannot fork';
if ($ret) {
	my ($tle, $child_ready);
	local $SIG{USR1} = sub { $child_ready = 1 };
	sleep 3; # Wait for ready signal (SIGUSR1)
	unless ($child_ready) {
		kill KILL => $ret;
		exit !say ERR, "\nNo response from gruntmaster-exec child";
	}
	local $SIG{ALRM} = sub {
		if ($killuser) {
			system @sudo, 'pkill', '-KILL', '-u', $killuser;
		} else {
			kill KILL => $ret
		}
		$tle = 1
	};
	alarm ($timeout || 10);
	waitpid $ret, 0;
	alarm 0;
	if (@sudo) {
		$? = $? >> 8;
		$? = $? < 128 || $? > 128+32 ? ($? << 8) : $? - 128;
	}
	my $sig = $? & 127;
	my $signame = sig_name $sig;
	exit !say TLE,  "\nTime Limit Exceeded"   if $tle;
	exit !say OLE,  "\nOutput Limit Exceeded" if $sig && $signame eq 'XFSZ';
	exit !say DIED, "\nCrash (SIG$signame)"   if $sig && ($signame ne 'PIPE' || $ARGV[0] !~ /prog/);
	exit !say NZX,  "\nNon-zero exit status: " . ($? >> 8) if $? >> 8;
	exit !say AC,   "\nAll OK";
} else {
	$^F = 50;
	POSIX::close 2 unless $keep_stderr;
	POSIX::close $_ for 0, 1, 3 .. $^F;
	for my $fdstring (@fds) {
		my ($fd, $file) = split ' ', $fdstring, 2;
		open my $fh, $file or die $!;
		my $oldfd = fileno $fh;
		if ($oldfd != $fd) {
			POSIX::dup2 $oldfd, $fd or die $!;
			POSIX::close $oldfd or die $!;
		}
	}
	test_pipes if grep /tty|fifo/, @fds;
	my $nproc = $killuser ? 15 : 1;
	my $debug = $ENV{TEST_VERBOSE};
	%ENV = (ONLINE_JUDGE => 1, PATH => $ENV{PATH}, HOME => $ENV{HOME});
	setrlimit RLIMIT_AS, $mlimit, $mlimit or die $! if $mlimit;
	setrlimit RLIMIT_FSIZE, $olimit, $olimit or die $! if $olimit;
	setrlimit RLIMIT_NPROC, $nproc, $nproc or die $! if $sudo;
	open my $adj, '>', '/proc/self/oom_score_adj';
	print $adj 900;
	close $adj;
	unshift @ARGV, @sudo;
	kill USR1 => getppid; # Tell parent process that we're ready
	say STDERR "Executing: ", join ' ', map { "'$_'" } @ARGV if $debug;
	exec @ARGV;
}

1;
__END__

=encoding utf-8

=head1 NAME

gruntmaster-exec - Gruntmaster 6000 executor

=head1 SYNOPSIS

  gruntmaster-exec 20000000 111 echo 'Hello, world!'

=head1 DESCRIPTION

gruntmaster-exec is the script used by gruntmasterd to run programs.

The first argument is the address space limit (in bytes), the second argument is the output limit (also in bytes). The rest of the arguments are the command that should be run and its arguments.

gruntmaster-exec sets the resource limits, cleans the environment (except for PATH and HOME), adds the ONLINE_JUDGE environment variable with value 1, and finally C<exec>s the given command.

=head1 AUTHOR

Marius Gavrilescu E<lt>marius@ieval.roE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2014 by Marius Gavrilescu

This program is free software: you can redistribute it and/or modify
it under the terms of the GNU Affero General Public License as published by
the Free Software Foundation, either version 3 of the License, or
(at your option) any later version.
Commit	Line	Data
	1	#!/usr/bin/perl
	2	use v5.14;
	3	use strict;
	4	use warnings;
	5
	6	use constant +{
	7	# Accepted
	8	AC => 0,
	9
	10	# Internal server error
	11	ERR => -1,
	12
	13	# All other errors
	14	WA => 1,
	15	NZX => 2,
	16	TLE => 3,
	17	OLE => 4,
	18	DIED => 5,
	19	REJ => 10,
	20	};
	21
	22	use BSD::Resource qw/setrlimit RLIMIT_AS RLIMIT_FSIZE RLIMIT_NPROC/;
	23	use IPC::Signal qw/sig_name sig_num/;
	24	use sigtrap qw/XFSZ/;
	25
	26	use Getopt::Long;
	27	use POSIX qw//;
	28	use Text::ParseWords qw/shellwords/;
	29	use Time::HiRes qw/alarm/;
	30
	31	my (@fds, $timeout, $mlimit, $olimit, $sudo, $keep_stderr);
	32
	33	GetOptions(
	34	"fd=s" => \@fds,
	35	"timeout=f" => \$timeout,
	36	"mlimit=i" => \$mlimit,
	37	"olimit=i" => \$olimit,
	38	"keep-stderr!" => \$keep_stderr,
	39	"sudo!" => \$sudo,
	40	);
	41
	42	sub test_pipe_read {
	43	my $data = '';
	44	sysread STDIN, $data, 4096 and syswrite STDOUT, "recvd\n" until $data =~ /done/;
	45	syswrite STDOUT, 'done';
	46	}
	47
	48	sub test_pipe_write {
	49	my ($rin, $rout);
	50	vec($rin, fileno STDIN, 1) = 1;
	51	syswrite STDOUT, "data\n" until select $rout = $rin, undef, undef, 0.05;
	52	syswrite STDOUT, 'done';
	53	my $data = '';
	54	sysread STDIN, $data, 4096 until $data =~ /done/;
	55	}
	56
	57	sub test_pipes {
	58	$ARGV[0] =~ /prog/ ? test_pipe_read : test_pipe_write
	59	}
	60
	61	my $killuser = $ENV{GRUNTMASTER_KILL_USER};
	62	my @sudo;
	63	@sudo = (shellwords ($ENV{GRUNTMASTER_SUDO}), '--') if $ENV{GRUNTMASTER_SUDO} && $sudo;
	64	undef $mlimit if @sudo; # sudo wants a lot of address space
	65
	66	my $ret = fork // die 'Cannot fork';
	67	if ($ret) {
	68	my ($tle, $child_ready);
	69	local $SIG{USR1} = sub { $child_ready = 1 };
	70	sleep 3; # Wait for ready signal (SIGUSR1)
	71	unless ($child_ready) {
	72	kill KILL => $ret;
	73	exit !say ERR, "\nNo response from gruntmaster-exec child";
	74	}
	75	local $SIG{ALRM} = sub {
	76	if ($killuser) {
	77	system @sudo, 'pkill', '-KILL', '-u', $killuser;
	78	} else {
	79	kill KILL => $ret
	80	}
	81	$tle = 1
	82	};
	83	alarm ($timeout \|\| 10);
	84	waitpid $ret, 0;
	85	alarm 0;
	86	if (@sudo) {
	87	$? = $? >> 8;
	88	$? = $? < 128 \|\| $? > 128+32 ? ($? << 8) : $? - 128;
	89	}
	90	my $sig = $? & 127;
	91	my $signame = sig_name $sig;
	92	exit !say TLE, "\nTime Limit Exceeded" if $tle;
	93	exit !say OLE, "\nOutput Limit Exceeded" if $sig && $signame eq 'XFSZ';
	94	exit !say DIED, "\nCrash (SIG$signame)" if $sig && ($signame ne 'PIPE' \|\| $ARGV[0] !~ /prog/);
	95	exit !say NZX, "\nNon-zero exit status: " . ($? >> 8) if $? >> 8;
	96	exit !say AC, "\nAll OK";
	97	} else {
	98	$^F = 50;
	99	POSIX::close 2 unless $keep_stderr;
	100	POSIX::close $_ for 0, 1, 3 .. $^F;
	101	for my $fdstring (@fds) {
	102	my ($fd, $file) = split ' ', $fdstring, 2;
	103	open my $fh, $file or die $!;
	104	my $oldfd = fileno $fh;
	105	if ($oldfd != $fd) {
	106	POSIX::dup2 $oldfd, $fd or die $!;
	107	POSIX::close $oldfd or die $!;
	108	}
	109	}
	110	test_pipes if grep /tty\|fifo/, @fds;
	111	my $nproc = $killuser ? 15 : 1;
	112	my $debug = $ENV{TEST_VERBOSE};
	113	%ENV = (ONLINE_JUDGE => 1, PATH => $ENV{PATH}, HOME => $ENV{HOME});
	114	setrlimit RLIMIT_AS, $mlimit, $mlimit or die $! if $mlimit;
	115	setrlimit RLIMIT_FSIZE, $olimit, $olimit or die $! if $olimit;
	116	setrlimit RLIMIT_NPROC, $nproc, $nproc or die $! if $sudo;
	117	open my $adj, '>', '/proc/self/oom_score_adj';
	118	print $adj 900;
	119	close $adj;
	120	unshift @ARGV, @sudo;
	121	kill USR1 => getppid; # Tell parent process that we're ready
	122	say STDERR "Executing: ", join ' ', map { "'$_'" } @ARGV if $debug;
	123	exec @ARGV;
	124	}
	125
	126	1;
	127	__END__
	128
	129	=encoding utf-8
	130
	131	=head1 NAME
	132
	133	gruntmaster-exec - Gruntmaster 6000 executor
	134
	135	=head1 SYNOPSIS
	136
	137	gruntmaster-exec 20000000 111 echo 'Hello, world!'
	138
	139	=head1 DESCRIPTION
	140
	141	gruntmaster-exec is the script used by gruntmasterd to run programs.
	142
	143	The first argument is the address space limit (in bytes), the second argument is the output limit (also in bytes). The rest of the arguments are the command that should be run and its arguments.
	144
	145	gruntmaster-exec sets the resource limits, cleans the environment (except for PATH and HOME), adds the ONLINE_JUDGE environment variable with value 1, and finally C<exec>s the given command.
	146
	147	=head1 AUTHOR
	148
	149	Marius Gavrilescu E<lt>marius@ieval.roE<gt>
	150
	151	=head1 COPYRIGHT AND LICENSE
	152
	153	Copyright (C) 2014 by Marius Gavrilescu
	154
	155	This program is free software: you can redistribute it and/or modify
	156	it under the terms of the GNU Affero General Public License as published by
	157	the Free Software Foundation, either version 3 of the License, or
	158	(at your option) any later version.