[gruntmaster-daemon.git] / gruntmaster-exec

#!/usr/bin/perl
use v5.14;
use strict;
use warnings;

use constant +{
	# Accepted
	AC => 0,

	# Internal server error
	ERR => -1,

	# All other errors
	WA => 1,
	NZX => 2,
	TLE => 3,
	OLE => 4,
	DIED => 5,
	REJ => 10,
};

use BSD::Resource qw/setrlimit RLIMIT_AS RLIMIT_FSIZE RLIMIT_NPROC/;
use IPC::Signal qw/sig_name sig_num/;
use sigtrap qw/XFSZ/;

use Getopt::Long;
use POSIX qw//;
use Text::ParseWords qw/shellwords/;
use Time::HiRes qw/alarm/;

my (@fds, $timeout, $mlimit, $olimit, $sudo, $keep_stderr);

GetOptions(
	"fd=s"         => \@fds,
	"timeout=f"    => \$timeout,
	"mlimit=i"     => \$mlimit,
	"olimit=i"     => \$olimit,
	"keep-stderr!" => \$keep_stderr,
	"sudo!"        => \$sudo,
);

my $killuser = $ENV{GRUNTMASTER_KILL_USER};
my @sudo;
@sudo = (shellwords ($ENV{GRUNTMASTER_SUDO}), '--') if $ENV{GRUNTMASTER_SUDO} && $sudo;
undef $mlimit if @sudo; # sudo wants a lot of address space

my $ret = fork // die 'Cannot fork';
if ($ret) {
	my ($tle, $child_ready);
	local $SIG{USR1} = sub { $child_ready = 1 };
	sleep 3; # Wait for ready signal (SIGUSR1)
	unless ($child_ready) {
		kill KILL => $ret;
		exit !say ERR, "\nNo response from gruntmaster-exec child";
	}
	local $SIG{ALRM} = sub {
		if ($killuser) {
			system @sudo, 'pkill', '-KILL', '-u', $killuser;
		} else {
			kill KILL => $ret
		}
		$tle = 1
	};
	alarm ($timeout || 10);
	waitpid $ret, 0;
	alarm 0;
	if (@sudo) {
		$? = $? >> 8;
		$? = $? < 128 || $? > 128+32 ? ($? << 8) : $? - 128;
	}
	my $sig = $? & 127;
	my $signame = sig_name $sig;
	exit !say TLE,  "\nTime Limit Exceeded"   if $tle;
	exit !say OLE,  "\nOutput Limit Exceeded" if $sig && $signame eq 'XFSZ';
	exit !say DIED, "\nCrash (SIG$signame)"   if $sig && ($signame ne 'PIPE' || $ARGV[0] !~ /prog/);
	exit !say NZX,  "\nNon-zero exit status: " . ($? >> 8) if $? >> 8;
	exit !say AC,   "\nAll OK";
} else {
	$^F = 50;
	POSIX::close 2 unless $keep_stderr;
	POSIX::close $_ for 0, 1, 3 .. $^F;
	for my $fdstring (@fds) {
		my ($fd, $file) = split ' ', $fdstring, 2;
		open my $fh, $file or die $!;
		my $oldfd = fileno $fh;
		if ($oldfd != $fd) {
			POSIX::dup2 $oldfd, $fd or die $!;
			POSIX::close $oldfd or die $!;
		}
	}
	my $nproc = $killuser ? 15 : 1;
	my $debug = $ENV{TEST_VERBOSE};
	%ENV = (ONLINE_JUDGE => 1, PATH => $ENV{PATH}, HOME => $ENV{HOME});
	setrlimit RLIMIT_AS, $mlimit, $mlimit or die $! if $mlimit;
	setrlimit RLIMIT_FSIZE, $olimit, $olimit or die $! if $olimit;
	setrlimit RLIMIT_NPROC, $nproc, $nproc or die $! if $sudo;
	open my $adj, '>', '/proc/self/oom_score_adj';
	print $adj 900;
	close $adj;
	unshift @ARGV, @sudo;
	kill USR1 => getppid; # Tell parent process that we're ready
	say STDERR "Executing: ", join ' ', map { "'$_'" } @ARGV if $debug;
	exec @ARGV;
}

1;
__END__

=encoding utf-8

=head1 NAME

gruntmaster-exec - Gruntmaster 6000 executor

=head1 SYNOPSIS

  gruntmaster-exec 20000000 111 echo 'Hello, world!'

=head1 DESCRIPTION

gruntmaster-exec is the script used by gruntmasterd to run programs.

The first argument is the address space limit (in bytes), the second argument is the output limit (also in bytes). The rest of the arguments are the command that should be run and its arguments.

gruntmaster-exec sets the resource limits, cleans the environment (except for PATH and HOME), adds the ONLINE_JUDGE environment variable with value 1, and finally C<exec>s the given command.

=head1 AUTHOR

Marius Gavrilescu E<lt>marius@ieval.roE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2014 by Marius Gavrilescu

This program is free software: you can redistribute it and/or modify
it under the terms of the GNU Affero General Public License as published by
the Free Software Foundation, either version 3 of the License, or
(at your option) any later version.
Commit	Line	Data
	1	#!/usr/bin/perl
	2	use v5.14;
	3	use strict;
	4	use warnings;
	5
	6	use constant +{
	7	# Accepted
	8	AC => 0,
	9
	10	# Internal server error
	11	ERR => -1,
	12
	13	# All other errors
	14	WA => 1,
	15	NZX => 2,
	16	TLE => 3,
	17	OLE => 4,
	18	DIED => 5,
	19	REJ => 10,
	20	};
	21
	22	use BSD::Resource qw/setrlimit RLIMIT_AS RLIMIT_FSIZE RLIMIT_NPROC/;
	23	use IPC::Signal qw/sig_name sig_num/;
	24	use sigtrap qw/XFSZ/;
	25
	26	use Getopt::Long;
	27	use POSIX qw//;
	28	use Text::ParseWords qw/shellwords/;
	29	use Time::HiRes qw/alarm/;
	30
	31	my (@fds, $timeout, $mlimit, $olimit, $sudo, $keep_stderr);
	32
	33	GetOptions(
	34	"fd=s" => \@fds,
	35	"timeout=f" => \$timeout,
	36	"mlimit=i" => \$mlimit,
	37	"olimit=i" => \$olimit,
	38	"keep-stderr!" => \$keep_stderr,
	39	"sudo!" => \$sudo,
	40	);
	41
	42	my $killuser = $ENV{GRUNTMASTER_KILL_USER};
	43	my @sudo;
	44	@sudo = (shellwords ($ENV{GRUNTMASTER_SUDO}), '--') if $ENV{GRUNTMASTER_SUDO} && $sudo;
	45	undef $mlimit if @sudo; # sudo wants a lot of address space
	46
	47	my $ret = fork // die 'Cannot fork';
	48	if ($ret) {
	49	my ($tle, $child_ready);
	50	local $SIG{USR1} = sub { $child_ready = 1 };
	51	sleep 3; # Wait for ready signal (SIGUSR1)
	52	unless ($child_ready) {
	53	kill KILL => $ret;
	54	exit !say ERR, "\nNo response from gruntmaster-exec child";
	55	}
	56	local $SIG{ALRM} = sub {
	57	if ($killuser) {
	58	system @sudo, 'pkill', '-KILL', '-u', $killuser;
	59	} else {
	60	kill KILL => $ret
	61	}
	62	$tle = 1
	63	};
	64	alarm ($timeout \|\| 10);
	65	waitpid $ret, 0;
	66	alarm 0;
	67	if (@sudo) {
	68	$? = $? >> 8;
	69	$? = $? < 128 \|\| $? > 128+32 ? ($? << 8) : $? - 128;
	70	}
	71	my $sig = $? & 127;
	72	my $signame = sig_name $sig;
	73	exit !say TLE, "\nTime Limit Exceeded" if $tle;
	74	exit !say OLE, "\nOutput Limit Exceeded" if $sig && $signame eq 'XFSZ';
	75	exit !say DIED, "\nCrash (SIG$signame)" if $sig && ($signame ne 'PIPE' \|\| $ARGV[0] !~ /prog/);
	76	exit !say NZX, "\nNon-zero exit status: " . ($? >> 8) if $? >> 8;
	77	exit !say AC, "\nAll OK";
	78	} else {
	79	$^F = 50;
	80	POSIX::close 2 unless $keep_stderr;
	81	POSIX::close $_ for 0, 1, 3 .. $^F;
	82	for my $fdstring (@fds) {
	83	my ($fd, $file) = split ' ', $fdstring, 2;
	84	open my $fh, $file or die $!;
	85	my $oldfd = fileno $fh;
	86	if ($oldfd != $fd) {
	87	POSIX::dup2 $oldfd, $fd or die $!;
	88	POSIX::close $oldfd or die $!;
	89	}
	90	}
	91	my $nproc = $killuser ? 15 : 1;
	92	my $debug = $ENV{TEST_VERBOSE};
	93	%ENV = (ONLINE_JUDGE => 1, PATH => $ENV{PATH}, HOME => $ENV{HOME});
	94	setrlimit RLIMIT_AS, $mlimit, $mlimit or die $! if $mlimit;
	95	setrlimit RLIMIT_FSIZE, $olimit, $olimit or die $! if $olimit;
	96	setrlimit RLIMIT_NPROC, $nproc, $nproc or die $! if $sudo;
	97	open my $adj, '>', '/proc/self/oom_score_adj';
	98	print $adj 900;
	99	close $adj;
	100	unshift @ARGV, @sudo;
	101	kill USR1 => getppid; # Tell parent process that we're ready
	102	say STDERR "Executing: ", join ' ', map { "'$_'" } @ARGV if $debug;
	103	exec @ARGV;
	104	}
	105
	106	1;
	107	__END__
	108
	109	=encoding utf-8
	110
	111	=head1 NAME
	112
	113	gruntmaster-exec - Gruntmaster 6000 executor
	114
	115	=head1 SYNOPSIS
	116
	117	gruntmaster-exec 20000000 111 echo 'Hello, world!'
	118
	119	=head1 DESCRIPTION
	120
	121	gruntmaster-exec is the script used by gruntmasterd to run programs.
	122
	123	The first argument is the address space limit (in bytes), the second argument is the output limit (also in bytes). The rest of the arguments are the command that should be run and its arguments.
	124
	125	gruntmaster-exec sets the resource limits, cleans the environment (except for PATH and HOME), adds the ONLINE_JUDGE environment variable with value 1, and finally C<exec>s the given command.
	126
	127	=head1 AUTHOR
	128
	129	Marius Gavrilescu E<lt>marius@ieval.roE<gt>
	130
	131	=head1 COPYRIGHT AND LICENSE
	132
	133	Copyright (C) 2014 by Marius Gavrilescu
	134
	135	This program is free software: you can redistribute it and/or modify
	136	it under the terms of the GNU Affero General Public License as published by
	137	the Free Software Foundation, either version 3 of the License, or
	138	(at your option) any later version.