[gruntmaster-daemon.git] / gruntmaster-exec

#!/usr/bin/perl
use v5.14;
use strict;
use warnings;

use constant +{
	# Accepted
	AC => 0,

	# Internal server error
	ERR => -1,

	# All other errors
	WA => 1,
	NZX => 2,
	TLE => 3,
	OLE => 4,
	DIED => 5,
	REJ => 10,
};

use BSD::Resource qw/setrlimit RLIMIT_AS RLIMIT_FSIZE RLIMIT_NPROC/;
use IPC::Signal qw/sig_name sig_num/;
use sigtrap qw/XFSZ/;

use Getopt::Long;
use POSIX qw//;
use Text::ParseWords qw/shellwords/;
use Time::HiRes qw/alarm/;

my (@fds, $timeout, $mlimit, $olimit, $sudo);
my $close = 1;

GetOptions(
	"fd=s"      => \@fds,
	"timeout=f" => \$timeout,
	"mlimit=i"  => \$mlimit,
	"olimit=i"  => \$olimit,
	"close!"    => \$close,
	"sudo!"   => \$sudo,
);

my $killuser = $ENV{GRUNTMASTER_KILL_USER};
my @sudo;
@sudo = (shellwords ($ENV{GRUNTMASTER_SUDO}), '--') if $ENV{GRUNTMASTER_SUDO} && $sudo;
undef $mlimit if @sudo; # sudo wants a lot of address space

my $ret = fork // die 'Cannot fork';
if ($ret) {
	my $tle;
	local $SIG{ALRM} = sub {
		if ($killuser) {
			system @sudo, 'pkill', '-KILL', '-u', $killuser;
		} else {
			kill KILL => $ret
		}
		$tle = 1
	};
	alarm ($timeout || 10);
	waitpid $ret, 0;
	alarm 0;
	if (@sudo) {
		$? = $? >> 8;
		$? = $? < 128 || $? > 128+32 ? ($? << 8) : $? - 128;
	}
	my $sig = $? & 127;
	my $signame = sig_name $sig;
	exit !say TLE,  "\nTime Limit Exceeded"   if $tle;
	exit !say OLE,  "\nOutput Limit Exceeded" if $sig && $signame eq 'XFSZ';
	exit !say DIED, "\nCrash (SIG$signame)"   if $sig && $signame ne 'PIPE';
	exit !say NZX,  "\nNon-zero exit status: " . ($? >> 8) if $? >> 8;
	exit !say AC,   "\nAll OK";
} else {
	$^F = 50;
	if ($close) {
		POSIX::close $_ for 0 .. $^F;
	}
	for my $fdstring (@fds) {
		my ($fd, $file) = split ' ', $fdstring, 2;
		open my $fh, $file or die $!;
		my $oldfd = fileno $fh;
		if ($oldfd != $fd) {
			POSIX::dup2 $oldfd, $fd or die $!;
			POSIX::close $oldfd or die $!;
		}
	}
	my $nproc = $killuser ? 15 : 1;
	my $debug = $ENV{TEST_VERBOSE};
	%ENV = (ONLINE_JUDGE => 1, PATH => $ENV{PATH}, HOME => $ENV{HOME});
	setrlimit RLIMIT_AS, $mlimit, $mlimit or die $! if $mlimit;
	setrlimit RLIMIT_FSIZE, $olimit, $olimit or die $! if $olimit;
	setrlimit RLIMIT_NPROC, $nproc, $nproc or die $! if $sudo;
	unshift @ARGV, @sudo;
	say STDERR "Executing: ", join ' ', map { "'$_'" } @ARGV if $debug;
	exec @ARGV;
}

1;
__END__

=encoding utf-8

=head1 NAME

gruntmaster-exec - Gruntmaster 6000 executor

=head1 SYNOPSIS

  gruntmaster-exec 20000000 111 echo 'Hello, world!'

=head1 DESCRIPTION

gruntmaster-exec is the script used by gruntmasterd to run programs.

The first argument is the address space limit (in bytes), the second argument is the output limit (also in bytes). The rest of the arguments are the command that should be run and its arguments.

gruntmaster-exec sets the resource limits, cleans the environment (except for PATH and HOME), adds the ONLINE_JUDGE environment variable with value 1, and finally C<exec>s the given command.

=head1 AUTHOR

Marius Gavrilescu E<lt>marius@ieval.roE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2014 by Marius Gavrilescu

This program is free software: you can redistribute it and/or modify
it under the terms of the GNU Affero General Public License as published by
the Free Software Foundation, either version 3 of the License, or
(at your option) any later version.
Commit	Line	Data
	1	#!/usr/bin/perl
	2	use v5.14;
	3	use strict;
	4	use warnings;
	5
	6	use constant +{
	7	# Accepted
	8	AC => 0,
	9
	10	# Internal server error
	11	ERR => -1,
	12
	13	# All other errors
	14	WA => 1,
	15	NZX => 2,
	16	TLE => 3,
	17	OLE => 4,
	18	DIED => 5,
	19	REJ => 10,
	20	};
	21
	22	use BSD::Resource qw/setrlimit RLIMIT_AS RLIMIT_FSIZE RLIMIT_NPROC/;
	23	use IPC::Signal qw/sig_name sig_num/;
	24	use sigtrap qw/XFSZ/;
	25
	26	use Getopt::Long;
	27	use POSIX qw//;
	28	use Text::ParseWords qw/shellwords/;
	29	use Time::HiRes qw/alarm/;
	30
	31	my (@fds, $timeout, $mlimit, $olimit, $sudo);
	32	my $close = 1;
	33
	34	GetOptions(
	35	"fd=s" => \@fds,
	36	"timeout=f" => \$timeout,
	37	"mlimit=i" => \$mlimit,
	38	"olimit=i" => \$olimit,
	39	"close!" => \$close,
	40	"sudo!" => \$sudo,
	41	);
	42
	43	my $killuser = $ENV{GRUNTMASTER_KILL_USER};
	44	my @sudo;
	45	@sudo = (shellwords ($ENV{GRUNTMASTER_SUDO}), '--') if $ENV{GRUNTMASTER_SUDO} && $sudo;
	46	undef $mlimit if @sudo; # sudo wants a lot of address space
	47
	48	my $ret = fork // die 'Cannot fork';
	49	if ($ret) {
	50	my $tle;
	51	local $SIG{ALRM} = sub {
	52	if ($killuser) {
	53	system @sudo, 'pkill', '-KILL', '-u', $killuser;
	54	} else {
	55	kill KILL => $ret
	56	}
	57	$tle = 1
	58	};
	59	alarm ($timeout \|\| 10);
	60	waitpid $ret, 0;
	61	alarm 0;
	62	if (@sudo) {
	63	$? = $? >> 8;
	64	$? = $? < 128 \|\| $? > 128+32 ? ($? << 8) : $? - 128;
	65	}
	66	my $sig = $? & 127;
	67	my $signame = sig_name $sig;
	68	exit !say TLE, "\nTime Limit Exceeded" if $tle;
	69	exit !say OLE, "\nOutput Limit Exceeded" if $sig && $signame eq 'XFSZ';
	70	exit !say DIED, "\nCrash (SIG$signame)" if $sig && $signame ne 'PIPE';
	71	exit !say NZX, "\nNon-zero exit status: " . ($? >> 8) if $? >> 8;
	72	exit !say AC, "\nAll OK";
	73	} else {
	74	$^F = 50;
	75	if ($close) {
	76	POSIX::close $_ for 0 .. $^F;
	77	}
	78	for my $fdstring (@fds) {
	79	my ($fd, $file) = split ' ', $fdstring, 2;
	80	open my $fh, $file or die $!;
	81	my $oldfd = fileno $fh;
	82	if ($oldfd != $fd) {
	83	POSIX::dup2 $oldfd, $fd or die $!;
	84	POSIX::close $oldfd or die $!;
	85	}
	86	}
	87	my $nproc = $killuser ? 15 : 1;
	88	my $debug = $ENV{TEST_VERBOSE};
	89	%ENV = (ONLINE_JUDGE => 1, PATH => $ENV{PATH}, HOME => $ENV{HOME});
	90	setrlimit RLIMIT_AS, $mlimit, $mlimit or die $! if $mlimit;
	91	setrlimit RLIMIT_FSIZE, $olimit, $olimit or die $! if $olimit;
	92	setrlimit RLIMIT_NPROC, $nproc, $nproc or die $! if $sudo;
	93	unshift @ARGV, @sudo;
	94	say STDERR "Executing: ", join ' ', map { "'$_'" } @ARGV if $debug;
	95	exec @ARGV;
	96	}
	97
	98	1;
	99	__END__
	100
	101	=encoding utf-8
	102
	103	=head1 NAME
	104
	105	gruntmaster-exec - Gruntmaster 6000 executor
	106
	107	=head1 SYNOPSIS
	108
	109	gruntmaster-exec 20000000 111 echo 'Hello, world!'
	110
	111	=head1 DESCRIPTION
	112
	113	gruntmaster-exec is the script used by gruntmasterd to run programs.
	114
	115	The first argument is the address space limit (in bytes), the second argument is the output limit (also in bytes). The rest of the arguments are the command that should be run and its arguments.
	116
	117	gruntmaster-exec sets the resource limits, cleans the environment (except for PATH and HOME), adds the ONLINE_JUDGE environment variable with value 1, and finally C<exec>s the given command.
	118
	119	=head1 AUTHOR
	120
	121	Marius Gavrilescu E<lt>marius@ieval.roE<gt>
	122
	123	=head1 COPYRIGHT AND LICENSE
	124
	125	Copyright (C) 2014 by Marius Gavrilescu
	126
	127	This program is free software: you can redistribute it and/or modify
	128	it under the terms of the GNU Affero General Public License as published by
	129	the Free Software Foundation, either version 3 of the License, or
	130	(at your option) any later version.