Limit user programs to one process
[gruntmaster-daemon.git] / gruntmaster-exec
1 #!/usr/bin/perl
2 use v5.14;
3 use strict;
4 use warnings;
5
6 use constant +{
7 # Accepted
8 AC => 0,
9
10 # Internal server error
11 ERR => -1,
12
13 # All other errors
14 WA => 1,
15 NZX => 2,
16 TLE => 3,
17 OLE => 4,
18 DIED => 5,
19 REJ => 10,
20 };
21 # These constants are changed by ex/makevm
22 use constant USER => 65534;
23 use constant GROUP => 65534;
24
25 use BSD::Resource qw/setrlimit RLIMIT_AS RLIMIT_FSIZE RLIMIT_NPROC/;
26 use IPC::Signal qw/sig_name sig_num/;
27 use sigtrap qw/XFSZ/;
28
29 use Getopt::Long;
30 use POSIX qw//;
31 use Time::HiRes qw/alarm/;
32
33 my (@fds, $timeout, $mlimit, $olimit, $nobody);
34 my $close = 1;
35
36 GetOptions(
37 "fd=s" => \@fds,
38 "timeout=f" => \$timeout,
39 "mlimit=i" => \$mlimit,
40 "olimit=i" => \$olimit,
41 "close!" => \$close,
42 "nobody!" => \$nobody,
43 );
44
45 my $ret = fork // die 'Cannot fork';
46 if ($ret) {
47 my $tle;
48 local $SIG{ALRM} = sub { kill KILL => $ret; $tle = 1};
49 alarm ($timeout || 5);
50 waitpid $ret, 0;
51 alarm 0;
52 my $sig = $? & 127;
53 my $signame = sig_name $sig;
54 exit !say TLE, "\nTime Limit Exceeded" if $tle;
55 exit !say OLE, "\nOutput Limit Exceeded" if $sig && $signame eq 'XFSZ';
56 exit !say DIED, "\nCrash (SIG$signame)" if $sig && $signame ne 'PIPE';
57 exit !say NZX, "\nNon-zero exit status: " . ($? >> 8) if $? >> 8;
58 exit !say AC, "\nAll OK";
59 } else {
60 $^F = 50;
61 if ($close) {
62 POSIX::close $_ for 0 .. $^F;
63 }
64 for my $fdstring (@fds) {
65 my ($fd, $file) = split ' ', $fdstring, 2;
66 open my $fh, $file or die $!;
67 my $oldfd = fileno $fh;
68 if ($oldfd != $fd) {
69 POSIX::dup2 $oldfd, $fd or die $!;
70 POSIX::close $oldfd or die $!;
71 }
72 }
73 %ENV = (ONLINE_JUDGE => 1, PATH => $ENV{PATH}, HOME => $ENV{HOME});
74 setrlimit RLIMIT_AS, $mlimit, $mlimit or die $! if $mlimit;
75 setrlimit RLIMIT_FSIZE, $olimit, $olimit or die $! if $olimit;
76 setrlimit RLIMIT_NPROC, 1, 1 or die $! if $nobody;
77 POSIX::setgid $nobody ? 65534 : USER;
78 POSIX::setuid $nobody ? 65534 : GROUP;
79 exec @ARGV;
80 }
81
82 1;
83 __END__
84
85 =encoding utf-8
86
87 =head1 NAME
88
89 gruntmaster-exec - Gruntmaster 6000 executor
90
91 =head1 SYNOPSIS
92
93 gruntmaster-exec 20000000 111 echo 'Hello, world!'
94
95 =head1 DESCRIPTION
96
97 gruntmaster-exec is the script used by gruntmasterd to run programs.
98
99 The first argument is the address space limit (in bytes), the second argument is the output limit (also in bytes). The rest of the arguments are the command that should be run and its arguments.
100
101 gruntmaster-exec sets the resource limits, cleans the environment (except for PATH and HOME), adds the ONLINE_JUDGE environment variable with value 1, and finally C<exec>s the given command.
102
103 =head1 AUTHOR
104
105 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
106
107 =head1 COPYRIGHT AND LICENSE
108
109 Copyright (C) 2014 by Marius Gavrilescu
110
111 This program is free software: you can redistribute it and/or modify
112 it under the terms of the GNU Affero General Public License as published by
113 the Free Software Foundation, either version 3 of the License, or
114 (at your option) any later version.
This page took 0.030853 seconds and 5 git commands to generate.