Add ruby
[gruntmaster-daemon.git] / lib / Gruntmaster / Daemon.pm
1 package Gruntmaster::Daemon;
2
3 use 5.014000;
4 use strict;
5 use warnings;
6
7 our $VERSION = '5999.000_004';
8
9 use Gruntmaster::Daemon::Constants qw/ERR/;
10 use Gruntmaster::Daemon::Format qw/prepare_files stopvms/;
11
12 use File::Temp qw/tempdir/;
13 use JSON qw/decode_json encode_json/;
14 use Sys::Hostname qw/hostname/;
15 use Time::HiRes qw/time/;
16 use Try::Tiny;
17 use Log::Log4perl qw/get_logger/;
18
19 use constant FORMAT_EXTENSION => {
20 C => 'c',
21 CPP => 'cpp',
22 GCCGO => 'go',
23 GOLANG => 'go',
24 HASKELL => 'hs',
25 MONO => 'cs',
26 JAVA => 'java',
27 PASCAL => 'pas',
28 PERL => 'pl',
29 PYTHON => 'py',
30 RUBY => 'rb',
31 SBCL => 'l',
32 };
33
34 ##################################################
35
36 my $db;
37
38 sub safe_can {
39 my ($type, $sub, $name) = @_;
40
41 get_logger->logdie("Invalid \l$type: '$name'") unless $name =~ /^\w+$/s;
42 my $pkg = __PACKAGE__ . "::${type}::${name}";
43 eval "require $pkg" or get_logger->warn("Error while requiring $pkg: $@");
44 $pkg->can($sub) or get_logger->logdie("No such \l$type: '$name'");
45 }
46
47 sub process{
48 my ($meta) = @_;
49
50 my @results;
51 my @full_results = ();
52 our $errors = '';
53 try {
54 prepare_files $meta;
55 chomp $errors;
56
57 my ($files, $generator, $runner, $judge, $testcnt) = map { $meta->{$_} or die "Required parameter missing: $_\n"} qw/files generator runner judge testcnt/;
58
59 $generator = safe_can Generator => generate => $generator;
60 $runner = safe_can Runner => run => $runner;
61 $judge = safe_can Judge => judge => $judge;
62
63 for my $test (1 .. $testcnt) {
64 my $start_time = time;
65 my $result;
66 try {
67 $generator->($test, $meta);
68 $result = $runner->($test, $meta);
69 } catch {
70 $result = $_;
71 unless (ref $result) {
72 chomp $result;
73 $result = [ERR, $result];
74 }
75 };
76
77 if (ref $result) {
78 get_logger->trace("Test $test result is " . $result->[1]);
79 push @full_results, {id => $test, result => $result->[0], result_text => $result->[1], time => time - $start_time}
80 } else {
81 get_logger->trace("Test $test result is $result");
82 push @full_results, {id => $test, result => 0, result_text => $result, time => time - $start_time}
83 }
84 push @results, $result;
85 last if $meta->{judge} eq 'Absolute' && ref $result
86 }
87
88 my %results = $judge->(@results);
89 $meta->{$_} = $results{$_} for keys %results;
90 $meta->{results} = \@full_results
91 } catch {
92 s/(.*) at .*/$1/s;
93 chomp;
94 $meta->{result} = -1;
95 $meta->{result_text} = $_;
96 };
97 stopvms;
98 $meta->{errors} = $errors;
99
100 get_logger->info('Job result: ' . $meta->{result_text});
101 }
102
103 sub process_job {
104 my ($job) = @_;
105 my $meta = {
106 problem => $job->problem->id,
107 files => {
108 prog => {
109 name => 'prog.' . $job->extension,
110 format => $job->format,
111 content => $job->source,
112 },
113 },
114 map { $_ => $job->problem->get_column($_) } qw/generator runner judge precnt testcnt timeout olimit/
115 };
116 $meta->{tests} = decode_json $job->problem->tests if $meta->{runner} eq 'File';
117 delete $meta->{precnt} if $job->problem->is_in_archive;
118 $meta->{testcnt} = $meta->{precnt} if $meta->{precnt};
119
120 $meta->{files}{ver} = {
121 name => 'ver.' . FORMAT_EXTENSION->{$job->problem->verformat},
122 format => $job->problem->verformat,
123 content => $job->problem->versource,
124 } if $job->problem->verformat;
125
126 process $meta;
127
128 $meta->{result_text} .= ' (pretests)' if $meta->{precnt};
129 $job->update({
130 result => $meta->{result},
131 result_text => $meta->{result_text},
132 ($meta->{results} ? (results => encode_json $meta->{results}) : ()),
133 $meta->{errors} ? (errors => $meta->{errors}) : ()
134 });
135
136 my $solved = $meta->{result} ? 0 : 1;
137 my $status = $db->problem_statuses->find($job->owner, $job->problem);
138 $db->problem_statuses->update_or_create({
139 problem => $job->problem,
140 owner => $job->owner,
141 job => $job->id,
142 solved => $solved}) if !$job->problem->is_private;
143 }
144
145 sub got_job{
146 my $job = $_[0];
147 my $id = $job->id;
148 get_logger->debug("Taking job $id...");
149 my $daemon = hostname . ":$$";
150 $job->update({daemon => $daemon}, {where => {daemon => undef}})->discard_changes;
151 if ($job->daemon eq $daemon) {
152 get_logger->debug("Succesfully taken job $id");
153 process_job $job;
154 get_logger->debug("Job $id done");
155 } else {
156 get_logger->debug("Job $id already taken by " . $job->daemon);
157 }
158 }
159
160 sub run{
161 require Gruntmaster::Data;
162 $db = Gruntmaster::Data->connect($ENV{GRUNTMASTER_DSN} // 'dbi:Pg:');
163 Log::Log4perl->init('/etc/gruntmasterd/gruntmasterd-log.conf');
164 get_logger->info("gruntmasterd $VERSION started");
165 my $dir = tempdir 'gruntmasterd.XXXX', CLEANUP => 1, TMPDIR => 1;
166 chmod 0711, $dir;
167 chdir $dir;
168 while (1) {
169 my $job = $db->jobs->search({daemon => undef}, {rows => 1})->first;
170 got_job $job if defined $job;
171 sleep 2 unless defined $job;
172 }
173 }
174
175 1;
176 __END__
177
178 =head1 NAME
179
180 Gruntmaster::Daemon - Gruntmaster 6000 Online Judge -- daemon
181
182 =head1 SYNOPSIS
183
184 use Gruntmaster::Daemon;
185 Gruntmaster::Daemon->run;
186
187 =head1 DESCRIPTION
188
189 Gruntmaster::Daemon is the daemon component of the Gruntmaster 6000 online judge.
190
191 =head1 AUTHOR
192
193 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
194
195 =head1 COPYRIGHT AND LICENSE
196
197 Copyright (C) 2014 by Marius Gavrilescu
198
199 This library is free software: you can redistribute it and/or modify
200 it under the terms of the GNU Affero General Public License as published by
201 the Free Software Foundation, either version 3 of the License, or
202 (at your option) any later version.
203
204
205 =cut
This page took 0.064256 seconds and 4 git commands to generate.