lib/Gruntmaster/Daemon.pm

   1 package Gruntmaster::Daemon;
   2
   3 use 5.014000;
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '5999.000_005';
   8
   9 use Gruntmaster::Daemon::Constants qw/ERR/;
  10 use Gruntmaster::Daemon::Format qw/prepare_files stopvms/;
  11
  12 use File::Slurp qw/read_file/;
  13 use File::Temp qw/tempdir/;
  14 use JSON qw/decode_json encode_json/;
  15 use Sys::Hostname qw/hostname/;
  16 use Time::HiRes qw/time/;
  17 use Try::Tiny;
  18 use Log::Log4perl qw/get_logger/;
  19
  20 use constant FORMAT_EXTENSION => {
  21         BRAINFUCK => 'bf',
  22         C => 'c',
  23         CPP => 'cpp',
  24         GCCGO => 'go',
  25         GOLANG => 'go',
  26         GOLFSCRIPT => 'gs',
  27         HASKELL => 'hs',
  28         JAVA => 'java',
  29         JULIA => 'jl',
  30         MONO => 'cs',
  31         OCAML => 'ml',
  32         PASCAL => 'pas',
  33         PERL => 'pl',
  34         PHP => 'php',
  35         PYTHON => 'py',
  36         RUBY => 'rb',
  37         RUST => 'rs',
  38         SBCL => 'l',
  39 };
  40
  41 ##################################################
  42
  43 sub safe_can {
  44         my ($type, $sub, $name) = @_;
  45
  46         get_logger->logdie("Invalid \l$type: '$name'") unless $name =~ /^\w+$/s;
  47         my $pkg = __PACKAGE__ . "::${type}::${name}";
  48         eval "require $pkg" or get_logger->warn("Error while requiring $pkg: $@");
  49         $pkg->can($sub) or get_logger->logdie("No such \l$type: '$name'");
  50 }
  51
  52 sub process{
  53         my ($meta) = @_;
  54
  55         my @results;
  56         my @full_results = ();
  57         our $errors = '';
  58         try {
  59                 prepare_files $meta;
  60                 chomp $errors;
  61
  62                 my ($files, $generator, $runner, $judge, $testcnt) = map { $meta->{$_} or die "Required parameter missing: $_\n"} qw/files generator runner judge testcnt/;
  63
  64                 $generator = safe_can Generator => generate => $generator;
  65                 $runner = safe_can Runner => run => $runner;
  66                 $judge = safe_can Judge => judge => $judge;
  67
  68                 for my $test (1 .. $testcnt) {
  69                         my $start_time = time;
  70                         my $result;
  71                         unlink 'result';
  72                         try {
  73                                 $generator->($test, $meta);
  74                                 $result = $runner->($test, $meta);
  75                         } catch {
  76                                 $result = $_;
  77                                 unless (ref $result) {
  78                                         chomp $result;
  79                                         $result = [ERR, $result];
  80                                 }
  81                         };
  82
  83                         if (ref $result) {
  84                                 my $result_text = $result->[1];
  85                                 $result_text .= ': ' . read_file 'result' if -s 'result';
  86                                 get_logger->trace("Test $test result is " . $result_text);
  87                                 push @full_results, {id => $test, result => $result->[0], result_text => $result_text, time => time - $start_time}
  88                         } else {
  89                                 get_logger->trace("Test $test result is $result");
  90                                 push @full_results, {id => $test, result => 0, result_text => $result, time => time - $start_time}
  91                         }
  92                         push @results, $result;
  93                         last if $meta->{judge} eq 'Absolute' && ref $result
  94                 }
  95
  96                 my %results = $judge->(@results);
  97                 $meta->{$_} = $results{$_} for keys %results;
  98                 $meta->{results} = \@full_results
  99         } catch {
 100                 s/(.*) at .*/$1/s;
 101                 chomp;
 102                 $meta->{result} = -1;
 103                 $meta->{result_text} = $_;
 104         };
 105         stopvms;
 106         $meta->{errors} = $errors;
 107
 108         get_logger->info('Job result: ' . $meta->{result_text});
 109 }
 110
 111 sub process_job {
 112         my ($job) = @_;
 113         my $pb = db()->select('problems', '*', {id => $job->{problem}})->hash;
 114         my $meta = {
 115                 problem => $job->{problem},
 116                 files => {
 117                         prog => {
 118                                 name => 'prog.' . $job->{extension},
 119                                 format => $job->{format},
 120                                 content => $job->{source},
 121                         },
 122                 },
 123                 map { $_ => $pb->{$_} } qw/generator runner judge precnt testcnt timeout olimit/
 124         };
 125         my $timeout_override = db()->query('SELECT timeout FROM limits WHERE problem=? AND format=?', $job->{problem}, $job->{format})->list;
 126         $meta->{timeout} = $timeout_override if defined $timeout_override;
 127         $meta->{tests} = decode_json $pb->{tests} if $meta->{runner} eq 'File';
 128         $job->{contest} &&= contest_entry($job->{contest});
 129         delete $meta->{precnt} unless $job->{contest} && $job->{contest}{started} && !$job->{contest}{finished}; ## no critic (ProhibitNegativeExpressionsInUnlessAndUntilConditions)
 130         $meta->{testcnt} = $meta->{precnt} if $meta->{precnt};
 131
 132         $meta->{files}{ver} = {
 133                 name => 'ver.' . FORMAT_EXTENSION->{$pb->{verformat}},
 134                 format => $pb->{verformat},
 135                 content => $pb->{versource},
 136         } if $pb->{verformat};
 137
 138         process $meta;
 139
 140         $meta->{result_text} .= ' (pretests)' if $meta->{precnt};
 141         finish_job($job, $job->{private} || $pb->{private},
 142           result => $meta->{result},
 143           result_text => $meta->{result_text},
 144           ($meta->{results} ? (results => encode_json $meta->{results}) : ()),
 145           $meta->{errors} ? (errors => $meta->{errors}) : ());
 146 }
 147
 148 sub got_job{
 149         my $job = $_[0];
 150         my $id = $job->{id};
 151         get_logger->debug("Processing job $id...");
 152         process_job $job;
 153         get_logger->debug("Job $id done");
 154 }
 155
 156 my $daemon = hostname . ":$$";
 157
 158 sub run{
 159         require Gruntmaster::Data;
 160         Gruntmaster::Data->import;
 161         dbinit($ENV{GRUNTMASTER_DSN} // 'dbi:Pg:');
 162         Log::Log4perl->init('/etc/gruntmasterd/gruntmasterd-log.conf');
 163         get_logger->info("gruntmasterd $VERSION started ($daemon)");
 164         my $dir = tempdir 'gruntmasterd.XXXX', CLEANUP => 1, TMPDIR => 1;
 165         chmod 0711, $dir;
 166         chdir $dir;
 167         while (1) {
 168                 my $job = take_job($daemon);
 169                 got_job $job if defined $job;
 170                 sleep 2 unless defined $job;
 171         }
 172 }
 173
 174 1;
 175 __END__
 176
 177 =head1 NAME
 178
 179 Gruntmaster::Daemon - Gruntmaster 6000 Online Judge -- daemon
 180
 181 =head1 SYNOPSIS
 182
 183   use Gruntmaster::Daemon;
 184   Gruntmaster::Daemon->run;
 185
 186 =head1 DESCRIPTION
 187
 188 Gruntmaster::Daemon is the daemon component of the Gruntmaster 6000 online judge.
 189
 190 =head1 AUTHOR
 191
 192 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
 193
 194 =head1 COPYRIGHT AND LICENSE
 195
 196 Copyright (C) 2014 by Marius Gavrilescu
 197
 198 This library is free software: you can redistribute it and/or modify
 199 it under the terms of the GNU Affero General Public License as published by
 200 the Free Software Foundation, either version 3 of the License, or
 201 (at your option) any later version.
 202
 203
 204 =cut