lib/Gruntmaster/Daemon/Format.pm

   1 package Gruntmaster::Daemon::Format;
   2
   3 use 5.014000;
   4 use strict;
   5 use warnings;
   6 use parent qw/Exporter/;
   7 no if $] > 5.017011, warnings => 'experimental::smartmatch';
   8
   9 use Digest::SHA qw/sha256_hex/;
  10 use Expect;
  11 use File::Basename qw/fileparse/;
  12 use File::Copy qw/cp/;
  13 use File::Slurp qw/read_file write_file/;
  14 use List::MoreUtils qw/natatime/;
  15 use Log::Log4perl qw/get_logger/;
  16 use String::ShellQuote qw/shell_quote/;
  17 use Try::Tiny;
  18
  19 our $VERSION = '5999.000_005';
  20 our @EXPORT_OK = qw/copy_from_vm copy_to_vm prepare_files stopvms/;
  21
  22 ##################################################
  23
  24 our (%vm, %pid);
  25
  26 sub copy_from_vm {
  27         my ($file) = @_;
  28         return unless $ENV{GRUNTMASTER_COPY_FROM_VM};
  29         get_logger->trace("Copying $file from VM");
  30         system $ENV{GRUNTMASTER_COPY_FROM_VM}, $file
  31 }
  32
  33 sub copy_to_vm {
  34         my ($file) = @_;
  35         return unless $ENV{GRUNTMASTER_COPY_TO_VM};
  36         get_logger->trace("Copying $file to VM");
  37         system $ENV{GRUNTMASTER_COPY_TO_VM}, $file
  38 }
  39
  40 sub runvm {
  41         my ($name, $arg) = @_;
  42         return unless $ENV{GRUNTMASTER_VM};
  43         my $cmd = $ENV{GRUNTMASTER_VM} . ' ' . $name;
  44         $cmd .= ' ' . $arg if $arg;
  45         get_logger->trace("Starting VM $name ($cmd)");
  46         $vm{$name} = Expect->new;
  47         $vm{$name}->raw_pty(1);
  48         $vm{$name}->log_stdout(0);
  49         $vm{$name}->spawn($cmd);
  50         $vm{$name}->expect(50, '# ') or get_logger->logdie("Error while starting VM $name: ". $vm{$name}->error);
  51         $vm{$name}->send("rm -rf ~/work/*\n");
  52         $vm{$name}->expect(50, '# ')
  53 }
  54
  55 sub stopvms {
  56         $_->hard_close for values %vm;
  57         %vm = %pid = ();
  58 }
  59
  60 sub execlist_finish {
  61         my ($vm, $kill) = @_;
  62
  63         if ($vm{$vm}) {
  64                 warn "Cannot kill VM\n" if $kill;
  65                 $vm{$vm}->expect(50, '# ');
  66         } else {
  67                 kill KILL => $pid{$vm} if $kill;
  68                 waitpid $pid{$vm}, 0;
  69         }
  70         return if $kill;
  71
  72         my $er = "exec-result-$vm";
  73         copy_from_vm $er;
  74         die "gruntmaster-exec died\n" if -z $er;
  75         my ($excode, $exmsg) = read_file $er;
  76         unlink $er;
  77         chomp ($excode, $exmsg); ## no critic (ProhibitParensWithBuiltins)
  78         get_logger->trace("Exec result from $vm: $excode $exmsg");
  79         die [$excode, $exmsg] if $excode; ## no critic (RequireCarping)
  80 }
  81
  82 sub execlist {
  83         my ($vm, @args) = @_;
  84         my $er = "exec-result-$vm";
  85         if ($vm{$vm}) {
  86                 my $cmd = ">$er " . shell_quote 'gruntmaster-exec', @args;
  87                 get_logger->trace("Running in VM $vm: $cmd");
  88                 $vm{$vm}->send($cmd, "\n");
  89         } else {
  90                 $pid{$vm} = fork // die "Cannot fork\n";
  91                 unless ($pid{$vm}) {
  92                         open STDOUT, '>', $er or die "Cannot open $er\n";
  93                         get_logger->trace("Running: gruntmaster-exec @args");
  94                         exec 'gruntmaster-exec', @args;
  95                 }
  96         }
  97 }
  98
  99 sub mkrun{
 100         my $format = shift;
 101         sub{
 102                 local *__ANON__ = 'mkrun_runner';
 103                 my ($name, %args) = @_;
 104                 get_logger->trace("Running $name...");
 105                 my $basename = fileparse $name, qr/[.][^.]*/s;
 106                 my @args = ('--sudo');
 107                 push @args, '--keep-stderr' if $ENV{TEST_VERBOSE};
 108                 push @args, '--timeout', $args{timeout} if $args{timeout};
 109                 push @args, '--mlimit',  $args{mlimit}  if $args{mlimit};
 110                 push @args, '--olimit',  $args{olimit}  if $args{olimit};
 111                 my @fds = exists $args{fds} ? @{$args{fds}} : ();
 112                 my $it = natatime 2, @fds;
 113                 while (my ($fd, $file) = $it->()) {
 114                         push @args, "--fd=$fd $file";
 115                 }
 116                 execlist $basename, @args, '--', "./$basename", @{$args{args}};
 117                 execlist_finish $basename unless $args{nonblocking}
 118         }
 119 }
 120
 121 sub prepare{
 122         my ($name, $format) = @_;
 123         get_logger->trace("Preparing file $name...");
 124
 125         try {
 126                 execlist prog => '--fd=1 >>errors', '--fd=2 >>errors', 'gruntmaster-compile', $format, $name;
 127                 execlist_finish 'prog';
 128         } catch {
 129                 my $exmsg = $_->[1];
 130                 die "Compile error ($exmsg)\n"
 131         } finally {
 132                 copy_from_vm 'errors';
 133                 $Gruntmaster::Daemon::errors .= read_file 'errors';
 134                 $Gruntmaster::Daemon::errors .= "\n" if -s 'errors';
 135                 unlink 'errors';
 136         };
 137 }
 138
 139 sub prepare_files{
 140         my $meta = shift;
 141         if ($meta->{runner} eq 'Interactive') {
 142                 runvm ver => '-serial unix:vm.sock,nowait,server';
 143                 runvm prog => '-serial unix:vm.sock,nowait';
 144         } else {
 145                 runvm $_ for keys %{$meta->{files}};
 146         }
 147
 148         for my $file (values %{$meta->{files}}) {
 149                 my ($format, $name, $content) = @{$file}{qw/format name content/};
 150
 151                 $file->{run} = mkrun($format);
 152                 write_file $name, $content;
 153                 copy_to_vm $name;
 154                 if ($ENV{GRUNTMASTER_CCACHE}) {
 155                         my $key = lc sha256_hex($content) . '-' . $format;
 156                         my $cachefn = "$ENV{GRUNTMASTER_CCACHE}/$key";
 157                         my $exefn = fileparse $name, qr/[.][^.]*/s;
 158                         if (cp $cachefn, $exefn) {
 159                                 get_logger->trace("File $name found in compilation cache")
 160                         } else {
 161                                 prepare $name, $format;
 162                                 cp $exefn, $cachefn
 163                         }
 164                 } else {
 165                         prepare $name, $format
 166                 }
 167         }
 168 }
 169
 170 1;
 171 __END__
 172
 173 =encoding utf-8
 174
 175 =head1 NAME
 176
 177 Gruntmaster::Daemon::Format - Utility functions for handling source files
 178
 179 =head1 SYNOPSIS
 180
 181   use Gruntmaster::Daemon::Format qw/prepare_files/;
 182   prepare_files { files => {
 183     prog => {
 184       name => 'prog.pl',
 185       format => 'PERL',
 186       content => 'print "Hello, world!"'
 187     },
 188     ver => {
 189       name => 'ver.cpp',
 190       format => 'CPP',
 191       content => ...
 192     },
 193   }};
 194
 195 =head1 DESCRIPTION
 196
 197 Gruntmaster::Daemon::Format exports utility functions for handling source files.
 198
 199 =over
 200
 201 =item B<prepare_files> I<$meta>
 202
 203 Compiles all the source files in C<< $meta->{files} >>.
 204
 205 =back
 206
 207 =head1 AUTHOR
 208
 209 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
 210
 211 =head1 COPYRIGHT AND LICENSE
 212
 213 Copyright (C) 2014 by Marius Gavrilescu
 214
 215 This library is free software: you can redistribute it and/or modify
 216 it under the terms of the GNU Affero General Public License as published by
 217 the Free Software Foundation, either version 3 of the License, or
 218 (at your option) any later version.
 219
 220
 221 =cut