Add perlcritic test and make code comply
[gruntmaster-daemon.git] / lib / Gruntmaster / Daemon / Format.pm
1 package Gruntmaster::Daemon::Format;
2
3 use 5.014000;
4 use strict;
5 use warnings;
6 use parent qw/Exporter/;
7 no if $] > 5.017011, warnings => 'experimental::smartmatch';
8
9 use Expect::Simple;
10 use File::Basename qw/fileparse/;
11 use File::Slurp qw/read_file write_file/;
12 use List::MoreUtils qw/natatime/;
13 use Log::Log4perl qw/get_logger/;
14 use POSIX qw/mkfifo/;
15 use String::ShellQuote qw/shell_quote/;
16 use Try::Tiny;
17
18 our $VERSION = '5999.000_004';
19 our @EXPORT_OK = qw/prepare_files stopvms/;
20
21 ##################################################
22
23 our (%vm);
24
25 sub runvm {
26 my ($name) = @_;
27 return unless $ENV{GRUNTMASTER_VM};
28 mkfifo "$name.in", 0600;
29 mkfifo "$name.out", 0600;
30 get_logger->trace("Starting VM $name");
31 $vm{$name} = Expect::Simple->new({
32 Cmd => "$ENV{GRUNTMASTER_VM} $name",
33 Prompt => '# ',
34 DisconnectCmd => 'exit',
35 RawPty => 1,
36 Timeout => 10,
37 });
38 }
39
40 sub stopvms { %vm = () }
41
42 sub execlist {
43 my ($vm, @args) = @_;
44 my $er = "exec-result-$vm";
45 if ($vm{$vm}) {
46 my $cmd = ">$er " . shell_quote 'gruntmaster-exec', @args;
47 get_logger->trace("Running in VM $vm: $cmd");
48 $vm{$vm}->send($cmd);
49 } else {
50 my $ret = fork // die "Cannot fork\n";
51 if ($ret) {
52 waitpid $ret, 0;
53 } else {
54 open STDOUT, '>', $er or die "Cannot open $er\n";
55 exec 'gruntmaster-exec', @args;
56 }
57 }
58
59 die "gruntmaster-exec died\n" if -z $er;
60 my ($excode, $exmsg) = read_file $er;
61 unlink $er;
62 chomp ($excode, $exmsg); ## no critic (ProhibitParensWithBuiltins)
63 get_logger->trace("Exec result: $excode $exmsg");
64 die [$excode, $exmsg] if $excode > 0; ## no critic (RequireCarping)
65 }
66
67 sub command_and_args{
68 my ($format, $basename) = @_;
69
70 given($format) {
71 "./$basename" when [qw/C CPP GCCGO GOLANG HASKELL PASCAL/];
72 "./$basename.exe" when 'MONO';
73 java => $basename when 'JAVA';
74 perl => $basename when 'PERL';
75 python => $basename when 'PYTHON';
76 default { die "Don't know how to execute format $format\n" }
77 }
78 }
79
80 sub mkrun{
81 my $format = shift;
82 sub{
83 local *__ANON__ = 'mkrun_runner';
84 my ($name, %args) = @_;
85 get_logger->trace("Running $name...");
86 my $basename = fileparse $name, qr/[.][^.]*/s;
87 my @args;
88 push @args, '--timeout', $args{timeout} if $args{timeout};
89 push @args, '--mlimit', $args{mlimit} if $args{mlimit};
90 push @args, '--olimit', $args{olimit} if $args{olimit};
91 my @fds = exists $args{fds} ? @{$args{fds}} : ();
92 my $it = natatime 2, @fds;
93 while (my ($fd, $file) = $it->()) {
94 push @args, "--fd=$fd $file";
95 }
96 execlist $basename, @args, command_and_args($format, $basename);
97 }
98 }
99
100 sub prepare{
101 my ($name, $format) = @_;
102 get_logger->trace("Preparing file $name...");
103
104 try {
105 execlist prog => '--fd=1 >>errors', '--fd=2 >>errors', 'gruntmaster-compile', $format, $name;
106 } catch {
107 die "Compile error\n"
108 } finally {
109 $Gruntmaster::Daemon::errors .= read_file 'errors';
110 $Gruntmaster::Daemon::errors .= "\n";
111 unlink 'errors';
112 };
113 }
114
115 sub prepare_files{
116 my $meta = shift;
117 runvm $_ for keys %{$meta->{files}};
118
119 for my $file (values %{$meta->{files}}) {
120 my ($format, $name, $content) = @{$file}{qw/format name content/};
121
122 $file->{run} = mkrun($format);
123 write_file $name, $content;
124 prepare $name, $format;
125 }
126 }
127
128 1;
129 __END__
130
131 =encoding utf-8
132
133 =head1 NAME
134
135 Gruntmaster::Daemon::Format - Utility functions for handling source files
136
137 =head1 SYNOPSIS
138
139 use Gruntmaster::Daemon::Format qw/prepare_files/;
140 prepare_files { files => {
141 prog => {
142 name => 'prog.pl',
143 format => 'PERL',
144 content => 'print "Hello, world!"'
145 },
146 ver => {
147 name => 'ver.cpp',
148 format => 'CPP',
149 content => ...
150 },
151 }};
152
153 =head1 DESCRIPTION
154
155 Gruntmaster::Daemon::Format exports utility functions for handling source files.
156
157 =over
158
159 =item B<prepare_files> I<$meta>
160
161 Compiles all the source files in C<< $meta->{files} >>.
162
163 =back
164
165 =head1 AUTHOR
166
167 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
168
169 =head1 COPYRIGHT AND LICENSE
170
171 Copyright (C) 2014 by Marius Gavrilescu
172
173 This library is free software: you can redistribute it and/or modify
174 it under the terms of the GNU Affero General Public License as published by
175 the Free Software Foundation, either version 3 of the License, or
176 (at your option) any later version.
177
178
179 =cut
This page took 0.033676 seconds and 4 git commands to generate.