lib/Gruntmaster/Daemon/Runner/Interactive.pm

   1 package Gruntmaster::Daemon::Runner::Interactive;
   2
   3 use 5.014000;
   4 use strict;
   5 use warnings;
   6
   7 use File::Slurp qw/slurp/;
   8 use Gruntmaster::Daemon::Constants qw/WA/;
   9 use Log::Log4perl qw/get_logger/;
  10 use POSIX qw/mkfifo/;
  11 use Try::Tiny;
  12
  13 our $VERSION = '5999.000_004';
  14
  15 ##################################################
  16
  17 sub run{
  18         my ($test, $meta) = @_;
  19         get_logger->trace("Running on test $test...");
  20
  21         mkfifo 'fifo1', 0600 or die "$!\n" unless -e 'fifo1';
  22         mkfifo 'fifo2', 0600 or die "$!\n" unless -e 'fifo2';
  23
  24         if ($test == 1 && $ENV{GRUNTMASTER_VM}) {
  25                 exec 'cat <prog.out >ver.in' if fork;
  26                 exec 'cat <ver.out >prog.in' if fork;
  27         }
  28
  29         my $ret = fork // get_logger->logdie("Fork failed: $!");
  30         if ($ret) {
  31                 try {
  32                         my @fds = $ENV{GRUNTMASTER_VM} ? qw,0 /dev/ttyS1 1 >/dev/ttyS1, : qw/0 fifo1 1 >fifo2/;
  33                         $meta->{files}{prog}{run}->($meta->{files}{prog}{name}, fds => \@fds, map {defined $meta->{$_} ? ($_ => $meta->{$_}) : () } qw/timeout mlimit/);
  34                 } catch {
  35                         die $_ ## no critic (RequireCarping)
  36                 } finally {
  37                         waitpid $ret, 0;
  38                 };
  39                 die [WA, 'Wrong Answer'] if $?; ## no critic (RequireCarping)
  40         } else {
  41                 try {
  42                         my @fds = $ENV{GRUNTMASTER_VM} ? qw,1 >/dev/ttyS1 0 /dev/ttyS1, : qw/1 >fifo1 0 fifo2/;
  43                         $meta->{files}{ver}{run}->($meta->{files}{ver}{name}, fds => [@fds, qw,4 >result,], args => [$test], map {defined $meta->{$_} ? ($_ => $meta->{$_}) : () } qw/timeout mlimit/);
  44                 } catch {
  45                         exit 1;
  46                 };
  47                 exit
  48         }
  49
  50         unlink 'fifo1';
  51         unlink 'fifo2';
  52
  53         scalar slurp 'result'
  54 }
  55
  56 1;
  57 __END__
  58
  59 =encoding utf-8
  60
  61 =head1 NAME
  62
  63 Gruntmaster::Daemon::Runner::Interactive - Make an interactive verifier talk to the program
  64
  65 =head1 SYNOPSIS
  66
  67   use Gruntmaster::Daemon::Runner::Interactive;
  68   Gruntmaster::Daemon::Runner::Interactive::run(5, $meta);
  69
  70 =head1 DESCRIPTION
  71
  72 B<WARNING: This runner is experimental!>
  73
  74 Gruntmaster::Daemon::Runner::Interactive is a runner which runs the program and an interactive verifier in parallel, connecting each program's STDIN to the other's STDOUT. The verifier, C<< $meta->{files}{ver} >>, should return nonzero if the program gives an incorrect answer, or print the test score to fd 4 then return 0 if the answer is correct.
  75
  76 =head1 AUTHOR
  77
  78 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
  79
  80 =head1 COPYRIGHT AND LICENSE
  81
  82 Copyright (C) 2014 by Marius Gavrilescu
  83
  84 This library is free software: you can redistribute it and/or modify
  85 it under the terms of the GNU Affero General Public License as published by
  86 the Free Software Foundation, either version 3 of the License, or
  87 (at your option) any later version.
  88
  89
  90 =cut