Fix purging of standings
[gruntmaster-daemon.git] / t / 01-jobs.t
1 #!/usr/bin/perl -w
2 use v5.14;
3 use strict;
4 use warnings;
5
6 use Gruntmaster::Daemon;
7
8 use Cwd qw/getcwd/;
9 use File::Basename qw/fileparse/;
10 use File::Slurp qw/read_file/;
11 use File::Temp qw/tempdir/;
12 use File::Which qw/which/;
13 use Hash::Merge qw/merge/;
14 use List::Util qw/sum/;
15 use Log::Log4perl;
16 use Test::More;
17 use YAML::Tiny qw/LoadFile/;
18
19 ##################################################
20
21 use constant COMPILER => {
22 qw/BRAINFUCK bfc
23 C gcc
24 CPP g++
25 D dmd
26 GOLFSCRIPT golfscript
27 MONO gmcs
28 JAVA javac
29 JULIA julia
30 PASCAL fpc
31 GOLANG go
32 GCCGO gccgo
33 HASKELL ghc
34 PERL perl
35 PHP php
36 PYTHON python2.7
37 RUBY ruby
38 RUST rustc
39 OBERON obc
40 OCAML ocaml
41 SBCL sbcl/};
42
43 my %needs_fork = map { $_ => 1 } qw/GOLANG GOLFSCRIPT GCCGO JAVA JULIA RUBY/;
44
45 my $loglevel = $ENV{TEST_LOG_LEVEL} // ($ENV{TEST_VERBOSE} ? 'TRACE' : 'OFF');
46 my $log_conf = <<CONF;
47 log4perl.category.Gruntmaster.Daemon = $loglevel, stderr
48
49 log4perl.appender.stderr = Log::Log4perl::Appender::Screen
50 log4perl.appender.stderr.layout = Log::Log4perl::Layout::PatternLayout
51 log4perl.appender.stderr.layout.ConversionPattern = [\%d] [\%F{1}:\%M{1}:\%L] [\%p] \%m\%n
52 CONF
53 Log::Log4perl->init(\$log_conf);
54
55 $ENV{PATH} = getcwd . ':' . $ENV{PATH};
56 umask 0022;
57
58 sub check_job{
59 my $meta = shift;
60 if (defined $meta->{results}) {
61 delete $meta->{results}[$_]{time} for keys @{$meta->{results}};
62 }
63 my $desc = $meta->{name} . ': ' . $meta->{test_name};
64 is $meta->{result}, $meta->{expected_result}, "Result is correct ($desc)";
65 is $meta->{result_text}, $meta->{expected_result_text}, "Result text is correct ($desc)";
66 is_deeply $meta->{results}, $meta->{expected_results}, "Results are correct ($desc)";
67 }
68
69 my @problems = exists $ENV{TEST_PROBLEMS} ? map {"t/problems/$_"} split ' ', $ENV{TEST_PROBLEMS} : <t/problems/*>;
70 @problems = grep { $_ !~ /hello/ } @problems unless $ENV{RELEASE_TESTING} || $ENV{TEST_PROBLEMS};
71
72 plan tests => 3 * sum map { my @temp = <$_/tests/*>; scalar @temp } @problems;
73 note "Problems to be tested: " . join ', ', @problems;
74
75 my $tempdir = tempdir "gruntmasterd-testingXXXX", TMPDIR => 1, CLEANUP => 1;
76 chmod 0777, $tempdir;
77
78 my $job = 0;
79
80 for my $problem (@problems) {
81 my $pbmeta = LoadFile "$problem/meta.yml";
82 for (1 .. $pbmeta->{testcnt}) {
83 $pbmeta->{infile}[$_ - 1] = read_file "$problem/$_.in" if $pbmeta->{generator} eq 'File';
84 $pbmeta->{okfile}[$_ - 1] = read_file "$problem/$_.ok" if $pbmeta->{runner} && $pbmeta->{runner} eq 'File';
85 }
86 if (exists $pbmeta->{files}) {
87 $_->{content} = read_file "$problem/$_->{name}" for values %{$pbmeta->{files}}
88 }
89
90 TODO: {
91 note "Now testing problem $pbmeta->{name} ($pbmeta->{description})";
92
93 for my $source (<$problem/tests/*>) {
94 SKIP: {
95 my $meta = LoadFile "$source/meta.yml";
96 if ($meta->{files}{prog}) {
97 my $format = $meta->{files}{prog}{format};
98 my $compiler = COMPILER->{$format};
99 skip "$compiler not found in path", 3 unless $ENV{GRUNTMASTER_VM} || which $compiler;
100 skip "$format requires multiple processes. Set GRUNTMASTER_KILL_USER and GRUNTMASTER_SUDO to allow multiple processes.", 3 if !$ENV{GRUNTMASTER_KILL_USER} && $needs_fork{$format};
101 $meta->{files}{prog}{content} = read_file "$source/$meta->{files}{prog}{name}";
102 }
103 $meta = merge $meta, $pbmeta;
104 local $TODO = $meta->{todo} if exists $meta->{todo};
105 note "Running $meta->{test_name} ($meta->{test_description})...";
106 my $savedcwd = getcwd;
107 chdir $tempdir;
108 Gruntmaster::Daemon::process $meta;
109 chdir $savedcwd;
110 check_job $meta;
111 }
112 }
113 }
114 }
This page took 0.058312 seconds and 5 git commands to generate.