[gruntmaster-data.git] / lib / Gruntmaster / Data.pm

use utf8;
package Gruntmaster::Data;

# Created by DBIx::Class::Schema::Loader
# DO NOT MODIFY THE FIRST PART OF THIS FILE

use strict;
use warnings;

use base 'DBIx::Class::Schema';

__PACKAGE__->load_namespaces;


# Created by DBIx::Class::Schema::Loader v0.07039 @ 2014-03-05 13:11:39
# DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:dAEmtAexvUaNXLgYz2rNEg

use parent qw/Exporter/;
our $VERSION = '5999.000_013';
our @EXPORT = qw/purge/; ## no critic (ProhibitAutomaticExportation)

use Lingua::EN::Inflect qw/PL_N/;
use JSON::MaybeXS qw/decode_json/;
use HTTP::Tiny;
use PerlX::Maybe qw/maybe/;
use Sub::Name qw/subname/;

use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private timeout olimit value/];
use constant USER_PUBLIC_COLUMNS => [qw/id admin name town university country level/];
use constant JOBS_PER_PAGE => 10;

sub dynsub{
	our ($name, $sub) = @_;
	no strict 'refs'; ## no critic (Strict)
	*$name = subname $name => $sub
}

BEGIN {
	for my $rs (qw/contest contest_problem job open problem user problem_status contest_status/) {
		my $rsname = ucfirst $rs;
		$rsname =~ s/_([a-z])/\u$1/gs;
		dynsub PL_N($rs) => sub { $_[0]->resultset($rsname)              };
		dynsub      $rs  => sub { $_[0]->resultset($rsname)->find($_[1]) };
	}
}

sub user_list {
	my ($self) = @_;
	my $rs = $self->users->search(undef, {columns => USER_PUBLIC_COLUMNS} );
	my (%solved, %attempted, %contests);

	for my $row ($self->problem_statuses->all) {
		$solved   {$row->rawowner}++ if     $row->solved;
		$attempted{$row->rawowner}++ unless $row->solved;
	}
	$contests{$_->rawowner}++ for $self->contest_statuses->all;

	[ sort { $b->{solved} <=> $a->{solved} or $b->{attempted} <=> $a->{attempted} } map { ## no critic (ProhibitReverseSort)
		my $id = $_->id;
		+{ $_->get_columns,
		   solved => ($solved{$id} // 0),
		   attempted => ($attempted{$id} // 0),
		   contests => ($contests{$id} // 0) }
	} $rs->all ]
}

sub user_entry {
	my ($self, $id) = @_;
	my $user = $self->users->find($id, {columns => USER_PUBLIC_COLUMNS, prefetch => [qw/problem_statuses contest_statuses/]});
	my @problems = map { {problem => $_->get_column('problem'), solved => $_->solved} } $user->problem_statuses->search(undef, {order_by => 'problem'});
	my @contests = map { {contest => $_->contest->id, contest_name => $_->contest->name, rank => $_->rank, score => $_->score} } $user->contest_statuses->search(undef, {prefetch => 'contest', order_by => 'contest.start DESC'});
	+{ $user->get_columns, problems => \@problems, contests => \@contests }
}

sub problem_list {
	my ($self, %args) = @_;
	my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
	push @columns, 'solution' if $args{solution} && $args{contest} && !$self->contest($args{contest})->is_running;
	my $rs = $self->problems->search(undef, {order_by => 'me.name', columns => \@columns, prefetch => 'owner'});
	$rs = $rs->search({-or => ['contest_problems.contest' => undef, 'contest.stop' => {'<=', time}], 'me.private' => 0}, {join => {'contest_problems' => 'contest'}, distinct => 1}) unless $args{contest} || $args{private};
	$rs = $rs->search({'contest_problems.contest' => $args{contest}}, {join => 'contest_problems'}) if $args{contest};
	$rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
	my %params;
	$params{contest} = $args{contest} if $args{contest};
	for ($rs->all) {
		$params{$_->level} //= [];
		push @{$params{$_->level}}, {$_->get_columns, owner_name => $_->owner->name} ;
	}
	\%params
}

sub problem_entry {
	my ($self, $id, $contest, $user) = @_;
	my $running = $contest && $self->contest($contest)->is_running;
	my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
	push @columns, 'statement';
	push @columns, 'solution' unless $running;
	my $pb = $self->problems->find($id, {columns => \@columns, prefetch => 'owner'});
	my $open;
	$open = $self->opens->find_or_create({
		contest => $contest,
		problem => $id,
		owner => $user,
		time => time,
	}) if $running;
	$contest &&= $self->contest($contest);
	+{
		$pb->get_columns,
		owner_name => $pb->owner->name,
		cansubmit => !$contest || !$contest->is_finished,
		$running ? (
			contest_start => $contest->start,
			contest_stop => $contest->stop,
			open_time => $open->time
		) : (),
	}
}

sub contest_list {
	my ($self, %args) = @_;
	my $rs = $self->contests->search(undef, {order_by => {-desc => 'start'}, prefetch => 'owner'});
	$rs = $rs->search({owner => $args{owner}}) if $args{owner};
	my %params;
	for ($rs->all) {
		my $state = $_->is_pending ? 'pending' : $_->is_running ? 'running' : 'finished';
		$params{$state} //= [];
		push @{$params{$state}}, { $_->get_columns, owner_name => $_->owner->name };
	}
	\%params
}

sub contest_entry {
	my ($self, $id) = @_;
	my $ct = $self->contest($id);
	+{ $ct->get_columns, started => !$ct->is_pending, owner_name => $ct->owner->name }
}

sub job_list {
	my ($self, %args) = @_;
	$args{page} //= 1;
	my $rs = $self->jobs->search({contest => $args{contest}}, {order_by => {-desc => 'me.id'}, prefetch => ['problem', 'owner'], rows => JOBS_PER_PAGE, page => $args{page}});
	$rs = $rs->search({'me.private'=> 0})          unless $args{private};
	$rs = $rs->search({'me.owner'  => $args{owner}})   if $args{owner};
	$rs = $rs->search({problem     => $args{problem}}) if $args{problem};
	return {
		log => [map {
			my %params = $_->get_columns;
			$params{owner_name}   = $_->owner->name;
			$params{problem_name} = $_->problem->name;
			$params{results} &&= decode_json $params{results};
			$params{size}      = length $params{source};
			delete $params{source};
			\%params
		} $rs->all],
		current_page => $rs->pager->current_page,
		maybe previous_page => $rs->pager->previous_page,
		maybe next_page => $rs->pager->next_page,
		maybe last_page => $rs->pager->last_page,
	}
}

sub job_entry {
	my ($self, $id) = @_;
	my $job = $self->jobs->find($id, {prefetch => ['problem', 'owner', 'contest']});
	my %params = $job->get_columns;
	$params{owner_name}   = $job->owner->name;
	$params{problem_name} = $job->problem->name;
	$params{contest_name} = $job->contest->name if $params{contest};
	$params{results} &&= decode_json $params{results};
	$params{size}      = length $params{source};
	delete $params{source};
	\%params
}

sub update_status {
	my ($self) = @_;
	my @jobs = $self->jobs->search({'me.private' => 0}, {cache => 1, prefetch => 'problem'})->all;

	my %private;
	my %hash;
	for (@jobs) {
		my $pb = $_->get_column('problem');
		$private{$pb} //= $_->problem->is_private;
		next if !$private{$pb};
		$hash{$pb, $_->get_column('owner')} = [$_->id, $_->result ? 0 : 1] for @jobs;
	}

	my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;

	my @contest_statuses = map {
		my $contest = $_->id;
		map { [$contest, $_->{user}, $_->{score}, $_->{rank}] } $_->standings
	} $self->contests->all;

	my $txn = sub {
		$self->problem_statuses->delete;
		$self->problem_statuses->populate([[qw/problem owner job solved/], @problem_statuses]);
		$self->contest_statuses->delete;
		$self->contest_statuses->populate([[qw/contest owner score rank/], @contest_statuses]);
	};

	$self->txn_do($txn);
}

my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
my $ht = HTTP::Tiny->new;

sub purge {
	$ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
}

1;

__END__

=encoding utf-8

=head1 NAME

Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools

=head1 SYNOPSIS

  my $db = Gruntmaster::Data->connect('dbi:Pg:');

  my $problem = $db->problem('my_problem');
  $problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
  $problem->rerun; # And rerun all jobs for this problem

  # ...

  my $contest = $db->contests->create({ # Create a new contest
    id => 'my_contest',
    name => 'My Awesome Contest',
    start => time + 100,
    end => time + 1900,
  });
  $db->contest_problems->create({ # Add a problem to the contest
    contest => 'my_contest',
    problem => 'my_problem',
  });

  say 'The contest has not started yet' if $contest->is_pending;

  # ...

  my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
  $_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest

=head1 DESCRIPTION

Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.

In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:

=over

=item contests

Equivalent to C<< $schema->resultset('Contest') >>

=item contest_problems

Equivalent to C<< $schema->resultset('ContestProblem') >>

=item jobs

Equivalent to C<< $schema->resultset('Job') >>

=item problems

Equivalent to C<< $schema->resultset('Problem') >>

=item users

Equivalent to C<< $schema->resultset('User') >>

=item contest($id)

Equivalent to C<< $schema->resultset('Contest')->find($id) >>

=item job($id)

Equivalent to C<< $schema->resultset('Job')->find($id) >>

=item problem($id)

Equivalent to C<< $schema->resultset('Problem')->find($id) >>

=item user($id)

Equivalent to C<< $schema->resultset('User')->find($id) >>

=item user_list

Returns a list of users as an arrayref containing hashrefs.

=item user_entry($id)

Returns a hashref with information about the user $id.

=item problem_list([%args])

Returns a list of problems grouped by level. A hashref with levels as keys.

Takes the following arguments:

=over

=item owner

Only show problems owned by this user

=item contest

Only show problems in this contest

=back

=item problem_entry($id, [$contest, $user])

Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.

=item contest_list([%args])

Returns a list of contests grouped by state. A hashref with the following keys:

=over

=item pending

An arrayref of hashrefs representing pending contests

=item running

An arrayref of hashrefs representing running contests

=item finished

An arrayref of hashrefs representing finished contests

=back

Takes the following arguments:

=over

=item owner

Only show contests owned by this user.

=back

=item contest_entry($id)

Returns a hashref with information about the contest $id.

=item job_list([%args])

Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:

=over

=item owner

Only show jobs submitted by this user.

=item contest

Only show jobs submitted in this contest.

=item problem

Only show jobs submitted for this problem.

=item page

Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.

=back

=item job_entry($id)

Returns a hashref with information about the job $id.

=back

=head1 AUTHOR

Marius Gavrilescu E<lt>marius@ieval.roE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2014 by Marius Gavrilescu

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.18.1 or,
at your option, any later version of Perl 5 you may have available.


=cut
Commit	Line	Data
4ed3f8e7	1	use utf8;
bbf8209c	2	package Gruntmaster::Data;
4ed3f8e7 MG	3
	4	# Created by DBIx::Class::Schema::Loader
	5	# DO NOT MODIFY THE FIRST PART OF THIS FILE
	6
	7	use strict;
bbf8209c	8	use warnings;
014ee8a6	9
4ed3f8e7 MG	10	use base 'DBIx::Class::Schema';
	11
	12	__PACKAGE__->load_namespaces;
014ee8a6	13
f7386aab	14
4ed3f8e7 MG	15	# Created by DBIx::Class::Schema::Loader v0.07039 @ 2014-03-05 13:11:39
	16	# DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:dAEmtAexvUaNXLgYz2rNEg
	17
edfc5928	18	use parent qw/Exporter/;
9e130d3b	19	our $VERSION = '5999.000_013';
de7226ca	20	our @EXPORT = qw/purge/; ## no critic (ProhibitAutomaticExportation)
4ed3f8e7 MG	21
4ed3f8e7 MG	22	use Lingua::EN::Inflect qw/PL_N/;
91203bd5	23	use JSON::MaybeXS qw/decode_json/;
edfc5928	24	use HTTP::Tiny;
3473324b	25	use PerlX::Maybe qw/maybe/;
4ed3f8e7	26	use Sub::Name qw/subname/;
014ee8a6	27
e890b3ae	28	use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private timeout olimit value/];
73243865	29	use constant USER_PUBLIC_COLUMNS => [qw/id admin name town university country level/];
de625c9b MG	30	use constant JOBS_PER_PAGE => 10;
de625c9b MG	31
014ee8a6	32	sub dynsub{
fb6a4e3d	33	our ($name, $sub) = @_;
dcd72991	34	no strict 'refs'; ## no critic (Strict)
fb6a4e3d	35	*$name = subname $name => $sub
014ee8a6 MG	36	}
	37
	38	BEGIN {
adb42d4d	39	for my $rs (qw/contest contest_problem job open problem user problem_status contest_status/) {
4ed3f8e7	40	my $rsname = ucfirst $rs;
dcd72991	41	$rsname =~ s/_([a-z])/\u$1/gs;
4ed3f8e7 MG	42	dynsub PL_N($rs) => sub { $_[0]->resultset($rsname) };
4ed3f8e7 MG	43	dynsub $rs => sub { $_[0]->resultset($rsname)->find($_[1]) };
014ee8a6 MG	44	}
	45	}
	46
de625c9b	47	sub user_list {
c9311d50 MG	48	my ($self) = @_;
	49	my $rs = $self->users->search(undef, {columns => USER_PUBLIC_COLUMNS} );
	50	my (%solved, %attempted, %contests);
	51
	52	for my $row ($self->problem_statuses->all) {
	53	$solved {$row->rawowner}++ if $row->solved;
	54	$attempted{$row->rawowner}++ unless $row->solved;
	55	}
	56	$contests{$_->rawowner}++ for $self->contest_statuses->all;
	57
1db27a21	58	[ sort { $b->{solved} <=> $a->{solved} or $b->{attempted} <=> $a->{attempted} } map { ## no critic (ProhibitReverseSort)
c9311d50 MG	59	my $id = $_->id;
	60	+{ $_->get_columns,
	61	solved => ($solved{$id} // 0),
	62	attempted => ($attempted{$id} // 0),
	63	contests => ($contests{$id} // 0) }
281c3952	64	} $rs->all ]
de625c9b MG	65	}
	66
	67	sub user_entry {
	68	my ($self, $id) = @_;
adb42d4d	69	my $user = $self->users->find($id, {columns => USER_PUBLIC_COLUMNS, prefetch => [qw/problem_statuses contest_statuses/]});
197d1959 MG	70	my @problems = map { {problem => $_->get_column('problem'), solved => $_->solved} } $user->problem_statuses->search(undef, {order_by => 'problem'});
197d1959 MG	71	my @contests = map { {contest => $_->contest->id, contest_name => $_->contest->name, rank => $_->rank, score => $_->score} } $user->contest_statuses->search(undef, {prefetch => 'contest', order_by => 'contest.start DESC'});
adb42d4d	72	+{ $user->get_columns, problems => \@problems, contests => \@contests }
de625c9b MG	73	}
	74
	75	sub problem_list {
	76	my ($self, %args) = @_;
4db1f725 MG	77	my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
	78	push @columns, 'solution' if $args{solution} && $args{contest} && !$self->contest($args{contest})->is_running;
	79	my $rs = $self->problems->search(undef, {order_by => 'me.name', columns => \@columns, prefetch => 'owner'});
d4c5bf27	80	$rs = $rs->search({-or => ['contest_problems.contest' => undef, 'contest.stop' => {'<=', time}], 'me.private' => 0}, {join => {'contest_problems' => 'contest'}, distinct => 1}) unless $args{contest} \|\| $args{private};
de625c9b MG	81	$rs = $rs->search({'contest_problems.contest' => $args{contest}}, {join => 'contest_problems'}) if $args{contest};
	82	$rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
	83	my %params;
	84	$params{contest} = $args{contest} if $args{contest};
	85	for ($rs->all) {
	86	$params{$_->level} //= [];
35596ea8	87	push @{$params{$_->level}}, {$_->get_columns, owner_name => $_->owner->name} ;
de625c9b MG	88	}
	89	\%params
	90	}
	91
	92	sub problem_entry {
	93	my ($self, $id, $contest, $user) = @_;
de625c9b	94	my $running = $contest && $self->contest($contest)->is_running;
4db1f725 MG	95	my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
	96	push @columns, 'statement';
	97	push @columns, 'solution' unless $running;
	98	my $pb = $self->problems->find($id, {columns => \@columns, prefetch => 'owner'});
9396be04 MG	99	my $open;
	100	$open = $self->opens->find_or_create({
	101	contest => $contest,
	102	problem => $id,
	103	owner => $user,
	104	time => time,
	105	}) if $running;
2431260b	106	$contest &&= $self->contest($contest);
9396be04 MG	107	+{
	108	$pb->get_columns,
	109	owner_name => $pb->owner->name,
1ecf0766	110	cansubmit => !$contest \|\| !$contest->is_finished,
9396be04 MG	111	$running ? (
	112	contest_start => $contest->start,
	113	contest_stop => $contest->stop,
	114	open_time => $open->time
	115	) : (),
	116	}
de625c9b MG	117	}
	118
	119	sub contest_list {
	120	my ($self, %args) = @_;
	121	my $rs = $self->contests->search(undef, {order_by => {-desc => 'start'}, prefetch => 'owner'});
	122	$rs = $rs->search({owner => $args{owner}}) if $args{owner};
	123	my %params;
	124	for ($rs->all) {
	125	my $state = $_->is_pending ? 'pending' : $_->is_running ? 'running' : 'finished';
	126	$params{$state} //= [];
b3cf23ae	127	push @{$params{$state}}, { $_->get_columns, owner_name => $_->owner->name };
de625c9b MG	128	}
	129	\%params
	130	}
	131
	132	sub contest_entry {
	133	my ($self, $id) = @_;
	134	my $ct = $self->contest($id);
	135	+{ $ct->get_columns, started => !$ct->is_pending, owner_name => $ct->owner->name }
	136	}
	137
	138	sub job_list {
	139	my ($self, %args) = @_;
	140	$args{page} //= 1;
17d49281	141	my $rs = $self->jobs->search({contest => $args{contest}}, {order_by => {-desc => 'me.id'}, prefetch => ['problem', 'owner'], rows => JOBS_PER_PAGE, page => $args{page}});
d4c5bf27 MG	142	$rs = $rs->search({'me.private'=> 0}) unless $args{private};
d4c5bf27 MG	143	$rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
d4c5bf27	144	$rs = $rs->search({problem => $args{problem}}) if $args{problem};
3473324b MG	145	return {
	146	log => [map {
	147	my %params = $_->get_columns;
	148	$params{owner_name} = $_->owner->name;
	149	$params{problem_name} = $_->problem->name;
	150	$params{results} &&= decode_json $params{results};
	151	$params{size} = length $params{source};
	152	delete $params{source};
	153	\%params
	154	} $rs->all],
	155	current_page => $rs->pager->current_page,
	156	maybe previous_page => $rs->pager->previous_page,
	157	maybe next_page => $rs->pager->next_page,
	158	maybe last_page => $rs->pager->last_page,
	159	}
de625c9b MG	160	}
	161
	162	sub job_entry {
	163	my ($self, $id) = @_;
7d499cdd	164	my $job = $self->jobs->find($id, {prefetch => ['problem', 'owner', 'contest']});
de625c9b MG	165	my %params = $job->get_columns;
	166	$params{owner_name} = $job->owner->name;
	167	$params{problem_name} = $job->problem->name;
7d499cdd	168	$params{contest_name} = $job->contest->name if $params{contest};
de625c9b MG	169	$params{results} &&= decode_json $params{results};
	170	$params{size} = length $params{source};
	171	delete $params{source};
	172	\%params
	173	}
	174
adb42d4d MG	175	sub update_status {
adb42d4d MG	176	my ($self) = @_;
c314c866	177	my @jobs = $self->jobs->search({'me.private' => 0}, {cache => 1, prefetch => 'problem'})->all;
a2aa46e6	178
27a32e4b	179	my %private;
adb42d4d	180	my %hash;
64bc7dfb	181	for (@jobs) {
27a32e4b MG	182	my $pb = $_->get_column('problem');
	183	$private{$pb} //= $_->problem->is_private;
	184	next if !$private{$pb};
	185	$hash{$pb, $_->get_column('owner')} = [$_->id, $_->result ? 0 : 1] for @jobs;
64bc7dfb MG	186	}
64bc7dfb MG	187
adb42d4d MG	188	my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;
	189
	190	my @contest_statuses = map {
	191	my $contest = $_->id;
751c70b5	192	map { [$contest, $_->{user}, $_->{score}, $_->{rank}] } $_->standings
adb42d4d MG	193	} $self->contests->all;
	194
	195	my $txn = sub {
	196	$self->problem_statuses->delete;
	197	$self->problem_statuses->populate([[qw/problem owner job solved/], @problem_statuses]);
	198	$self->contest_statuses->delete;
	199	$self->contest_statuses->populate([[qw/contest owner score rank/], @contest_statuses]);
	200	};
	201
	202	$self->txn_do($txn);
	203	}
	204
edfc5928 MG	205	my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
	206	my $ht = HTTP::Tiny->new;
	207
de7226ca MG	208	sub purge {
	209	$ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
	210	}
edfc5928	211
f7386aab	212	1;
4a8747ef MG	213
	214	__END__
	215
	216	=encoding utf-8
	217
	218	=head1 NAME
	219
	220	Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools
	221
	222	=head1 SYNOPSIS
	223
	224	my $db = Gruntmaster::Data->connect('dbi:Pg:');
cbb36c78 MG	225
	226	my $problem = $db->problem('my_problem');
	227	$problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
	228	$problem->rerun; # And rerun all jobs for this problem
	229
	230	# ...
	231
	232	my $contest = $db->contests->create({ # Create a new contest
	233	id => 'my_contest',
	234	name => 'My Awesome Contest',
	235	start => time + 100,
	236	end => time + 1900,
	237	});
	238	$db->contest_problems->create({ # Add a problem to the contest
	239	contest => 'my_contest',
	240	problem => 'my_problem',
	241	});
	242
	243	say 'The contest has not started yet' if $contest->is_pending;
	244
	245	# ...
	246
	247	my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
	248	$_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest
4a8747ef MG	249
	250	=head1 DESCRIPTION
	251
cbb36c78 MG	252	Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.
	253
	254	In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:
	255
	256	=over
	257
	258	=item contests
	259
	260	Equivalent to C<< $schema->resultset('Contest') >>
	261
	262	=item contest_problems
	263
	264	Equivalent to C<< $schema->resultset('ContestProblem') >>
	265
	266	=item jobs
	267
	268	Equivalent to C<< $schema->resultset('Job') >>
	269
	270	=item problems
	271
	272	Equivalent to C<< $schema->resultset('Problem') >>
	273
	274	=item users
	275
	276	Equivalent to C<< $schema->resultset('User') >>
	277
	278	=item contest($id)
	279
	280	Equivalent to C<< $schema->resultset('Contest')->find($id) >>
	281
	282	=item job($id)
	283
	284	Equivalent to C<< $schema->resultset('Job')->find($id) >>
	285
	286	=item problem($id)
	287
	288	Equivalent to C<< $schema->resultset('Problem')->find($id) >>
	289
	290	=item user($id)
	291
	292	Equivalent to C<< $schema->resultset('User')->find($id) >>
	293
de625c9b MG	294	=item user_list
	295
	296	Returns a list of users as an arrayref containing hashrefs.
	297
	298	=item user_entry($id)
	299
	300	Returns a hashref with information about the user $id.
	301
	302	=item problem_list([%args])
	303
	304	Returns a list of problems grouped by level. A hashref with levels as keys.
	305
	306	Takes the following arguments:
	307
	308	=over
	309
	310	=item owner
	311
	312	Only show problems owned by this user
	313
	314	=item contest
	315
	316	Only show problems in this contest
	317
	318	=back
	319
	320	=item problem_entry($id, [$contest, $user])
	321
	322	Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.
	323
	324	=item contest_list([%args])
	325
	326	Returns a list of contests grouped by state. A hashref with the following keys:
	327
	328	=over
	329
	330	=item pending
	331
	332	An arrayref of hashrefs representing pending contests
	333
	334	=item running
	335
	336	An arrayref of hashrefs representing running contests
	337
	338	=item finished
	339
	340	An arrayref of hashrefs representing finished contests
	341
	342	=back
	343
	344	Takes the following arguments:
	345
	346	=over
	347
	348	=item owner
	349
	350	Only show contests owned by this user.
	351
	352	=back
	353
	354	=item contest_entry($id)
	355
	356	Returns a hashref with information about the contest $id.
	357
358	=item job_list([%args])
359
360	Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:
361
362	=over
363
364	=item owner
365
366	Only show jobs submitted by this user.
367
368	=item contest
369
370	Only show jobs submitted in this contest.
371
372	=item problem
373
374	Only show jobs submitted for this problem.
375
376	=item page
377
378	Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.
379
380	=back
381
382	=item job_entry($id)
383
384	Returns a hashref with information about the job $id.
385
cbb36c78	386	=back
4a8747ef MG	387
	388	=head1 AUTHOR
	389
	390	Marius Gavrilescu E<lt>marius@ieval.roE<gt>
	391
	392	=head1 COPYRIGHT AND LICENSE
	393
	394	Copyright (C) 2014 by Marius Gavrilescu
	395
9d2e740e MG	396	This library is free software; you can redistribute it and/or modify
	397	it under the same terms as Perl itself, either Perl version 5.18.1 or,
	398	at your option, any later version of Perl 5 you may have available.
4a8747ef MG	399
	400
	401	=cut