[gruntmaster-data.git] / lib / Gruntmaster / Data.pm

use utf8;
package Gruntmaster::Data;

# Created by DBIx::Class::Schema::Loader
# DO NOT MODIFY THE FIRST PART OF THIS FILE

use strict;
use warnings;

use base 'DBIx::Class::Schema';

__PACKAGE__->load_namespaces;


# Created by DBIx::Class::Schema::Loader v0.07039 @ 2014-03-05 13:11:39
# DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:dAEmtAexvUaNXLgYz2rNEg

use parent qw/Exporter/;
our $VERSION = '5999.000_013';
our @EXPORT = qw/purge/; ## no critic (ProhibitAutomaticExportation)

use Lingua::EN::Inflect qw/PL_N/;
use JSON::MaybeXS qw/decode_json/;
use HTTP::Tiny;
use PerlX::Maybe qw/maybe/;
use Sub::Name qw/subname/;

use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private timeout olimit value/];
use constant USER_PUBLIC_COLUMNS => [qw/id admin name town university level/];
use constant JOBS_PER_PAGE => 10;

sub dynsub{
	our ($name, $sub) = @_;
	no strict 'refs'; ## no critic (Strict)
	*$name = subname $name => $sub
}

BEGIN {
	for my $rs (qw/contest contest_problem job open problem user problem_status contest_status/) {
		my $rsname = ucfirst $rs;
		$rsname =~ s/_([a-z])/\u$1/gs;
		dynsub PL_N($rs) => sub { $_[0]->resultset($rsname)              };
		dynsub      $rs  => sub { $_[0]->resultset($rsname)->find($_[1]) };
	}
}

sub user_list {
	my ($self) = @_;
	my $rs = $self->users->search(undef, {columns => USER_PUBLIC_COLUMNS} );
	my (%solved, %attempted, %contests);

	for my $row ($self->problem_statuses->all) {
		$solved   {$row->rawowner}++ if     $row->solved;
		$attempted{$row->rawowner}++ unless $row->solved;
	}
	$contests{$_->rawowner}++ for $self->contest_statuses->all;

	[ sort { $b->{solved} <=> $a->{solved} or $b->{attempted} <=> $a->{attempted} } map { ## no critic (ProhibitReverseSort)
		my $id = $_->id;
		+{ $_->get_columns,
		   solved => ($solved{$id} // 0),
		   attempted => ($attempted{$id} // 0),
		   contests => ($contests{$id} // 0) }
	} $rs->all ]
}

sub user_entry {
	my ($self, $id) = @_;
	my $user = $self->users->find($id, {columns => USER_PUBLIC_COLUMNS, prefetch => [qw/problem_statuses contest_statuses/]});
	my @problems = map { {problem => $_->get_column('problem'), solved => $_->solved} } $user->problem_statuses->search(undef, {order_by => 'problem'});
	my @contests = map { {contest => $_->contest->id, contest_name => $_->contest->name, rank => $_->rank, score => $_->score} } $user->contest_statuses->search(undef, {prefetch => 'contest', order_by => 'contest.start DESC'});
	+{ $user->get_columns, problems => \@problems, contests => \@contests }
}

sub problem_list {
	my ($self, %args) = @_;
	my $rs = $self->problems->search(undef, {order_by => 'me.name', columns => PROBLEM_PUBLIC_COLUMNS, prefetch => 'owner'});
	$rs = $rs->search({-or => ['contest_problems.contest' => undef, 'contest.stop' => {'<=', time}], 'me.private' => 0}, {join => {'contest_problems' => 'contest'}, distinct => 1}) unless $args{contest} || $args{private};
	$rs = $rs->search({'contest_problems.contest' => $args{contest}}, {join => 'contest_problems'}) if $args{contest};
	$rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
	my %params;
	$params{contest} = $args{contest} if $args{contest};
	for ($rs->all) {
		$params{$_->level} //= [];
		push @{$params{$_->level}}, {$_->get_columns, owner_name => $_->owner->name} ;
	}
	\%params
}

sub problem_entry {
	my ($self, $id, $contest, $user) = @_;
	my $running = $contest && $self->contest($contest)->is_running;
	my $columns = PROBLEM_PUBLIC_COLUMNS;
	push @$columns, 'statement';
	push @$columns, 'solution' unless $running;
	my $pb = $self->problems->find($id, {columns => $columns, prefetch => 'owner'});
	my $open;
	$open = $self->opens->find_or_create({
		contest => $contest,
		problem => $id,
		owner => $user,
		time => time,
	}) if $running;
	$contest &&= $self->contest($contest);
	+{
		$pb->get_columns,
		owner_name => $pb->owner->name,
		cansubmit => !$contest || !$contest->is_finished,
		$running ? (
			contest_start => $contest->start,
			contest_stop => $contest->stop,
			open_time => $open->time
		) : (),
	}
}

sub contest_list {
	my ($self, %args) = @_;
	my $rs = $self->contests->search(undef, {order_by => {-desc => 'start'}, prefetch => 'owner'});
	$rs = $rs->search({owner => $args{owner}}) if $args{owner};
	my %params;
	for ($rs->all) {
		my $state = $_->is_pending ? 'pending' : $_->is_running ? 'running' : 'finished';
		$params{$state} //= [];
		push @{$params{$state}}, { $_->get_columns, started => !$_->is_pending, owner_name => $_->owner->name };
	}
	\%params
}

sub contest_entry {
	my ($self, $id) = @_;
	my $ct = $self->contest($id);
	+{ $ct->get_columns, started => !$ct->is_pending, owner_name => $ct->owner->name }
}

sub job_list {
	my ($self, %args) = @_;
	$args{page} //= 1;
	my $rs = $self->jobs->search({contest => $args{contest}}, {order_by => {-desc => 'me.id'}, prefetch => ['problem', 'owner'], rows => JOBS_PER_PAGE, page => $args{page}});
	$rs = $rs->search({'me.private'=> 0})          unless $args{private};
	$rs = $rs->search({'me.owner'  => $args{owner}})   if $args{owner};
	$rs = $rs->search({problem     => $args{problem}}) if $args{problem};
	return {
		log => [map {
			my %params = $_->get_columns;
			$params{owner_name}   = $_->owner->name;
			$params{problem_name} = $_->problem->name;
			$params{results} &&= decode_json $params{results};
			$params{size}      = length $params{source};
			delete $params{source};
			\%params
		} $rs->all],
		current_page => $rs->pager->current_page,
		maybe previous_page => $rs->pager->previous_page,
		maybe next_page => $rs->pager->next_page,
		maybe last_page => $rs->pager->last_page,
	}
}

sub job_entry {
	my ($self, $id) = @_;
	my $job = $self->jobs->find($id, {prefetch => ['problem', 'owner', 'contest']});
	my %params = $job->get_columns;
	$params{owner_name}   = $job->owner->name;
	$params{problem_name} = $job->problem->name;
	$params{contest_name} = $job->contest->name if $params{contest};
	$params{results} &&= decode_json $params{results};
	$params{size}      = length $params{source};
	delete $params{source};
	\%params
}

sub update_status {
	my ($self) = @_;
	my @jobs = $self->jobs->search(undef, {cache => 1})->all;

	my %hash;
	$hash{$_->get_column('problem'), $_->get_column('owner')} = [$_->id, $_->result ? 0 : 1] for @jobs;
	my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;

	my @contest_statuses = map {
		my $contest = $_->id;
		map { [$contest, $_->{user}, $_->{score}, $_->{rank}] } $_->standings
	} $self->contests->all;

	my $txn = sub {
		$self->problem_statuses->delete;
		$self->problem_statuses->populate([[qw/problem owner job solved/], @problem_statuses]);
		$self->contest_statuses->delete;
		$self->contest_statuses->populate([[qw/contest owner score rank/], @contest_statuses]);
	};

	$self->txn_do($txn);
}

my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
my $ht = HTTP::Tiny->new;

sub purge {
	$ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
}

1;

__END__

=encoding utf-8

=head1 NAME

Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools

=head1 SYNOPSIS

  my $db = Gruntmaster::Data->connect('dbi:Pg:');

  my $problem = $db->problem('my_problem');
  $problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
  $problem->rerun; # And rerun all jobs for this problem

  # ...

  my $contest = $db->contests->create({ # Create a new contest
    id => 'my_contest',
    name => 'My Awesome Contest',
    start => time + 100,
    end => time + 1900,
  });
  $db->contest_problems->create({ # Add a problem to the contest
    contest => 'my_contest',
    problem => 'my_problem',
  });

  say 'The contest has not started yet' if $contest->is_pending;

  # ...

  my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
  $_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest

=head1 DESCRIPTION

Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.

In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:

=over

=item contests

Equivalent to C<< $schema->resultset('Contest') >>

=item contest_problems

Equivalent to C<< $schema->resultset('ContestProblem') >>

=item jobs

Equivalent to C<< $schema->resultset('Job') >>

=item problems

Equivalent to C<< $schema->resultset('Problem') >>

=item users

Equivalent to C<< $schema->resultset('User') >>

=item contest($id)

Equivalent to C<< $schema->resultset('Contest')->find($id) >>

=item job($id)

Equivalent to C<< $schema->resultset('Job')->find($id) >>

=item problem($id)

Equivalent to C<< $schema->resultset('Problem')->find($id) >>

=item user($id)

Equivalent to C<< $schema->resultset('User')->find($id) >>

=item user_list

Returns a list of users as an arrayref containing hashrefs.

=item user_entry($id)

Returns a hashref with information about the user $id.

=item problem_list([%args])

Returns a list of problems grouped by level. A hashref with levels as keys.

Takes the following arguments:

=over

=item owner

Only show problems owned by this user

=item contest

Only show problems in this contest

=back

=item problem_entry($id, [$contest, $user])

Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.

=item contest_list([%args])

Returns a list of contests grouped by state. A hashref with the following keys:

=over

=item pending

An arrayref of hashrefs representing pending contests

=item running

An arrayref of hashrefs representing running contests

=item finished

An arrayref of hashrefs representing finished contests

=back

Takes the following arguments:

=over

=item owner

Only show contests owned by this user.

=back

=item contest_entry($id)

Returns a hashref with information about the contest $id.

=item job_list([%args])

Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:

=over

=item owner

Only show jobs submitted by this user.

=item contest

Only show jobs submitted in this contest.

=item problem

Only show jobs submitted for this problem.

=item page

Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.

=back

=item job_entry($id)

Returns a hashref with information about the job $id.

=back

=head1 AUTHOR

Marius Gavrilescu E<lt>marius@ieval.roE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2014 by Marius Gavrilescu

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.18.1 or,
at your option, any later version of Perl 5 you may have available.


=cut
Commit	Line	Data
4ed3f8e7	1	use utf8;
bbf8209c	2	package Gruntmaster::Data;
4ed3f8e7 MG	3
	4	# Created by DBIx::Class::Schema::Loader
	5	# DO NOT MODIFY THE FIRST PART OF THIS FILE
	6
	7	use strict;
bbf8209c	8	use warnings;
014ee8a6	9
4ed3f8e7 MG	10	use base 'DBIx::Class::Schema';
	11
	12	__PACKAGE__->load_namespaces;
014ee8a6	13
f7386aab	14
4ed3f8e7 MG	15	# Created by DBIx::Class::Schema::Loader v0.07039 @ 2014-03-05 13:11:39
	16	# DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:dAEmtAexvUaNXLgYz2rNEg
	17
edfc5928	18	use parent qw/Exporter/;
9e130d3b	19	our $VERSION = '5999.000_013';
de7226ca	20	our @EXPORT = qw/purge/; ## no critic (ProhibitAutomaticExportation)
4ed3f8e7 MG	21
4ed3f8e7 MG	22	use Lingua::EN::Inflect qw/PL_N/;
91203bd5	23	use JSON::MaybeXS qw/decode_json/;
edfc5928	24	use HTTP::Tiny;
3473324b	25	use PerlX::Maybe qw/maybe/;
4ed3f8e7	26	use Sub::Name qw/subname/;
014ee8a6	27
e890b3ae	28	use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private timeout olimit value/];
de625c9b MG	29	use constant USER_PUBLIC_COLUMNS => [qw/id admin name town university level/];
	30	use constant JOBS_PER_PAGE => 10;
	31
014ee8a6	32	sub dynsub{
fb6a4e3d	33	our ($name, $sub) = @_;
dcd72991	34	no strict 'refs'; ## no critic (Strict)
fb6a4e3d	35	*$name = subname $name => $sub
014ee8a6 MG	36	}
	37
	38	BEGIN {
adb42d4d	39	for my $rs (qw/contest contest_problem job open problem user problem_status contest_status/) {
4ed3f8e7	40	my $rsname = ucfirst $rs;
dcd72991	41	$rsname =~ s/_([a-z])/\u$1/gs;
4ed3f8e7 MG	42	dynsub PL_N($rs) => sub { $_[0]->resultset($rsname) };
4ed3f8e7 MG	43	dynsub $rs => sub { $_[0]->resultset($rsname)->find($_[1]) };
014ee8a6 MG	44	}
	45	}
	46
de625c9b	47	sub user_list {
c9311d50 MG	48	my ($self) = @_;
	49	my $rs = $self->users->search(undef, {columns => USER_PUBLIC_COLUMNS} );
	50	my (%solved, %attempted, %contests);
	51
	52	for my $row ($self->problem_statuses->all) {
	53	$solved {$row->rawowner}++ if $row->solved;
	54	$attempted{$row->rawowner}++ unless $row->solved;
	55	}
	56	$contests{$_->rawowner}++ for $self->contest_statuses->all;
	57
1db27a21	58	[ sort { $b->{solved} <=> $a->{solved} or $b->{attempted} <=> $a->{attempted} } map { ## no critic (ProhibitReverseSort)
c9311d50 MG	59	my $id = $_->id;
	60	+{ $_->get_columns,
	61	solved => ($solved{$id} // 0),
	62	attempted => ($attempted{$id} // 0),
	63	contests => ($contests{$id} // 0) }
281c3952	64	} $rs->all ]
de625c9b MG	65	}
	66
	67	sub user_entry {
	68	my ($self, $id) = @_;
adb42d4d	69	my $user = $self->users->find($id, {columns => USER_PUBLIC_COLUMNS, prefetch => [qw/problem_statuses contest_statuses/]});
197d1959 MG	70	my @problems = map { {problem => $_->get_column('problem'), solved => $_->solved} } $user->problem_statuses->search(undef, {order_by => 'problem'});
197d1959 MG	71	my @contests = map { {contest => $_->contest->id, contest_name => $_->contest->name, rank => $_->rank, score => $_->score} } $user->contest_statuses->search(undef, {prefetch => 'contest', order_by => 'contest.start DESC'});
adb42d4d	72	+{ $user->get_columns, problems => \@problems, contests => \@contests }
de625c9b MG	73	}
	74
	75	sub problem_list {
	76	my ($self, %args) = @_;
	77	my $rs = $self->problems->search(undef, {order_by => 'me.name', columns => PROBLEM_PUBLIC_COLUMNS, prefetch => 'owner'});
d4c5bf27	78	$rs = $rs->search({-or => ['contest_problems.contest' => undef, 'contest.stop' => {'<=', time}], 'me.private' => 0}, {join => {'contest_problems' => 'contest'}, distinct => 1}) unless $args{contest} \|\| $args{private};
de625c9b MG	79	$rs = $rs->search({'contest_problems.contest' => $args{contest}}, {join => 'contest_problems'}) if $args{contest};
	80	$rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
	81	my %params;
	82	$params{contest} = $args{contest} if $args{contest};
	83	for ($rs->all) {
	84	$params{$_->level} //= [];
35596ea8	85	push @{$params{$_->level}}, {$_->get_columns, owner_name => $_->owner->name} ;
de625c9b MG	86	}
	87	\%params
	88	}
	89
	90	sub problem_entry {
	91	my ($self, $id, $contest, $user) = @_;
de625c9b	92	my $running = $contest && $self->contest($contest)->is_running;
8bd66733	93	my $columns = PROBLEM_PUBLIC_COLUMNS;
e890b3ae	94	push @$columns, 'statement';
8bd66733 MG	95	push @$columns, 'solution' unless $running;
8bd66733 MG	96	my $pb = $self->problems->find($id, {columns => $columns, prefetch => 'owner'});
9396be04 MG	97	my $open;
	98	$open = $self->opens->find_or_create({
	99	contest => $contest,
	100	problem => $id,
	101	owner => $user,
	102	time => time,
	103	}) if $running;
2431260b	104	$contest &&= $self->contest($contest);
9396be04 MG	105	+{
	106	$pb->get_columns,
	107	owner_name => $pb->owner->name,
1ecf0766	108	cansubmit => !$contest \|\| !$contest->is_finished,
9396be04 MG	109	$running ? (
	110	contest_start => $contest->start,
	111	contest_stop => $contest->stop,
	112	open_time => $open->time
	113	) : (),
	114	}
de625c9b MG	115	}
	116
	117	sub contest_list {
	118	my ($self, %args) = @_;
	119	my $rs = $self->contests->search(undef, {order_by => {-desc => 'start'}, prefetch => 'owner'});
	120	$rs = $rs->search({owner => $args{owner}}) if $args{owner};
	121	my %params;
	122	for ($rs->all) {
	123	my $state = $_->is_pending ? 'pending' : $_->is_running ? 'running' : 'finished';
	124	$params{$state} //= [];
35596ea8	125	push @{$params{$state}}, { $_->get_columns, started => !$_->is_pending, owner_name => $_->owner->name };
de625c9b MG	126	}
	127	\%params
	128	}
	129
	130	sub contest_entry {
	131	my ($self, $id) = @_;
	132	my $ct = $self->contest($id);
	133	+{ $ct->get_columns, started => !$ct->is_pending, owner_name => $ct->owner->name }
	134	}
	135
	136	sub job_list {
	137	my ($self, %args) = @_;
	138	$args{page} //= 1;
17d49281	139	my $rs = $self->jobs->search({contest => $args{contest}}, {order_by => {-desc => 'me.id'}, prefetch => ['problem', 'owner'], rows => JOBS_PER_PAGE, page => $args{page}});
d4c5bf27 MG	140	$rs = $rs->search({'me.private'=> 0}) unless $args{private};
d4c5bf27 MG	141	$rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
d4c5bf27	142	$rs = $rs->search({problem => $args{problem}}) if $args{problem};
3473324b MG	143	return {
	144	log => [map {
	145	my %params = $_->get_columns;
	146	$params{owner_name} = $_->owner->name;
	147	$params{problem_name} = $_->problem->name;
	148	$params{results} &&= decode_json $params{results};
	149	$params{size} = length $params{source};
	150	delete $params{source};
	151	\%params
	152	} $rs->all],
	153	current_page => $rs->pager->current_page,
	154	maybe previous_page => $rs->pager->previous_page,
	155	maybe next_page => $rs->pager->next_page,
	156	maybe last_page => $rs->pager->last_page,
	157	}
de625c9b MG	158	}
	159
	160	sub job_entry {
	161	my ($self, $id) = @_;
7d499cdd	162	my $job = $self->jobs->find($id, {prefetch => ['problem', 'owner', 'contest']});
de625c9b MG	163	my %params = $job->get_columns;
	164	$params{owner_name} = $job->owner->name;
	165	$params{problem_name} = $job->problem->name;
7d499cdd	166	$params{contest_name} = $job->contest->name if $params{contest};
de625c9b MG	167	$params{results} &&= decode_json $params{results};
	168	$params{size} = length $params{source};
	169	delete $params{source};
	170	\%params
	171	}
	172
adb42d4d MG	173	sub update_status {
	174	my ($self) = @_;
	175	my @jobs = $self->jobs->search(undef, {cache => 1})->all;
a2aa46e6	176
adb42d4d	177	my %hash;
9bfb38e0	178	$hash{$_->get_column('problem'), $_->get_column('owner')} = [$_->id, $_->result ? 0 : 1] for @jobs;
adb42d4d MG	179	my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;
	180
	181	my @contest_statuses = map {
	182	my $contest = $_->id;
751c70b5	183	map { [$contest, $_->{user}, $_->{score}, $_->{rank}] } $_->standings
adb42d4d MG	184	} $self->contests->all;
	185
	186	my $txn = sub {
	187	$self->problem_statuses->delete;
	188	$self->problem_statuses->populate([[qw/problem owner job solved/], @problem_statuses]);
	189	$self->contest_statuses->delete;
	190	$self->contest_statuses->populate([[qw/contest owner score rank/], @contest_statuses]);
	191	};
	192
	193	$self->txn_do($txn);
	194	}
	195
edfc5928 MG	196	my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
	197	my $ht = HTTP::Tiny->new;
	198
de7226ca MG	199	sub purge {
	200	$ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
	201	}
edfc5928	202
f7386aab	203	1;
4a8747ef MG	204
	205	__END__
	206
	207	=encoding utf-8
	208
	209	=head1 NAME
	210
	211	Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools
	212
	213	=head1 SYNOPSIS
	214
	215	my $db = Gruntmaster::Data->connect('dbi:Pg:');
cbb36c78 MG	216
	217	my $problem = $db->problem('my_problem');
	218	$problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
	219	$problem->rerun; # And rerun all jobs for this problem
	220
	221	# ...
	222
	223	my $contest = $db->contests->create({ # Create a new contest
	224	id => 'my_contest',
	225	name => 'My Awesome Contest',
	226	start => time + 100,
	227	end => time + 1900,
	228	});
	229	$db->contest_problems->create({ # Add a problem to the contest
	230	contest => 'my_contest',
	231	problem => 'my_problem',
	232	});
	233
	234	say 'The contest has not started yet' if $contest->is_pending;
	235
	236	# ...
	237
	238	my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
	239	$_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest
4a8747ef MG	240
	241	=head1 DESCRIPTION
	242
cbb36c78 MG	243	Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.
	244
	245	In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:
	246
	247	=over
	248
	249	=item contests
	250
	251	Equivalent to C<< $schema->resultset('Contest') >>
	252
	253	=item contest_problems
	254
	255	Equivalent to C<< $schema->resultset('ContestProblem') >>
	256
	257	=item jobs
	258
	259	Equivalent to C<< $schema->resultset('Job') >>
	260
	261	=item problems
	262
	263	Equivalent to C<< $schema->resultset('Problem') >>
	264
	265	=item users
	266
	267	Equivalent to C<< $schema->resultset('User') >>
	268
	269	=item contest($id)
	270
	271	Equivalent to C<< $schema->resultset('Contest')->find($id) >>
	272
	273	=item job($id)
	274
	275	Equivalent to C<< $schema->resultset('Job')->find($id) >>
	276
	277	=item problem($id)
	278
	279	Equivalent to C<< $schema->resultset('Problem')->find($id) >>
	280
	281	=item user($id)
	282
	283	Equivalent to C<< $schema->resultset('User')->find($id) >>
	284
de625c9b MG	285	=item user_list
	286
	287	Returns a list of users as an arrayref containing hashrefs.
	288
	289	=item user_entry($id)
	290
	291	Returns a hashref with information about the user $id.
	292
	293	=item problem_list([%args])
	294
	295	Returns a list of problems grouped by level. A hashref with levels as keys.
	296
	297	Takes the following arguments:
	298
	299	=over
	300
	301	=item owner
	302
	303	Only show problems owned by this user
	304
	305	=item contest
	306
	307	Only show problems in this contest
	308
	309	=back
	310
	311	=item problem_entry($id, [$contest, $user])
	312
	313	Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.
	314
	315	=item contest_list([%args])
	316
	317	Returns a list of contests grouped by state. A hashref with the following keys:
	318
	319	=over
	320
	321	=item pending
	322
	323	An arrayref of hashrefs representing pending contests
	324
	325	=item running
	326
	327	An arrayref of hashrefs representing running contests
	328
	329	=item finished
	330
	331	An arrayref of hashrefs representing finished contests
	332
	333	=back
	334
	335	Takes the following arguments:
	336
	337	=over
	338
	339	=item owner
	340
	341	Only show contests owned by this user.
	342
	343	=back
	344
	345	=item contest_entry($id)
	346
	347	Returns a hashref with information about the contest $id.
	348
349	=item job_list([%args])
350
351	Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:
352
353	=over
354
355	=item owner
356
357	Only show jobs submitted by this user.
358
359	=item contest
360
361	Only show jobs submitted in this contest.
362
363	=item problem
364
365	Only show jobs submitted for this problem.
366
367	=item page
368
369	Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.
370
371	=back
372
373	=item job_entry($id)
374
375	Returns a hashref with information about the job $id.
376
cbb36c78	377	=back
4a8747ef MG	378
	379	=head1 AUTHOR
	380
	381	Marius Gavrilescu E<lt>marius@ieval.roE<gt>
	382
	383	=head1 COPYRIGHT AND LICENSE
	384
	385	Copyright (C) 2014 by Marius Gavrilescu
	386
9d2e740e MG	387	This library is free software; you can redistribute it and/or modify
	388	it under the same terms as Perl itself, either Perl version 5.18.1 or,
	389	at your option, any later version of Perl 5 you may have available.
4a8747ef MG	390
	391
	392	=cut