[gruntmaster-data.git] / lib / Gruntmaster / Data.pm

package Gruntmaster::Data;
use 5.014;
use warnings;

use parent qw/Exporter/;
our $VERSION = '5999.000_013';
our @EXPORT = qw/dbinit purge db user_list user_entry problem_list problem_entry contest_list contest_entry contest_has_problem job_list job_entry create_job standings update_status rerun_job take_job finish_job/; ## no critic (ProhibitAutomaticExportation)
our @EXPORT_OK = @EXPORT;

use JSON::MaybeXS qw/decode_json/;
use HTTP::Tiny;
use PerlX::Maybe qw/maybe/;

use DBI;
use DBIx::Simple;
use List::Util qw/sum/;
use SQL::Abstract;

use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private timeout olimit value/];
use constant JOBS_PER_PAGE => 50;

my %statements = (
	user_list_sth => 'SELECT * FROM user_list LIMIT 200',
	user_entry_sth => 'SELECT * FROM user_data WHERE id = ?',

	problem_status_sth => 'SELECT problem,solved FROM problem_status WHERE owner = ?',
	contest_status_sth => 'SELECT contest,score,rank FROM contest_status WHERE owner = ?',

	contest_list_sth => 'SELECT * FROM contest_entry',
	contest_entry_sth => 'SELECT * FROM contest_entry WHERE id = ?',
	contest_has_problem_sth => 'SELECT EXISTS(SELECT 1 FROM contest_problems WHERE contest = ? AND problem = ?)',
	opens_sth => 'SELECT problem,owner,time FROM opens WHERE contest = ?',

	problem_entry_sth => 'SELECT ' . (join ',', @{PROBLEM_PUBLIC_COLUMNS()}, 'statement', 'solution') . ' FROM problems WHERE id = ?',
	limits_sth => 'SELECT format,timeout FROM limits WHERE problem = ?',

	job_entry_sth => 'SELECT * FROM job_entry WHERE id = ?',

	rerun_job_sth => 'UPDATE jobs SET daemon=NULL,result=-2,result_text=NULL,results=NULL,errors=NULL WHERE id = ?',
	take_job_sth => 'UPDATE jobs SET daemon=? WHERE id = (SELECT id FROM jobs WHERE daemon IS NULL LIMIT 1 FOR UPDATE) RETURNING id',
);

our $db;
sub db () { $db }

sub dbinit {
	$db = DBIx::Simple->new(@_);
	$db->keep_statements = 100;
};

sub purge;

sub query {
	my ($stat, @extra) = @_;
	$db->query($statements{$stat}, @extra)
}

my (%name_cache, %name_cache_time);
use constant NAME_CACHE_MAX_AGE => 5;

sub object_name {
	my ($table, $id) = @_;
	$name_cache_time{$table} //= 0;
	if (time - $name_cache_time{$table} > NAME_CACHE_MAX_AGE) {
		$name_cache_time{$table} = time;
		$name_cache{$table} = {};
		$name_cache{$table} = $db->select($table, 'id,name')->map;
	}

	$name_cache{$table}{$id}
}


sub add_names ($) { ## no critic (ProhibitSubroutinePrototypes)
	my ($el) = @_;
	return unless defined $el;
	if (ref $el eq 'ARRAY') {
		&add_names ($_) for @$el ## no critic (ProhibitAmpersandSigils)
	} else {
		for my $object (qw/contest owner problem/) {
			my $table = $object eq 'owner' ? 'users' : "${object}s";
			$el->{"${object}_name"} = object_name $table, $el->{$object} if defined $el->{$object}
		}
	}

	$el
}

sub user_list { scalar query('user_list_sth')->hashes }

sub user_entry {
	my ($id) = @_;
	my $ret = query('user_entry_sth', $id)->hash;
	$ret->{problems} = add_names query('problem_status_sth', $id)->hashes;
	$ret->{contests} = add_names query('contest_status_sth', $id)->hashes;

	$ret;
}

sub problem_list {
	my (%args) = @_;
	my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
	push @columns, 'solution' if $args{solution};
	my %where;
	$where{private} = 0 unless $args{contest} || $args{private};
	$where{'cp.contest'} = $args{contest} if $args{contest};
	$where{owner} = $args{owner} if $args{owner};

	my $table = $args{contest} ? 'problems JOIN contest_problems cp ON cp.problem = id' : 'problems';
	add_names $db->select(\$table, \@columns, \%where, 'name')->hashes
}

sub problem_entry {
	my ($id, $contest) = @_;
	$contest = contest_entry ($contest) if $contest;
	my $ret = add_names query(problem_entry_sth => $id)->hash;
	my $limits = query(limits_sth => $id)->hashes;
	$ret->{limits} = $limits if @$limits;

	if ($contest) {
		$ret->{contest_start} = $contest->{start};
		$ret->{contest_stop}  = $contest->{stop};
		delete $ret->{solution}
	}

	$ret
}

sub contest_list { add_names query('contest_list_sth')->hashes }

sub contest_entry { add_names query(contest_entry_sth => $_[0])->hash }

sub contest_has_problem { query('contest_has_problem_sth', @_[0, 1])->flat }

sub job_list {
	my (%args) = @_;
	$args{page} = int ($args{page} // 1);
	my %where = (
		maybe contest => $args{contest},
		maybe owner => $args{owner},
		maybe problem => $args{problem},
		maybe result => $args{result},
	);
	$where{private} = 0 unless $args{private};

	my $rows = $db->select('job_entry', 'COUNT(*)', \%where)->list;
	my $pages = int (($rows + JOBS_PER_PAGE - 1) / JOBS_PER_PAGE);
	my ($stmt, @bind) = $db->abstract->select('job_entry', '*', \%where, {-desc => 'id'});
	my $jobs = add_names $db->query("$stmt LIMIT " . JOBS_PER_PAGE . ' OFFSET ' . ($args{page} - 1) * JOBS_PER_PAGE, @bind)->hashes;
	my $pageinfo = {
		current_page => $args{page},
		last_page    => $pages,
		($args{page} - 1) ? (previous_page => $args{page} - 1) : (),
		($args{page} < $pages) ? (next_page => $args{page} + 1) : (),
	};
	wantarray ? ($jobs, $pageinfo) : $jobs;
}

sub job_entry {
	my $ret = add_names query(job_entry_sth => $_[0])->hash;
	$ret->{results} = decode_json $ret->{results} if $ret->{results};
	$ret
}

sub create_job {
	my (%args) = @_;
	$db->update('users', {lastjob => time}, {id => $args{owner}});
	purge '/log/';
	scalar $db->insert('jobs', \%args, {returning => 'id'})->list
}

sub _calc_score {
	my ($mxscore, $time, $tries, $totaltime) = @_;
	my $score = $mxscore;
	$time = 300 if $time > $totaltime; # uncoverable branch true does not happen anymore (only possible if opens are broken)
	$score = ($totaltime - $time) / $totaltime * $score;
	$score -= $tries / 10 * $mxscore;
	$score = $mxscore * 3 / 10 if $score < $mxscore * 3 / 10;
	int $score + 0.5
}

sub standings {
	my ($ct) = @_;
	my @problems = sort { $a->{value} <=> $b->{value} } @{problem_list contest => $ct};
	my %values = map { $_->{id} => $_->{value} } @problems;
	$ct = contest_entry $ct;

	my (%scores, %tries, %opens);
	my $opens = query(opens_sth => $ct->{id});
	while ($opens->into(my ($problem, $owner, $time))) {
		$opens{$problem, $owner} = $time;
	}

	my $jobs = $db->select('job_entry', '*', {contest => $ct->{id}}, 'id');

	while (my $job = $jobs->hash) {
		my $open = $opens{$job->{problem}, $job->{owner}} // $ct->{start};
		my $time = $job->{date} - $open;
		next if $time < 0; # uncoverable branch true job sent before contest is deprecated
		my $value = $values{$job->{problem}};
		my $factor = $job->{result} ? 0 : 1;
		$factor = $1 / 100 if $job->{result_text} =~ /^(\d+ )/s;
		$scores{$job->{owner}}{$job->{problem}} = int ($factor * _calc_score ($value, $time, $tries{$job->{owner}}{$job->{problem}}++, $ct->{stop} - $ct->{start}));
	}

	my @st = sort { $b->{score} <=> $a->{score} or $a->{user} cmp $b->{user} } map { ## no critic (ProhibitReverseSortBlock)
		my $user = $_;
		+{
			user => $user,
			user_name => object_name(users => $user),
			score => sum (values %{$scores{$user}}),
			scores => [map { $scores{$user}{$_->{id}} // '-'} @problems],
		}
	} keys %scores;

	$st[0]->{rank} = 1 if @st;
	$st[$_]->{rank} = $st[$_ - 1]->{rank} + ($st[$_]->{score} < $st[$_ - 1]->{score}) for 1 .. $#st;

	\@st
}

sub update_status {
	my $jobs = $db->select('jobs', 'id,owner,problem,result', {-not_bool => 'private'}, 'id');

	my %hash;
	while ($jobs->into(my ($id, $owner, $problem, $result))) {
		$hash{$problem, $owner} = [$id, $result ? 0 : 1];
	}

	my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;

	my @contest_statuses = map {
		my $ct = $_;
		map { [$ct, $_->{user}, $_->{score}, $_->{rank}] } @{standings $ct}
	} $db->select('contests', 'id')->flat;

	$db->begin;
	$db->delete('problem_status');
	$db->query('INSERT INTO problem_status (problem,owner,job,solved) VALUES (??)', @$_) for @problem_statuses;
	$db->delete('contest_status');
	$db->query('INSERT INTO contest_status (contest,owner,score,rank) VALUES (??)', @$_) for @contest_statuses;
	$db->commit
}

sub rerun_job {
	my ($id) = @_;
	query rerun_job_sth => $id;
	purge '/log/';
	purge "/log/$id";
}

sub take_job {
	my ($daemon) = @_;
	my $id = query(take_job_sth => $daemon)->list;
	return $id ? db->select(jobs => '*', {id => $id})->hash : undef;
}

sub finish_job {
	my ($job, $private, %args) = @_;
	db->update(jobs => \%args, {id => $job->{id}});
	return if $private;
	my $status = {
		problem => $job->{problem},
		owner   => $job->{owner},
		job     => $job->{id},
		solved  => ($args{result} ? 0 : 1),
	};
	eval {
		db->insert(problem_status => $status)
	} or db->update(problem_status => $status, {owner => $job->{owner}, problem => $job->{problem}});
}

my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
my $ht = HTTP::Tiny->new;

sub purge {
	$ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
}

1;

__END__

=encoding utf-8

=head1 NAME

Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools

=head1 SYNOPSIS

  my $db = Gruntmaster::Data->connect('dbi:Pg:');

  my $problem = $db->problem('my_problem');
  $problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
  $problem->rerun; # And rerun all jobs for this problem

  # ...

  my $contest = $db->contests->create({ # Create a new contest
    id => 'my_contest',
    name => 'My Awesome Contest',
    start => time + 100,
    end => time + 1900,
  });
  $db->contest_problems->create({ # Add a problem to the contest
    contest => 'my_contest',
    problem => 'my_problem',
  });

  say 'The contest has not started yet' if $contest->is_pending;

  # ...

  my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
  $_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest

=head1 DESCRIPTION

Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.

In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:

=over

=item contests

Equivalent to C<< $schema->resultset('Contest') >>

=item contest_problems

Equivalent to C<< $schema->resultset('ContestProblem') >>

=item jobs

Equivalent to C<< $schema->resultset('Job') >>

=item problems

Equivalent to C<< $schema->resultset('Problem') >>

=item users

Equivalent to C<< $schema->resultset('User') >>

=item contest($id)

Equivalent to C<< $schema->resultset('Contest')->find($id) >>

=item job($id)

Equivalent to C<< $schema->resultset('Job')->find($id) >>

=item problem($id)

Equivalent to C<< $schema->resultset('Problem')->find($id) >>

=item user($id)

Equivalent to C<< $schema->resultset('User')->find($id) >>

=item user_list

Returns a list of users as an arrayref containing hashrefs.

=item user_entry($id)

Returns a hashref with information about the user $id.

=item problem_list([%args])

Returns a list of problems grouped by level. A hashref with levels as keys.

Takes the following arguments:

=over

=item owner

Only show problems owned by this user

=item contest

Only show problems in this contest

=back

=item problem_entry($id, [$contest, $user])

Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.

=item contest_list([%args])

Returns a list of contests grouped by state. A hashref with the following keys:

=over

=item pending

An arrayref of hashrefs representing pending contests

=item running

An arrayref of hashrefs representing running contests

=item finished

An arrayref of hashrefs representing finished contests

=back

Takes the following arguments:

=over

=item owner

Only show contests owned by this user.

=back

=item contest_entry($id)

Returns a hashref with information about the contest $id.

=item job_list([%args])

Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:

=over

=item owner

Only show jobs submitted by this user.

=item contest

Only show jobs submitted in this contest.

=item problem

Only show jobs submitted for this problem.

=item page

Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.

=back

=item job_entry($id)

Returns a hashref with information about the job $id.

=back

=head1 AUTHOR

Marius Gavrilescu E<lt>marius@ieval.roE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2014 by Marius Gavrilescu

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.18.1 or,
at your option, any later version of Perl 5 you may have available.


=cut
Commit	Line	Data
bbf8209c	1	package Gruntmaster::Data;
6c0423f4	2	use 5.014;
bbf8209c	3	use warnings;
014ee8a6	4
edfc5928	5	use parent qw/Exporter/;
9e130d3b	6	our $VERSION = '5999.000_013';
6fb81f9a	7	our @EXPORT = qw/dbinit purge db user_list user_entry problem_list problem_entry contest_list contest_entry contest_has_problem job_list job_entry create_job standings update_status rerun_job take_job finish_job/; ## no critic (ProhibitAutomaticExportation)
6dfc2864	8	our @EXPORT_OK = @EXPORT;
4ed3f8e7	9
91203bd5	10	use JSON::MaybeXS qw/decode_json/;
edfc5928	11	use HTTP::Tiny;
3473324b	12	use PerlX::Maybe qw/maybe/;
52172a1a MG	13
	14	use DBI;
	15	use DBIx::Simple;
	16	use List::Util qw/sum/;
	17	use SQL::Abstract;
014ee8a6	18
e890b3ae	19	use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private timeout olimit value/];
e1250e20	20	use constant JOBS_PER_PAGE => 50;
de625c9b	21
52172a1a MG	22	my %statements = (
	23	user_list_sth => 'SELECT * FROM user_list LIMIT 200',
	24	user_entry_sth => 'SELECT * FROM user_data WHERE id = ?',
	25
	26	problem_status_sth => 'SELECT problem,solved FROM problem_status WHERE owner = ?',
	27	contest_status_sth => 'SELECT contest,score,rank FROM contest_status WHERE owner = ?',
	28
	29	contest_list_sth => 'SELECT * FROM contest_entry',
	30	contest_entry_sth => 'SELECT * FROM contest_entry WHERE id = ?',
52172a1a MG	31	contest_has_problem_sth => 'SELECT EXISTS(SELECT 1 FROM contest_problems WHERE contest = ? AND problem = ?)',
	32	opens_sth => 'SELECT problem,owner,time FROM opens WHERE contest = ?',
	33
	34	problem_entry_sth => 'SELECT ' . (join ',', @{PROBLEM_PUBLIC_COLUMNS()}, 'statement', 'solution') . ' FROM problems WHERE id = ?',
	35	limits_sth => 'SELECT format,timeout FROM limits WHERE problem = ?',
52172a1a MG	36
52172a1a MG	37	job_entry_sth => 'SELECT * FROM job_entry WHERE id = ?',
341fb893 MG	38
341fb893 MG	39	rerun_job_sth => 'UPDATE jobs SET daemon=NULL,result=-2,result_text=NULL,results=NULL,errors=NULL WHERE id = ?',
9dc335bd	40	take_job_sth => 'UPDATE jobs SET daemon=? WHERE id = (SELECT id FROM jobs WHERE daemon IS NULL LIMIT 1 FOR UPDATE) RETURNING id',
52172a1a MG	41	);
52172a1a MG	42
50b165c3	43	our $db;
341fb893	44	sub db () { $db }
23aa7eca	45
6fb81f9a	46	sub dbinit {
62a58bf3 MG	47	$db = DBIx::Simple->new(@_);
62a58bf3 MG	48	$db->keep_statements = 100;
52172a1a MG	49	};
	50
	51	sub purge;
	52
	53	sub query {
62a58bf3	54	my ($stat, @extra) = @_;
4623c9f2	55	$db->query($statements{$stat}, @extra)
52172a1a MG	56	}
	57
	58	my (%name_cache, %name_cache_time);
	59	use constant NAME_CACHE_MAX_AGE => 5;
	60
	61	sub object_name {
62a58bf3	62	my ($table, $id) = @_;
52172a1a MG	63	$name_cache_time{$table} //= 0;
	64	if (time - $name_cache_time{$table} > NAME_CACHE_MAX_AGE) {
	65	$name_cache_time{$table} = time;
	66	$name_cache{$table} = {};
62a58bf3	67	$name_cache{$table} = $db->select($table, 'id,name')->map;
52172a1a MG	68	}
	69
	70	$name_cache{$table}{$id}
	71	}
	72
	73
6c0423f4	74	sub add_names ($) { ## no critic (ProhibitSubroutinePrototypes)
62a58bf3	75	my ($el) = @_;
ee00be0c	76	return unless defined $el;
52172a1a	77	if (ref $el eq 'ARRAY') {
6c0423f4	78	&add_names ($_) for @$el ## no critic (ProhibitAmpersandSigils)
52172a1a MG	79	} else {
	80	for my $object (qw/contest owner problem/) {
	81	my $table = $object eq 'owner' ? 'users' : "${object}s";
62a58bf3	82	$el->{"${object}_name"} = object_name $table, $el->{$object} if defined $el->{$object}
52172a1a MG	83	}
	84	}
	85
	86	$el
	87	}
	88
b69781c1	89	sub user_list { scalar query('user_list_sth')->hashes }
52172a1a MG	90
52172a1a MG	91	sub user_entry {
62a58bf3 MG	92	my ($id) = @_;
	93	my $ret = query('user_entry_sth', $id)->hash;
	94	$ret->{problems} = add_names query('problem_status_sth', $id)->hashes;
	95	$ret->{contests} = add_names query('contest_status_sth', $id)->hashes;
52172a1a	96
52172a1a MG	97	$ret;
	98	}
	99
52172a1a	100	sub problem_list {
62a58bf3	101	my (%args) = @_;
52172a1a MG	102	my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
	103	push @columns, 'solution' if $args{solution};
	104	my %where;
	105	$where{private} = 0 unless $args{contest} \|\| $args{private};
	106	$where{'cp.contest'} = $args{contest} if $args{contest};
	107	$where{owner} = $args{owner} if $args{owner};
	108
	109	my $table = $args{contest} ? 'problems JOIN contest_problems cp ON cp.problem = id' : 'problems';
b69781c1	110	add_names $db->select(\$table, \@columns, \%where, 'name')->hashes
52172a1a MG	111	}
52172a1a MG	112
52172a1a	113	sub problem_entry {
a1a4325a	114	my ($id, $contest) = @_;
4623c9f2	115	$contest = contest_entry ($contest) if $contest;
62a58bf3 MG	116	my $ret = add_names query(problem_entry_sth => $id)->hash;
62a58bf3 MG	117	my $limits = query(limits_sth => $id)->hashes;
52172a1a MG	118	$ret->{limits} = $limits if @$limits;
	119
	120	if ($contest) {
	121	$ret->{contest_start} = $contest->{start};
	122	$ret->{contest_stop} = $contest->{stop};
d33e87f2	123	delete $ret->{solution}
52172a1a MG	124	}
	125
	126	$ret
	127	}
	128
b69781c1	129	sub contest_list { add_names query('contest_list_sth')->hashes }
52172a1a	130
b69781c1	131	sub contest_entry { add_names query(contest_entry_sth => $_[0])->hash }
52172a1a	132
b69781c1	133	sub contest_has_problem { query('contest_has_problem_sth', @_[0, 1])->flat }
52172a1a	134
52172a1a	135	sub job_list {
62a58bf3	136	my (%args) = @_;
b69781c1	137	$args{page} = int ($args{page} // 1);
52172a1a MG	138	my %where = (
	139	maybe contest => $args{contest},
	140	maybe owner => $args{owner},
	141	maybe problem => $args{problem},
	142	maybe result => $args{result},
	143	);
	144	$where{private} = 0 unless $args{private};
	145
62a58bf3	146	my $rows = $db->select('job_entry', 'COUNT(*)', \%where)->list;
52172a1a	147	my $pages = int (($rows + JOBS_PER_PAGE - 1) / JOBS_PER_PAGE);
62a58bf3	148	my ($stmt, @bind) = $db->abstract->select('job_entry', '*', \%where, {-desc => 'id'});
b69781c1 MG	149	my $jobs = add_names $db->query("$stmt LIMIT " . JOBS_PER_PAGE . ' OFFSET ' . ($args{page} - 1) * JOBS_PER_PAGE, @bind)->hashes;
b69781c1 MG	150	my $pageinfo = {
52172a1a MG	151	current_page => $args{page},
52172a1a MG	152	last_page => $pages,
b69781c1 MG	153	($args{page} - 1) ? (previous_page => $args{page} - 1) : (),
	154	($args{page} < $pages) ? (next_page => $args{page} + 1) : (),
	155	};
	156	wantarray ? ($jobs, $pageinfo) : $jobs;
52172a1a MG	157	}
	158
	159	sub job_entry {
b69781c1	160	my $ret = add_names query(job_entry_sth => $_[0])->hash;
4623c9f2	161	$ret->{results} = decode_json $ret->{results} if $ret->{results};
62a58bf3	162	$ret
52172a1a MG	163	}
52172a1a MG	164
52172a1a	165	sub create_job {
62a58bf3	166	my (%args) = @_;
5e77eeae	167	$db->update('users', {lastjob => time}, {id => $args{owner}});
52172a1a	168	purge '/log/';
62a58bf3	169	scalar $db->insert('jobs', \%args, {returning => 'id'})->list
52172a1a MG	170	}
52172a1a MG	171
01fcdebe	172	sub _calc_score {
52172a1a MG	173	my ($mxscore, $time, $tries, $totaltime) = @_;
52172a1a MG	174	my $score = $mxscore;
4623c9f2	175	$time = 300 if $time > $totaltime; # uncoverable branch true does not happen anymore (only possible if opens are broken)
52172a1a MG	176	$score = ($totaltime - $time) / $totaltime * $score;
	177	$score -= $tries / 10 * $mxscore;
	178	$score = $mxscore * 3 / 10 if $score < $mxscore * 3 / 10;
	179	int $score + 0.5
	180	}
	181
	182	sub standings {
62a58bf3	183	my ($ct) = @_;
01fcdebe MG	184	my @problems = sort { $a->{value} <=> $b->{value} } @{problem_list contest => $ct};
01fcdebe MG	185	my %values = map { $_->{id} => $_->{value} } @problems;
62a58bf3	186	$ct = contest_entry $ct;
52172a1a	187
52172a1a	188	my (%scores, %tries, %opens);
62a58bf3	189	my $opens = query(opens_sth => $ct->{id});
52172a1a MG	190	while ($opens->into(my ($problem, $owner, $time))) {
	191	$opens{$problem, $owner} = $time;
	192	}
	193
62a58bf3	194	my $jobs = $db->select('job_entry', '*', {contest => $ct->{id}}, 'id');
52172a1a MG	195
	196	while (my $job = $jobs->hash) {
	197	my $open = $opens{$job->{problem}, $job->{owner}} // $ct->{start};
	198	my $time = $job->{date} - $open;
4623c9f2	199	next if $time < 0; # uncoverable branch true job sent before contest is deprecated
52172a1a MG	200	my $value = $values{$job->{problem}};
	201	my $factor = $job->{result} ? 0 : 1;
	202	$factor = $1 / 100 if $job->{result_text} =~ /^(\d+ )/s;
01fcdebe	203	$scores{$job->{owner}}{$job->{problem}} = int ($factor * _calc_score ($value, $time, $tries{$job->{owner}}{$job->{problem}}++, $ct->{stop} - $ct->{start}));
52172a1a MG	204	}
	205
	206	my @st = sort { $b->{score} <=> $a->{score} or $a->{user} cmp $b->{user} } map { ## no critic (ProhibitReverseSortBlock)
	207	my $user = $_;
	208	+{
	209	user => $user,
62a58bf3	210	user_name => object_name(users => $user),
52172a1a	211	score => sum (values %{$scores{$user}}),
01fcdebe	212	scores => [map { $scores{$user}{$_->{id}} // '-'} @problems],
52172a1a MG	213	}
	214	} keys %scores;
	215
	216	$st[0]->{rank} = 1 if @st;
	217	$st[$_]->{rank} = $st[$_ - 1]->{rank} + ($st[$_]->{score} < $st[$_ - 1]->{score}) for 1 .. $#st;
01fcdebe MG	218
01fcdebe MG	219	\@st
52172a1a MG	220	}
52172a1a MG	221
52172a1a	222	sub update_status {
1761e170	223	my $jobs = $db->select('jobs', 'id,owner,problem,result', {-not_bool => 'private'}, 'id');
52172a1a MG	224
	225	my %hash;
	226	while ($jobs->into(my ($id, $owner, $problem, $result))) {
	227	$hash{$problem, $owner} = [$id, $result ? 0 : 1];
	228	}
	229
	230	my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;
	231
	232	my @contest_statuses = map {
	233	my $ct = $_;
01fcdebe	234	map { [$ct, $_->{user}, $_->{score}, $_->{rank}] } @{standings $ct}
62a58bf3 MG	235	} $db->select('contests', 'id')->flat;
	236
	237	$db->begin;
	238	$db->delete('problem_status');
	239	$db->query('INSERT INTO problem_status (problem,owner,job,solved) VALUES (??)', @$_) for @problem_statuses;
	240	$db->delete('contest_status');
	241	$db->query('INSERT INTO contest_status (contest,owner,score,rank) VALUES (??)', @$_) for @contest_statuses;
	242	$db->commit
52172a1a MG	243	}
52172a1a MG	244
341fb893 MG	245	sub rerun_job {
341fb893 MG	246	my ($id) = @_;
686bacca	247	query rerun_job_sth => $id;
341fb893 MG	248	purge '/log/';
	249	purge "/log/$id";
	250	}
	251
9dc335bd MG	252	sub take_job {
	253	my ($daemon) = @_;
	254	my $id = query(take_job_sth => $daemon)->list;
cab36bc4	255	return $id ? db->select(jobs => '*', {id => $id})->hash : undef;
9dc335bd MG	256	}
	257
	258	sub finish_job {
	259	my ($job, $private, %args) = @_;
	260	db->update(jobs => \%args, {id => $job->{id}});
	261	return if $private;
	262	my $status = {
	263	problem => $job->{problem},
	264	owner => $job->{owner},
	265	job => $job->{id},
	266	solved => ($args{result} ? 0 : 1),
	267	};
	268	eval {
	269	db->insert(problem_status => $status)
	270	} or db->update(problem_status => $status, {owner => $job->{owner}, problem => $job->{problem}});
	271	}
	272
edfc5928 MG	273	my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
	274	my $ht = HTTP::Tiny->new;
	275
de7226ca MG	276	sub purge {
	277	$ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
	278	}
edfc5928	279
f7386aab	280	1;
4a8747ef MG	281
	282	__END__
	283
	284	=encoding utf-8
	285
	286	=head1 NAME
	287
	288	Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools
	289
	290	=head1 SYNOPSIS
	291
	292	my $db = Gruntmaster::Data->connect('dbi:Pg:');
cbb36c78 MG	293
	294	my $problem = $db->problem('my_problem');
	295	$problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
	296	$problem->rerun; # And rerun all jobs for this problem
	297
	298	# ...
	299
	300	my $contest = $db->contests->create({ # Create a new contest
	301	id => 'my_contest',
	302	name => 'My Awesome Contest',
	303	start => time + 100,
	304	end => time + 1900,
	305	});
	306	$db->contest_problems->create({ # Add a problem to the contest
	307	contest => 'my_contest',
	308	problem => 'my_problem',
	309	});
	310
	311	say 'The contest has not started yet' if $contest->is_pending;
	312
	313	# ...
	314
	315	my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
	316	$_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest
4a8747ef MG	317
	318	=head1 DESCRIPTION
	319
cbb36c78 MG	320	Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.
	321
	322	In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:
	323
	324	=over
	325
	326	=item contests
	327
	328	Equivalent to C<< $schema->resultset('Contest') >>
	329
	330	=item contest_problems
	331
	332	Equivalent to C<< $schema->resultset('ContestProblem') >>
	333
	334	=item jobs
	335
	336	Equivalent to C<< $schema->resultset('Job') >>
	337
	338	=item problems
	339
	340	Equivalent to C<< $schema->resultset('Problem') >>
	341
	342	=item users
	343
	344	Equivalent to C<< $schema->resultset('User') >>
	345
	346	=item contest($id)
	347
	348	Equivalent to C<< $schema->resultset('Contest')->find($id) >>
	349
	350	=item job($id)
	351
	352	Equivalent to C<< $schema->resultset('Job')->find($id) >>
	353
	354	=item problem($id)
	355
	356	Equivalent to C<< $schema->resultset('Problem')->find($id) >>
	357
	358	=item user($id)
	359
	360	Equivalent to C<< $schema->resultset('User')->find($id) >>
	361
de625c9b MG	362	=item user_list
	363
	364	Returns a list of users as an arrayref containing hashrefs.
	365
	366	=item user_entry($id)
	367
	368	Returns a hashref with information about the user $id.
	369
	370	=item problem_list([%args])
	371
	372	Returns a list of problems grouped by level. A hashref with levels as keys.
	373
	374	Takes the following arguments:
	375
	376	=over
	377
	378	=item owner
	379
	380	Only show problems owned by this user
	381
	382	=item contest
	383
	384	Only show problems in this contest
	385
	386	=back
	387
	388	=item problem_entry($id, [$contest, $user])
	389
	390	Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.
	391
	392	=item contest_list([%args])
	393
	394	Returns a list of contests grouped by state. A hashref with the following keys:
	395
	396	=over
	397
	398	=item pending
	399
	400	An arrayref of hashrefs representing pending contests
	401
	402	=item running
	403
	404	An arrayref of hashrefs representing running contests
	405
	406	=item finished
	407
	408	An arrayref of hashrefs representing finished contests
	409
	410	=back
	411
	412	Takes the following arguments:
	413
	414	=over
	415
	416	=item owner
	417
	418	Only show contests owned by this user.
	419
	420	=back
	421
	422	=item contest_entry($id)
	423
	424	Returns a hashref with information about the contest $id.
	425
426	=item job_list([%args])
427
428	Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:
429
430	=over
431
432	=item owner
433
434	Only show jobs submitted by this user.
435
436	=item contest
437
438	Only show jobs submitted in this contest.
439
440	=item problem
441
442	Only show jobs submitted for this problem.
443
444	=item page
445
446	Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.
447
448	=back
449
450	=item job_entry($id)
451
452	Returns a hashref with information about the job $id.
453
cbb36c78	454	=back
4a8747ef MG	455
	456	=head1 AUTHOR
	457
	458	Marius Gavrilescu E<lt>marius@ieval.roE<gt>
	459
	460	=head1 COPYRIGHT AND LICENSE
	461
	462	Copyright (C) 2014 by Marius Gavrilescu
	463
9d2e740e MG	464	This library is free software; you can redistribute it and/or modify
	465	it under the same terms as Perl itself, either Perl version 5.18.1 or,
	466	at your option, any later version of Perl 5 you may have available.
4a8747ef MG	467
	468
	469	=cut