lib/Gruntmaster/Data.pm

   1 use utf8;
   2 package Gruntmaster::Data;
   3
   4 # Created by DBIx::Class::Schema::Loader
   5 # DO NOT MODIFY THE FIRST PART OF THIS FILE
   6
   7 use strict;
   8 use warnings;
   9
  10 use base 'DBIx::Class::Schema';
  11
  12 __PACKAGE__->load_namespaces;
  13
  14
  15 # Created by DBIx::Class::Schema::Loader v0.07039 @ 2014-03-05 13:11:39
  16 # DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:dAEmtAexvUaNXLgYz2rNEg
  17
  18 use parent qw/Exporter/;
  19 our $VERSION = '5999.000_013';
  20 our @EXPORT = qw/purge/; ## no critic (ProhibitAutomaticExportation)
  21
  22 use Lingua::EN::Inflect qw/PL_N/;
  23 use JSON::MaybeXS qw/decode_json/;
  24 use HTTP::Tiny;
  25 use PerlX::Maybe qw/maybe/;
  26 use Sub::Name qw/subname/;
  27
  28 use constant CONTEST_PUBLIC_COLUMNS => [qw/id name description start stop owner/];
  29 use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private timeout olimit value/];
  30 use constant USER_PUBLIC_COLUMNS => [qw/id admin name town university country level/];
  31 use constant JOBS_PER_PAGE => 10;
  32
  33 sub dynsub{
  34         our ($name, $sub) = @_;
  35         no strict 'refs'; ## no critic (Strict)
  36         *$name = subname $name => $sub
  37 }
  38
  39 BEGIN {
  40         for my $rs (qw/contest contest_problem job open limit problem user problem_status contest_status/) {
  41                 my $rsname = ucfirst $rs;
  42                 $rsname =~ s/_([a-z])/\u$1/gs;
  43                 dynsub PL_N($rs) => sub { $_[0]->resultset($rsname)              };
  44                 dynsub      $rs  => sub { $_[0]->resultset($rsname)->find($_[1]) };
  45         }
  46 }
  47
  48 sub user_list {
  49         my ($self) = @_;
  50         my $rs = $self->users->search(undef, {columns => USER_PUBLIC_COLUMNS} );
  51         my (%solved, %attempted, %contests);
  52
  53         for my $row ($self->problem_statuses->all) {
  54                 $solved   {$row->rawowner}++ if     $row->solved;
  55                 $attempted{$row->rawowner}++ unless $row->solved;
  56         }
  57         $contests{$_->rawowner}++ for $self->contest_statuses->all;
  58
  59         [ sort { $b->{solved} <=> $a->{solved} or $b->{attempted} <=> $a->{attempted} } ## no critic (ProhibitReverseSort)
  60                 grep { $_->{solved} || $_->{attempted} } map {
  61                         my $id = $_->id;
  62                         +{ $_->get_columns,
  63                            solved => ($solved{$id} // 0),
  64                            attempted => ($attempted{$id} // 0),
  65                            contests => ($contests{$id} // 0) }
  66                 } $rs->all ]
  67 }
  68
  69 sub user_entry {
  70         my ($self, $id) = @_;
  71         my $user = $self->users->find($id, {columns => USER_PUBLIC_COLUMNS, prefetch => [qw/problem_statuses contest_statuses/]});
  72         my @problems = map { {problem => $_->get_column('problem'), solved => $_->solved} } $user->problem_statuses->search(undef, {order_by => 'problem'});
  73         my @contests = map { {contest => $_->contest->id, contest_name => $_->contest->name, rank => $_->rank, score => $_->score} } $user->contest_statuses->search(undef, {prefetch => 'contest', order_by => 'contest.start DESC'});
  74         +{ $user->get_columns, problems => \@problems, contests => \@contests }
  75 }
  76
  77 sub problem_list {
  78         my ($self, %args) = @_;
  79         my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
  80         push @columns, 'solution' if $args{solution} && $args{contest} && !$self->contest($args{contest})->is_running;
  81         my $rs = $self->problems->search(undef, {order_by => 'me.name', columns => \@columns, prefetch => 'owner'});
  82         $rs = $rs->search({'private' => 0}) unless $args{contest} || $args{private};
  83         $rs = $rs->search({'contest_problems.contest' => $args{contest}}, {join => 'contest_problems'}) if $args{contest};
  84         $rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
  85         my %params;
  86         $params{contest} = $args{contest} if $args{contest} && $self->contest($args{contest})->is_running;
  87         for ($rs->all) {
  88                 $params{$_->level} //= [];
  89                 push @{$params{$_->level}}, {$_->get_columns, owner_name => $_->owner->name} ;
  90         }
  91         \%params
  92 }
  93
  94 sub problem_entry {
  95         my ($self, $id, $contest, $user) = @_;
  96         my $running = $contest && $self->contest($contest)->is_running;
  97         my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
  98         push @columns, 'statement';
  99         push @columns, 'solution' unless $running;
 100         my $pb = $self->problems->find($id, {columns => \@columns, prefetch => 'owner'});
 101         my @limits = map { +{
 102                 format  => $_->format,
 103                 timeout => $_->timeout,
 104         } } $self->limits->search({problem => $id});
 105         my $open;
 106         $open = $self->opens->find_or_create({
 107                 contest => $contest,
 108                 problem => $id,
 109                 owner => $user,
 110                 time => time,
 111         }) if $running;
 112         $contest &&= $self->contest($contest);
 113         +{
 114                 $pb->get_columns,
 115                 @limits ? (limits => \@limits) : (),
 116                 owner_name => $pb->owner->name,
 117                 cansubmit => !$contest || !$contest->is_finished,
 118                 $running ? (
 119                         contest_start => $contest->start,
 120                         contest_stop => $contest->stop,
 121                         open_time => $open->time
 122                 ) : (),
 123         }
 124 }
 125
 126 sub contest_list {
 127         my ($self, %args) = @_;
 128         my $rs = $self->contests->search(undef, {columns => CONTEST_PUBLIC_COLUMNS, order_by => {-desc => 'start'}, prefetch => 'owner'});
 129         $rs = $rs->search({owner => $args{owner}}) if $args{owner};
 130         my %params;
 131         for ($rs->all) {
 132                 my $state = $_->is_pending ? 'pending' : $_->is_running ? 'running' : 'finished';
 133                 $params{$state} //= [];
 134                 push @{$params{$state}}, { $_->get_columns, owner_name => $_->owner->name };
 135         }
 136         \%params
 137 }
 138
 139 sub contest_entry {
 140         my ($self, $id) = @_;
 141         my $ct = $self->contests->find($id,{columns => CONTEST_PUBLIC_COLUMNS});
 142         +{ $ct->get_columns, started => !$ct->is_pending, finished => $ct->is_finished, owner_name => $ct->owner->name }
 143 }
 144
 145 sub job_list {
 146         my ($self, %args) = @_;
 147         $args{page} //= 1;
 148         my $rs = $self->jobs->search(undef, {order_by => {-desc => 'me.id'}, prefetch => ['problem', 'owner', 'contest'], rows => JOBS_PER_PAGE, page => $args{page}});
 149         $rs = $rs->search({contest => $args{contest} || undef}) if exists $args{contest};
 150         $rs = $rs->search({'me.private'=> 0})          unless $args{private};
 151         $rs = $rs->search({'me.owner'  => $args{owner}})   if $args{owner};
 152         $rs = $rs->search({problem     => $args{problem}}) if $args{problem};
 153         $rs = $rs->search({result      => $args{result}})  if defined $args{result};
 154         return {
 155                 log => [map {
 156                         my %params = $_->get_columns;
 157                         $params{owner_name}   = $_->owner->name;
 158                         $params{problem_name} = $_->problem->name;
 159                         $params{contest_name} = $_->contest->name if $params{contest};
 160                         $params{results} &&= decode_json $params{results};
 161                         $params{size}      = length $params{source};
 162                         delete $params{source};
 163                         \%params
 164                 } $rs->all],
 165                 current_page => $rs->pager->current_page,
 166                 maybe previous_page => $rs->pager->previous_page,
 167                 maybe next_page => $rs->pager->next_page,
 168                 maybe last_page => $rs->pager->last_page,
 169         }
 170 }
 171
 172 sub job_entry {
 173         my ($self, $id) = @_;
 174         my $job = $self->jobs->find($id, {prefetch => ['problem', 'owner', 'contest']});
 175         my %params = $job->get_columns;
 176         $params{owner_name}   = $job->owner->name;
 177         $params{problem_name} = $job->problem->name;
 178         $params{contest_name} = $job->contest->name if $params{contest};
 179         $params{results} &&= decode_json $params{results};
 180         $params{size}      = length $params{source};
 181         delete $params{source};
 182         \%params
 183 }
 184
 185 sub update_status {
 186         my ($self) = @_;
 187         my @jobs = $self->jobs->search({'me.private' => 0}, {cache => 1, prefetch => 'problem', order_by => 'me.id'})->all;
 188
 189         my %private;
 190         my %hash;
 191         for (@jobs) {
 192                 my $pb = $_->get_column('problem');
 193                 $private{$pb} //= $_->problem->private;
 194                 next if $private{$pb};
 195                 $hash{$pb, $_->get_column('owner')} = [$_->id, $_->result ? 0 : 1];
 196         }
 197
 198         my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;
 199
 200         my @contest_statuses = map {
 201                 my $contest = $_->id;
 202                 map { [$contest, $_->{user}, $_->{score}, $_->{rank}] } $_->standings
 203         } $self->contests->all;
 204
 205         my $txn = sub {
 206                 $self->problem_statuses->delete;
 207                 $self->problem_statuses->populate([[qw/problem owner job solved/], @problem_statuses]);
 208                 $self->contest_statuses->delete;
 209                 $self->contest_statuses->populate([[qw/contest owner score rank/], @contest_statuses]);
 210         };
 211
 212         $self->txn_do($txn);
 213 }
 214
 215 my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
 216 my $ht = HTTP::Tiny->new;
 217
 218 sub purge {
 219         $ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
 220 }
 221
 222 1;
 223
 224 __END__
 225
 226 =encoding utf-8
 227
 228 =head1 NAME
 229
 230 Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools
 231
 232 =head1 SYNOPSIS
 233
 234   my $db = Gruntmaster::Data->connect('dbi:Pg:');
 235
 236   my $problem = $db->problem('my_problem');
 237   $problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
 238   $problem->rerun; # And rerun all jobs for this problem
 239
 240   # ...
 241
 242   my $contest = $db->contests->create({ # Create a new contest
 243     id => 'my_contest',
 244     name => 'My Awesome Contest',
 245     start => time + 100,
 246     end => time + 1900,
 247   });
 248   $db->contest_problems->create({ # Add a problem to the contest
 249     contest => 'my_contest',
 250     problem => 'my_problem',
 251   });
 252
 253   say 'The contest has not started yet' if $contest->is_pending;
 254
 255   # ...
 256
 257   my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
 258   $_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest
 259
 260 =head1 DESCRIPTION
 261
 262 Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.
 263
 264 In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:
 265
 266 =over
 267
 268 =item contests
 269
 270 Equivalent to C<< $schema->resultset('Contest') >>
 271
 272 =item contest_problems
 273
 274 Equivalent to C<< $schema->resultset('ContestProblem') >>
 275
 276 =item jobs
 277
 278 Equivalent to C<< $schema->resultset('Job') >>
 279
 280 =item problems
 281
 282 Equivalent to C<< $schema->resultset('Problem') >>
 283
 284 =item users
 285
 286 Equivalent to C<< $schema->resultset('User') >>
 287
 288 =item contest($id)
 289
 290 Equivalent to C<< $schema->resultset('Contest')->find($id) >>
 291
 292 =item job($id)
 293
 294 Equivalent to C<< $schema->resultset('Job')->find($id) >>
 295
 296 =item problem($id)
 297
 298 Equivalent to C<< $schema->resultset('Problem')->find($id) >>
 299
 300 =item user($id)
 301
 302 Equivalent to C<< $schema->resultset('User')->find($id) >>
 303
 304 =item user_list
 305
 306 Returns a list of users as an arrayref containing hashrefs.
 307
 308 =item user_entry($id)
 309
 310 Returns a hashref with information about the user $id.
 311
 312 =item problem_list([%args])
 313
 314 Returns a list of problems grouped by level. A hashref with levels as keys.
 315
 316 Takes the following arguments:
 317
 318 =over
 319
 320 =item owner
 321
 322 Only show problems owned by this user
 323
 324 =item contest
 325
 326 Only show problems in this contest
 327
 328 =back
 329
 330 =item problem_entry($id, [$contest, $user])
 331
 332 Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.
 333
 334 =item contest_list([%args])
 335
 336 Returns a list of contests grouped by state. A hashref with the following keys:
 337
 338 =over
 339
 340 =item pending
 341
 342 An arrayref of hashrefs representing pending contests
 343
 344 =item running
 345
 346 An arrayref of hashrefs representing running contests
 347
 348 =item finished
 349
 350 An arrayref of hashrefs representing finished contests
 351
 352 =back
 353
 354 Takes the following arguments:
 355
 356 =over
 357
 358 =item owner
 359
 360 Only show contests owned by this user.
 361
 362 =back
 363
 364 =item contest_entry($id)
 365
 366 Returns a hashref with information about the contest $id.
 367
 368 =item job_list([%args])
 369
 370 Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:
 371
 372 =over
 373
 374 =item owner
 375
 376 Only show jobs submitted by this user.
 377
 378 =item contest
 379
 380 Only show jobs submitted in this contest.
 381
 382 =item problem
 383
 384 Only show jobs submitted for this problem.
 385
 386 =item page
 387
 388 Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.
 389
 390 =back
 391
 392 =item job_entry($id)
 393
 394 Returns a hashref with information about the job $id.
 395
 396 =back
 397
 398 =head1 AUTHOR
 399
 400 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
 401
 402 =head1 COPYRIGHT AND LICENSE
 403
 404 Copyright (C) 2014 by Marius Gavrilescu
 405
 406 This library is free software; you can redistribute it and/or modify
 407 it under the same terms as Perl itself, either Perl version 5.18.1 or,
 408 at your option, any later version of Perl 5 you may have available.
 409
 410
 411 =cut