[gruntmaster-data.git] / lib / Gruntmaster / Data.pm

use utf8;
package Gruntmaster::Data;

# Created by DBIx::Class::Schema::Loader
# DO NOT MODIFY THE FIRST PART OF THIS FILE

use strict;
use warnings;

use base 'DBIx::Class::Schema';

__PACKAGE__->load_namespaces;


# Created by DBIx::Class::Schema::Loader v0.07039 @ 2014-03-05 13:11:39
# DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:dAEmtAexvUaNXLgYz2rNEg

use parent qw/Exporter/;
our $VERSION = '5999.000_013';
our @EXPORT = qw/purge/; ## no critic (ProhibitAutomaticExportation)

use Lingua::EN::Inflect qw/PL_N/;
use JSON::MaybeXS qw/decode_json/;
use HTTP::Tiny;
use PerlX::Maybe qw/maybe/;
use Sub::Name qw/subname/;

use constant CONTEST_PUBLIC_COLUMNS => [qw/id name description start stop owner/];
use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private timeout olimit value/];
use constant USER_PUBLIC_COLUMNS => [qw/id admin name town university country level/];
use constant JOBS_PER_PAGE => 10;

sub dynsub{
	our ($name, $sub) = @_;
	no strict 'refs'; ## no critic (Strict)
	*$name = subname $name => $sub
}

BEGIN {
	for my $rs (qw/contest contest_problem job open limit problem user problem_status contest_status/) {
		my $rsname = ucfirst $rs;
		$rsname =~ s/_([a-z])/\u$1/gs;
		dynsub PL_N($rs) => sub { $_[0]->resultset($rsname)              };
		dynsub      $rs  => sub { $_[0]->resultset($rsname)->find($_[1]) };
	}
}

sub user_list {
	my ($self) = @_;
	my $rs = $self->users->search(undef, {columns => USER_PUBLIC_COLUMNS} );
	my (%solved, %attempted, %contests);

	for my $row ($self->problem_statuses->all) {
		$solved   {$row->rawowner}++ if     $row->solved;
		$attempted{$row->rawowner}++ unless $row->solved;
	}
	$contests{$_->rawowner}++ for $self->contest_statuses->all;

	[ sort { $b->{solved} <=> $a->{solved} or $b->{attempted} <=> $a->{attempted} } ## no critic (ProhibitReverseSort)
		grep { $_->{solved} || $_->{attempted} } map {
			my $id = $_->id;
			+{ $_->get_columns,
			   solved => ($solved{$id} // 0),
			   attempted => ($attempted{$id} // 0),
			   contests => ($contests{$id} // 0) }
		} $rs->all ]
}

sub user_entry {
	my ($self, $id) = @_;
	my $user = $self->users->find($id, {columns => USER_PUBLIC_COLUMNS, prefetch => [qw/problem_statuses contest_statuses/]});
	my @problems = map { {problem => $_->get_column('problem'), solved => $_->solved} } $user->problem_statuses->search(undef, {order_by => 'problem'});
	my @contests = map { {contest => $_->contest->id, contest_name => $_->contest->name, rank => $_->rank, score => $_->score} } $user->contest_statuses->search(undef, {prefetch => 'contest', order_by => 'contest.start DESC'});
	+{ $user->get_columns, problems => \@problems, contests => \@contests }
}

sub problem_list {
	my ($self, %args) = @_;
	my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
	push @columns, 'solution' if $args{solution} && $args{contest} && !$self->contest($args{contest})->is_running;
	my $rs = $self->problems->search(undef, {order_by => 'me.name', columns => \@columns, prefetch => 'owner'});
	$rs = $rs->search({'private' => 0}) unless $args{contest} || $args{private};
	$rs = $rs->search({'contest_problems.contest' => $args{contest}}, {join => 'contest_problems'}) if $args{contest};
	$rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
	my %params;
	$params{contest} = $args{contest} if $args{contest} && $self->contest($args{contest})->is_running;
	for ($rs->all) {
		$params{$_->level} //= [];
		push @{$params{$_->level}}, {$_->get_columns, owner_name => $_->owner->name} ;
	}
	\%params
}

sub problem_entry {
	my ($self, $id, $contest, $user) = @_;
	my $running = $contest && $self->contest($contest)->is_running;
	my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
	push @columns, 'statement';
	push @columns, 'solution' unless $running;
	my $pb = $self->problems->find($id, {columns => \@columns, prefetch => 'owner'});
	my @limits = map { +{
		format  => $_->format,
		timeout => $_->timeout,
	} } $self->limits->search({problem => $id});
	my $open;
	$open = $self->opens->find_or_create({
		contest => $contest,
		problem => $id,
		owner => $user,
		time => time,
	}) if $running;
	$contest &&= $self->contest($contest);
	+{
		$pb->get_columns,
		@limits ? (limits => \@limits) : (),
		owner_name => $pb->owner->name,
		cansubmit => !$contest || !$contest->is_finished,
		$running ? (
			contest_start => $contest->start,
			contest_stop => $contest->stop,
			open_time => $open->time
		) : (),
	}
}

sub contest_list {
	my ($self, %args) = @_;
	my $rs = $self->contests->search(undef, {columns => CONTEST_PUBLIC_COLUMNS, order_by => {-desc => 'start'}, prefetch => 'owner'});
	$rs = $rs->search({owner => $args{owner}}) if $args{owner};
	my %params;
	for ($rs->all) {
		my $state = $_->is_pending ? 'pending' : $_->is_running ? 'running' : 'finished';
		$params{$state} //= [];
		push @{$params{$state}}, { $_->get_columns, owner_name => $_->owner->name };
	}
	\%params
}

sub contest_entry {
	my ($self, $id) = @_;
	my $ct = $self->contests->find($id,{columns => CONTEST_PUBLIC_COLUMNS});
	+{ $ct->get_columns, started => !$ct->is_pending, finished => $ct->is_finished, owner_name => $ct->owner->name }
}

sub job_list {
	my ($self, %args) = @_;
	$args{page} //= 1;
	my $rs = $self->jobs->search(undef, {order_by => {-desc => 'me.id'}, prefetch => ['problem', 'owner', 'contest'], rows => JOBS_PER_PAGE, page => $args{page}});
	$rs = $rs->search({contest => $args{contest} || undef}) if exists $args{contest};
	$rs = $rs->search({'me.private'=> 0})          unless $args{private};
	$rs = $rs->search({'me.owner'  => $args{owner}})   if $args{owner};
	$rs = $rs->search({problem     => $args{problem}}) if $args{problem};
	$rs = $rs->search({result      => $args{result}})  if defined $args{result};
	return {
		log => [map {
			my %params = $_->get_columns;
			$params{owner_name}   = $_->owner->name;
			$params{problem_name} = $_->problem->name;
			$params{contest_name} = $_->contest->name if $params{contest};
			$params{results} &&= decode_json $params{results};
			$params{size}      = length $params{source};
			delete $params{source};
			\%params
		} $rs->all],
		current_page => $rs->pager->current_page,
		maybe previous_page => $rs->pager->previous_page,
		maybe next_page => $rs->pager->next_page,
		maybe last_page => $rs->pager->last_page,
	}
}

sub job_entry {
	my ($self, $id) = @_;
	my $job = $self->jobs->find($id, {prefetch => ['problem', 'owner', 'contest']});
	my %params = $job->get_columns;
	$params{owner_name}   = $job->owner->name;
	$params{problem_name} = $job->problem->name;
	$params{contest_name} = $job->contest->name if $params{contest};
	$params{results} &&= decode_json $params{results};
	$params{size}      = length $params{source};
	delete $params{source};
	\%params
}

sub update_status {
	my ($self) = @_;
	my @jobs = $self->jobs->search({'me.private' => 0}, {cache => 1, prefetch => 'problem', order_by => 'me.id'})->all;

	my %private;
	my %hash;
	for (@jobs) {
		my $pb = $_->get_column('problem');
		$private{$pb} //= $_->problem->private;
		next if $private{$pb};
		$hash{$pb, $_->get_column('owner')} = [$_->id, $_->result ? 0 : 1];
	}

	my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;

	my @contest_statuses = map {
		my $contest = $_->id;
		map { [$contest, $_->{user}, $_->{score}, $_->{rank}] } $_->standings
	} $self->contests->all;

	my $txn = sub {
		$self->problem_statuses->delete;
		$self->problem_statuses->populate([[qw/problem owner job solved/], @problem_statuses]);
		$self->contest_statuses->delete;
		$self->contest_statuses->populate([[qw/contest owner score rank/], @contest_statuses]);
	};

	$self->txn_do($txn);
}

my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
my $ht = HTTP::Tiny->new;

sub purge {
	$ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
}

1;

__END__

=encoding utf-8

=head1 NAME

Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools

=head1 SYNOPSIS

  my $db = Gruntmaster::Data->connect('dbi:Pg:');

  my $problem = $db->problem('my_problem');
  $problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
  $problem->rerun; # And rerun all jobs for this problem

  # ...

  my $contest = $db->contests->create({ # Create a new contest
    id => 'my_contest',
    name => 'My Awesome Contest',
    start => time + 100,
    end => time + 1900,
  });
  $db->contest_problems->create({ # Add a problem to the contest
    contest => 'my_contest',
    problem => 'my_problem',
  });

  say 'The contest has not started yet' if $contest->is_pending;

  # ...

  my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
  $_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest

=head1 DESCRIPTION

Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.

In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:

=over

=item contests

Equivalent to C<< $schema->resultset('Contest') >>

=item contest_problems

Equivalent to C<< $schema->resultset('ContestProblem') >>

=item jobs

Equivalent to C<< $schema->resultset('Job') >>

=item problems

Equivalent to C<< $schema->resultset('Problem') >>

=item users

Equivalent to C<< $schema->resultset('User') >>

=item contest($id)

Equivalent to C<< $schema->resultset('Contest')->find($id) >>

=item job($id)

Equivalent to C<< $schema->resultset('Job')->find($id) >>

=item problem($id)

Equivalent to C<< $schema->resultset('Problem')->find($id) >>

=item user($id)

Equivalent to C<< $schema->resultset('User')->find($id) >>

=item user_list

Returns a list of users as an arrayref containing hashrefs.

=item user_entry($id)

Returns a hashref with information about the user $id.

=item problem_list([%args])

Returns a list of problems grouped by level. A hashref with levels as keys.

Takes the following arguments:

=over

=item owner

Only show problems owned by this user

=item contest

Only show problems in this contest

=back

=item problem_entry($id, [$contest, $user])

Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.

=item contest_list([%args])

Returns a list of contests grouped by state. A hashref with the following keys:

=over

=item pending

An arrayref of hashrefs representing pending contests

=item running

An arrayref of hashrefs representing running contests

=item finished

An arrayref of hashrefs representing finished contests

=back

Takes the following arguments:

=over

=item owner

Only show contests owned by this user.

=back

=item contest_entry($id)

Returns a hashref with information about the contest $id.

=item job_list([%args])

Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:

=over

=item owner

Only show jobs submitted by this user.

=item contest

Only show jobs submitted in this contest.

=item problem

Only show jobs submitted for this problem.

=item page

Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.

=back

=item job_entry($id)

Returns a hashref with information about the job $id.

=back

=head1 AUTHOR

Marius Gavrilescu E<lt>marius@ieval.roE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2014 by Marius Gavrilescu

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.18.1 or,
at your option, any later version of Perl 5 you may have available.


=cut
Commit	Line	Data
4ed3f8e7	1	use utf8;
bbf8209c	2	package Gruntmaster::Data;
4ed3f8e7 MG	3
	4	# Created by DBIx::Class::Schema::Loader
	5	# DO NOT MODIFY THE FIRST PART OF THIS FILE
	6
	7	use strict;
bbf8209c	8	use warnings;
014ee8a6	9
4ed3f8e7 MG	10	use base 'DBIx::Class::Schema';
	11
	12	__PACKAGE__->load_namespaces;
014ee8a6	13
f7386aab	14
4ed3f8e7 MG	15	# Created by DBIx::Class::Schema::Loader v0.07039 @ 2014-03-05 13:11:39
	16	# DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:dAEmtAexvUaNXLgYz2rNEg
	17
edfc5928	18	use parent qw/Exporter/;
9e130d3b	19	our $VERSION = '5999.000_013';
de7226ca	20	our @EXPORT = qw/purge/; ## no critic (ProhibitAutomaticExportation)
4ed3f8e7 MG	21
4ed3f8e7 MG	22	use Lingua::EN::Inflect qw/PL_N/;
91203bd5	23	use JSON::MaybeXS qw/decode_json/;
edfc5928	24	use HTTP::Tiny;
3473324b	25	use PerlX::Maybe qw/maybe/;
4ed3f8e7	26	use Sub::Name qw/subname/;
014ee8a6	27
d5046b3d	28	use constant CONTEST_PUBLIC_COLUMNS => [qw/id name description start stop owner/];
e890b3ae	29	use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private timeout olimit value/];
73243865	30	use constant USER_PUBLIC_COLUMNS => [qw/id admin name town university country level/];
de625c9b MG	31	use constant JOBS_PER_PAGE => 10;
de625c9b MG	32
014ee8a6	33	sub dynsub{
fb6a4e3d	34	our ($name, $sub) = @_;
dcd72991	35	no strict 'refs'; ## no critic (Strict)
fb6a4e3d	36	*$name = subname $name => $sub
014ee8a6 MG	37	}
	38
	39	BEGIN {
6dda1f23	40	for my $rs (qw/contest contest_problem job open limit problem user problem_status contest_status/) {
4ed3f8e7	41	my $rsname = ucfirst $rs;
dcd72991	42	$rsname =~ s/_([a-z])/\u$1/gs;
4ed3f8e7 MG	43	dynsub PL_N($rs) => sub { $_[0]->resultset($rsname) };
4ed3f8e7 MG	44	dynsub $rs => sub { $_[0]->resultset($rsname)->find($_[1]) };
014ee8a6 MG	45	}
	46	}
	47
de625c9b	48	sub user_list {
c9311d50 MG	49	my ($self) = @_;
	50	my $rs = $self->users->search(undef, {columns => USER_PUBLIC_COLUMNS} );
	51	my (%solved, %attempted, %contests);
	52
	53	for my $row ($self->problem_statuses->all) {
	54	$solved {$row->rawowner}++ if $row->solved;
	55	$attempted{$row->rawowner}++ unless $row->solved;
	56	}
	57	$contests{$_->rawowner}++ for $self->contest_statuses->all;
	58
a78c65b6 MG	59	[ sort { $b->{solved} <=> $a->{solved} or $b->{attempted} <=> $a->{attempted} } ## no critic (ProhibitReverseSort)
	60	grep { $_->{solved} \|\| $_->{attempted} } map {
	61	my $id = $_->id;
	62	+{ $_->get_columns,
	63	solved => ($solved{$id} // 0),
	64	attempted => ($attempted{$id} // 0),
	65	contests => ($contests{$id} // 0) }
	66	} $rs->all ]
de625c9b MG	67	}
	68
	69	sub user_entry {
	70	my ($self, $id) = @_;
adb42d4d	71	my $user = $self->users->find($id, {columns => USER_PUBLIC_COLUMNS, prefetch => [qw/problem_statuses contest_statuses/]});
197d1959 MG	72	my @problems = map { {problem => $_->get_column('problem'), solved => $_->solved} } $user->problem_statuses->search(undef, {order_by => 'problem'});
197d1959 MG	73	my @contests = map { {contest => $_->contest->id, contest_name => $_->contest->name, rank => $_->rank, score => $_->score} } $user->contest_statuses->search(undef, {prefetch => 'contest', order_by => 'contest.start DESC'});
adb42d4d	74	+{ $user->get_columns, problems => \@problems, contests => \@contests }
de625c9b MG	75	}
	76
	77	sub problem_list {
	78	my ($self, %args) = @_;
4db1f725 MG	79	my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
	80	push @columns, 'solution' if $args{solution} && $args{contest} && !$self->contest($args{contest})->is_running;
	81	my $rs = $self->problems->search(undef, {order_by => 'me.name', columns => \@columns, prefetch => 'owner'});
aadc8d86	82	$rs = $rs->search({'private' => 0}) unless $args{contest} \|\| $args{private};
de625c9b MG	83	$rs = $rs->search({'contest_problems.contest' => $args{contest}}, {join => 'contest_problems'}) if $args{contest};
	84	$rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
	85	my %params;
e340417c	86	$params{contest} = $args{contest} if $args{contest} && $self->contest($args{contest})->is_running;
de625c9b MG	87	for ($rs->all) {
de625c9b MG	88	$params{$_->level} //= [];
35596ea8	89	push @{$params{$_->level}}, {$_->get_columns, owner_name => $_->owner->name} ;
de625c9b MG	90	}
	91	\%params
	92	}
	93
	94	sub problem_entry {
	95	my ($self, $id, $contest, $user) = @_;
de625c9b	96	my $running = $contest && $self->contest($contest)->is_running;
4db1f725 MG	97	my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
	98	push @columns, 'statement';
	99	push @columns, 'solution' unless $running;
	100	my $pb = $self->problems->find($id, {columns => \@columns, prefetch => 'owner'});
5401c109 MG	101	my @limits = map { +{
	102	format => $_->format,
	103	timeout => $_->timeout,
	104	} } $self->limits->search({problem => $id});
9396be04 MG	105	my $open;
	106	$open = $self->opens->find_or_create({
	107	contest => $contest,
	108	problem => $id,
	109	owner => $user,
	110	time => time,
	111	}) if $running;
2431260b	112	$contest &&= $self->contest($contest);
9396be04 MG	113	+{
9396be04 MG	114	$pb->get_columns,
5401c109	115	@limits ? (limits => \@limits) : (),
9396be04	116	owner_name => $pb->owner->name,
1ecf0766	117	cansubmit => !$contest \|\| !$contest->is_finished,
9396be04 MG	118	$running ? (
	119	contest_start => $contest->start,
	120	contest_stop => $contest->stop,
	121	open_time => $open->time
	122	) : (),
	123	}
de625c9b MG	124	}
	125
	126	sub contest_list {
	127	my ($self, %args) = @_;
d5046b3d	128	my $rs = $self->contests->search(undef, {columns => CONTEST_PUBLIC_COLUMNS, order_by => {-desc => 'start'}, prefetch => 'owner'});
de625c9b MG	129	$rs = $rs->search({owner => $args{owner}}) if $args{owner};
	130	my %params;
	131	for ($rs->all) {
	132	my $state = $_->is_pending ? 'pending' : $_->is_running ? 'running' : 'finished';
	133	$params{$state} //= [];
b3cf23ae	134	push @{$params{$state}}, { $_->get_columns, owner_name => $_->owner->name };
de625c9b MG	135	}
	136	\%params
	137	}
	138
	139	sub contest_entry {
	140	my ($self, $id) = @_;
d5046b3d	141	my $ct = $self->contests->find($id,{columns => CONTEST_PUBLIC_COLUMNS});
a11202e4	142	+{ $ct->get_columns, started => !$ct->is_pending, finished => $ct->is_finished, owner_name => $ct->owner->name }
de625c9b MG	143	}
	144
	145	sub job_list {
	146	my ($self, %args) = @_;
	147	$args{page} //= 1;
4adba835	148	my $rs = $self->jobs->search(undef, {order_by => {-desc => 'me.id'}, prefetch => ['problem', 'owner', 'contest'], rows => JOBS_PER_PAGE, page => $args{page}});
9d16980e	149	$rs = $rs->search({contest => $args{contest} \|\| undef}) if exists $args{contest};
d4c5bf27 MG	150	$rs = $rs->search({'me.private'=> 0}) unless $args{private};
d4c5bf27 MG	151	$rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
d4c5bf27	152	$rs = $rs->search({problem => $args{problem}}) if $args{problem};
02844430	153	$rs = $rs->search({result => $args{result}}) if defined $args{result};
3473324b MG	154	return {
	155	log => [map {
	156	my %params = $_->get_columns;
	157	$params{owner_name} = $_->owner->name;
	158	$params{problem_name} = $_->problem->name;
4adba835	159	$params{contest_name} = $_->contest->name if $params{contest};
3473324b MG	160	$params{results} &&= decode_json $params{results};
	161	$params{size} = length $params{source};
	162	delete $params{source};
	163	\%params
	164	} $rs->all],
	165	current_page => $rs->pager->current_page,
	166	maybe previous_page => $rs->pager->previous_page,
	167	maybe next_page => $rs->pager->next_page,
	168	maybe last_page => $rs->pager->last_page,
	169	}
de625c9b MG	170	}
	171
	172	sub job_entry {
	173	my ($self, $id) = @_;
7d499cdd	174	my $job = $self->jobs->find($id, {prefetch => ['problem', 'owner', 'contest']});
de625c9b MG	175	my %params = $job->get_columns;
	176	$params{owner_name} = $job->owner->name;
	177	$params{problem_name} = $job->problem->name;
7d499cdd	178	$params{contest_name} = $job->contest->name if $params{contest};
de625c9b MG	179	$params{results} &&= decode_json $params{results};
	180	$params{size} = length $params{source};
	181	delete $params{source};
	182	\%params
	183	}
	184
adb42d4d MG	185	sub update_status {
adb42d4d MG	186	my ($self) = @_;
dbbf61be	187	my @jobs = $self->jobs->search({'me.private' => 0}, {cache => 1, prefetch => 'problem', order_by => 'me.id'})->all;
a2aa46e6	188
27a32e4b	189	my %private;
adb42d4d	190	my %hash;
64bc7dfb	191	for (@jobs) {
27a32e4b	192	my $pb = $_->get_column('problem');
5657ea00	193	$private{$pb} //= $_->problem->private;
9a24a777	194	next if $private{$pb};
95594d6d	195	$hash{$pb, $_->get_column('owner')} = [$_->id, $_->result ? 0 : 1];
64bc7dfb MG	196	}
64bc7dfb MG	197
adb42d4d MG	198	my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;
	199
	200	my @contest_statuses = map {
	201	my $contest = $_->id;
751c70b5	202	map { [$contest, $_->{user}, $_->{score}, $_->{rank}] } $_->standings
adb42d4d MG	203	} $self->contests->all;
	204
	205	my $txn = sub {
	206	$self->problem_statuses->delete;
	207	$self->problem_statuses->populate([[qw/problem owner job solved/], @problem_statuses]);
	208	$self->contest_statuses->delete;
	209	$self->contest_statuses->populate([[qw/contest owner score rank/], @contest_statuses]);
	210	};
	211
	212	$self->txn_do($txn);
	213	}
	214
edfc5928 MG	215	my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
	216	my $ht = HTTP::Tiny->new;
	217
de7226ca MG	218	sub purge {
	219	$ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
	220	}
edfc5928	221
f7386aab	222	1;
4a8747ef MG	223
	224	__END__
	225
	226	=encoding utf-8
	227
	228	=head1 NAME
	229
	230	Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools
	231
	232	=head1 SYNOPSIS
	233
	234	my $db = Gruntmaster::Data->connect('dbi:Pg:');
cbb36c78 MG	235
	236	my $problem = $db->problem('my_problem');
	237	$problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
	238	$problem->rerun; # And rerun all jobs for this problem
	239
	240	# ...
	241
	242	my $contest = $db->contests->create({ # Create a new contest
	243	id => 'my_contest',
	244	name => 'My Awesome Contest',
	245	start => time + 100,
	246	end => time + 1900,
	247	});
	248	$db->contest_problems->create({ # Add a problem to the contest
	249	contest => 'my_contest',
	250	problem => 'my_problem',
	251	});
	252
	253	say 'The contest has not started yet' if $contest->is_pending;
	254
	255	# ...
	256
	257	my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
	258	$_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest
4a8747ef MG	259
	260	=head1 DESCRIPTION
	261
cbb36c78 MG	262	Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.
	263
	264	In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:
	265
	266	=over
	267
	268	=item contests
	269
	270	Equivalent to C<< $schema->resultset('Contest') >>
	271
	272	=item contest_problems
	273
	274	Equivalent to C<< $schema->resultset('ContestProblem') >>
	275
	276	=item jobs
	277
	278	Equivalent to C<< $schema->resultset('Job') >>
	279
	280	=item problems
	281
	282	Equivalent to C<< $schema->resultset('Problem') >>
	283
	284	=item users
	285
	286	Equivalent to C<< $schema->resultset('User') >>
	287
	288	=item contest($id)
	289
	290	Equivalent to C<< $schema->resultset('Contest')->find($id) >>
	291
	292	=item job($id)
	293
	294	Equivalent to C<< $schema->resultset('Job')->find($id) >>
	295
	296	=item problem($id)
	297
	298	Equivalent to C<< $schema->resultset('Problem')->find($id) >>
	299
	300	=item user($id)
	301
	302	Equivalent to C<< $schema->resultset('User')->find($id) >>
	303
de625c9b MG	304	=item user_list
	305
	306	Returns a list of users as an arrayref containing hashrefs.
	307
	308	=item user_entry($id)
	309
	310	Returns a hashref with information about the user $id.
	311
	312	=item problem_list([%args])
	313
	314	Returns a list of problems grouped by level. A hashref with levels as keys.
	315
	316	Takes the following arguments:
	317
	318	=over
	319
	320	=item owner
	321
	322	Only show problems owned by this user
	323
	324	=item contest
	325
	326	Only show problems in this contest
	327
	328	=back
	329
	330	=item problem_entry($id, [$contest, $user])
	331
	332	Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.
	333
	334	=item contest_list([%args])
	335
	336	Returns a list of contests grouped by state. A hashref with the following keys:
	337
	338	=over
	339
	340	=item pending
	341
	342	An arrayref of hashrefs representing pending contests
	343
	344	=item running
	345
	346	An arrayref of hashrefs representing running contests
	347
	348	=item finished
	349
	350	An arrayref of hashrefs representing finished contests
	351
	352	=back
	353
	354	Takes the following arguments:
	355
	356	=over
	357
	358	=item owner
	359
	360	Only show contests owned by this user.
	361
	362	=back
	363
	364	=item contest_entry($id)
	365
	366	Returns a hashref with information about the contest $id.
	367
368	=item job_list([%args])
369
370	Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:
371
372	=over
373
374	=item owner
375
376	Only show jobs submitted by this user.
377
378	=item contest
379
380	Only show jobs submitted in this contest.
381
382	=item problem
383
384	Only show jobs submitted for this problem.
385
386	=item page
387
388	Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.
389
390	=back
391
392	=item job_entry($id)
393
394	Returns a hashref with information about the job $id.
395
cbb36c78	396	=back
4a8747ef MG	397
	398	=head1 AUTHOR
	399
	400	Marius Gavrilescu E<lt>marius@ieval.roE<gt>
	401
	402	=head1 COPYRIGHT AND LICENSE
	403
	404	Copyright (C) 2014 by Marius Gavrilescu
	405
9d2e740e MG	406	This library is free software; you can redistribute it and/or modify
	407	it under the same terms as Perl itself, either Perl version 5.18.1 or,
	408	at your option, any later version of Perl 5 you may have available.
4a8747ef MG	409
	410
	411	=cut