app.psgi

   1 #!/usr/bin/perl
   2 use v5.14;
   3 use warnings;
   4
   5 use Gruntmaster::Data;
   6 use Plack::App::Gruntmaster;
   7 use Plack::Builder;
   8 use Plack::Util;
   9 use Log::Log4perl;
  10
  11 sub CONTENT_SECURITY_POLICY () {
  12         my $csp = <<CSP;
  13 default-src 'none'
  14 connect-src 'self'
  15 form-action 'self'
  16 frame-ancestors 'none'
  17 img-src 'self'
  18 referrer origin-when-cross-origin
  19 script-src 'self'
  20 style-src 'self'
  21 CSP
  22         chomp $csp;
  23         $csp =~ s/\n/; /gr;
  24 }
  25
  26 my $db;
  27
  28 sub add_database {
  29         my $app = $_[0];
  30         sub {
  31                 my ($env) = @_;
  32                 $db //= Gruntmaster::Data->connect($ENV{GRUNTMASTER_DSN} // 'dbi:Pg:');
  33                 $env->{'gruntmaster.dbic'} = $db;
  34                 $app->($env)
  35         }
  36 }
  37
  38 sub add_headers {
  39         my $app = $_[0];
  40         sub {
  41                 my $resp = $app->($_[0]);
  42                 my $hdrs = Plack::Util::headers($resp->[1]);
  43                 $hdrs->set('Content-Security-Policy', CONTENT_SECURITY_POLICY);
  44                 $hdrs->set('Link', '</static/cyborg.css>; rel=stylesheet') if $hdrs->get('Content-Type') =~ m,^text/html,;
  45                 $hdrs->set('Cache-Control', 'public, max-age=604800') if $_[0]->{PATH_INFO} =~ qr,^/static/,;
  46                 $resp->[1] = $hdrs->headers;
  47                 $resp;
  48         }
  49 }
  50
  51 Log::Log4perl->init_once('log.conf');
  52 $ENV{DBIC_NULLABLE_KEY_NOWARN} = 1;
  53
  54 builder {
  55         enable_if { $_[0]->{PATH_INFO} eq '/ok' } sub { sub{ [200, [], []] }};
  56         enable 'ContentLength';
  57         enable \&add_headers;
  58         enable 'Static', path => qr,^/static/,;
  59         enable 'Log4perl', category => 'plack';
  60         enable \&add_database;
  61         enable '+Plack::App::Gruntmaster::Auth',
  62           dbi_connect => [$ENV{GRUNTMASTER_DSN} // 'dbi:Pg:', '', ''],
  63           realm       => 'Gruntmaster 6000',
  64           mail_from   => $ENV{GRUNTMASTER_RESET_FROM};
  65         Plack::App::Gruntmaster->run_if_script
  66 }