app.psgi

   1 #!/usr/bin/perl -w
   2 use v5.14;
   3 no if $] >= 5.017011, warnings => 'experimental::smartmatch';
   4
   5 use Gruntmaster::Data;
   6 use Plack::App::Gruntmaster;
   7 use Plack::Builder;
   8 use Plack::Util;
   9 use Log::Log4perl;
  10
  11 use constant AUTH_TIMEOUT => 5 * 60;
  12 use constant ACCESSLOG_FORMAT => 'combined';
  13
  14 sub CONTENT_SECURITY_POLICY () {
  15         my $csp = <<CSP;
  16 default-src 'none'
  17 connect-src 'self'
  18 form-action 'self'
  19 frame-ancestors 'none'
  20 img-src 'self'
  21 referrer origin-when-cross-origin
  22 script-src 'self'
  23 style-src 'self'
  24 CSP
  25         chomp $csp;
  26         $csp =~ s/\n/; /gr;
  27 }
  28
  29 my $db;
  30
  31 sub add_database {
  32         my $app = $_[0];
  33         sub {
  34                 my ($env) = @_;
  35                 $db //= Gruntmaster::Data->connect($ENV{GRUNTMASTER_DSN} // 'dbi:Pg:');
  36                 $env->{'gruntmaster.dbic'} = $db;
  37                 $app->($env)
  38         }
  39 }
  40
  41 sub add_headers {
  42         my $app = $_[0];
  43         sub {
  44                 my $resp = $app->($_[0]);
  45                 my $hdrs = Plack::Util::headers($resp->[1]);
  46                 $hdrs->set('Content-Security-Policy', CONTENT_SECURITY_POLICY);
  47                 $hdrs->set('Link', '</static/cyborg.css>; rel=stylesheet') if $hdrs->get('Content-Type') =~ m,^text/html,;
  48                 $hdrs->set('Cache-Control', 'public, max-age=604800') if $_[0]->{PATH_INFO} =~ qr,^/static/,;
  49                 $resp->[1] = $hdrs->headers;
  50                 $resp;
  51         }
  52 }
  53
  54 Log::Log4perl->init_once('log.conf');
  55 my $access_logger = Log::Log4perl->get_logger('access');
  56 $ENV{DBIC_NULLABLE_KEY_NOWARN} = 1;
  57
  58 builder {
  59         enable_if { $_[0]->{PATH_INFO} eq '/ok' } sub { sub{ [200, [], []] }};
  60         enable 'AccessLog', format => ACCESSLOG_FORMAT, logger => sub { $access_logger->info(@_) };
  61         enable 'ContentLength';
  62         enable \&add_headers;
  63         enable 'Static', path => qr,^/static/,;
  64         enable 'Log4perl', category => 'plack';
  65         enable \&add_database;
  66         enable '+Plack::App::Gruntmaster::Auth',
  67           dbi_connect => [$ENV{GRUNTMASTER_DSN} // 'dbi:Pg:', '', ''],
  68           realm       => 'Gruntmaster 6000',
  69           mail_from   => $ENV{GRUNTMASTER_RESET_FROM};
  70         Plack::App::Gruntmaster->run_if_script
  71 }