lib/Plack/App/Gruntmaster.pm

   1 package Plack::App::Gruntmaster;
   2
   3 use 5.014000;
   4 use strict;
   5 our $VERSION = '5999.000_001';
   6
   7 use Encode qw/encode decode/;
   8 use File::Slurp qw/read_file/;
   9 use JSON::MaybeXS qw/encode_json/;
  10 use PerlX::Maybe;
  11 use Scope::Upper qw/unwind SUB UP/;
  12 use Web::Simple;
  13
  14 use Gruntmaster::Data;
  15 use Plack::App::Gruntmaster::HTML;
  16
  17 use Email::Sender::Simple qw/sendmail/;
  18 use Email::Simple;
  19
  20 use warnings NONFATAL => 'all';
  21 no warnings 'illegalproto';
  22
  23 ##################################################
  24
  25 use constant USER_REGEX => qr/^\w{2,20}$/a;
  26
  27 use constant CONTENT_TYPES => +{
  28         c => 'text/x-csrc',
  29         cpp => 'text/x-c++src',
  30         cs => 'text/x-csharp', # Used by GNOME. Not in mime.types.
  31         go => 'text/plain', # ?
  32         hs => 'text/x-haskell',
  33         java => 'text/x-java',
  34         pas => 'text/x-pascal',
  35         pl => 'text/x-perl',
  36         py => 'text/x-python',
  37         l => 'text/plain',
  38 };
  39
  40 use constant FORMAT_EXTENSION => {
  41         C => 'c',
  42         CPP => 'cpp',
  43         GCCGO => 'go',
  44         GOLANG => 'go',
  45         HASKELL => 'hs',
  46         MONO => 'cs',
  47         JAVA => 'java',
  48         PASCAL => 'pas',
  49         PERL => 'pl',
  50         PYTHON => 'py',
  51         SBCL => 'l',
  52 };
  53
  54 use constant NOT_FOUND => [404, ['X-Forever' => 1, 'Content-Type' => 'text/plain'], ['Not found']];
  55
  56 my ($env, $privacy);
  57
  58 sub db { $env->{'gruntmaster.dbic'} }
  59
  60 sub remote_user {
  61         my $user = $env->{REMOTE_USER};
  62         $user &&= db->user($user);
  63         $user
  64 }
  65
  66 sub admin   { remote_user && remote_user->admin }
  67 sub contest { db->contest ($_{contest}) }
  68 sub problem { db->problem ($_{problem}) }
  69 sub job     { db->job     ($_{job})     }
  70 sub user    { db->user    ($_{user})    }
  71
  72 sub redirect { [301, ['X-Forever' => 1, 'Location' => $_[0]], []] }
  73 sub reply    { [200, ['Content-Type' => 'text/plain; charset=utf-8'], \@_] }
  74 sub response {
  75         my ($template, $title, $params, $maxage) = @_;
  76         unless ($params) {
  77                 $params = $title;
  78                 $title = 'No title';
  79         }
  80         $params->{time} = time;
  81         $params->{args} = {%_};
  82         bless {template => $template, title => $title, params => $params, maxage => ($maxage // 1)}, __PACKAGE__.'::Response'
  83 }
  84
  85 sub forbid {
  86         my ($condition) = @_;
  87         $privacy = 'private' if $condition;
  88         return if !$condition || admin;
  89         unwind $env->{authcomplex}->unauthorized, SUB UP
  90 }
  91
  92 sub dispatch_request{
  93         $env = $_[PSGI_ENV];
  94         $privacy = 'public';
  95
  96         sub (GET) {
  97                 sub (/robots.txt) { NOT_FOUND },
  98
  99                 sub (/src/:job) {
 100                         return NOT_FOUND if !job;
 101                         my $isowner = remote_user && remote_user->id eq job->rawowner;
 102                         my $private = job->private || job->problem->private || job->contest && job->contest->is_running;
 103                         forbid !$isowner && $private;
 104                         my $privacy = $private ? 'private' : 'public';
 105                         my @headers = ('X-Forever' => 1, 'Cache-Control' => "$privacy, max-age=604800", 'Content-Type' => CONTENT_TYPES->{job->extension});
 106                         push @headers, (Vary => 'Authorization') if $private;
 107                         [200, \@headers, [job->source]]
 108                 },
 109
 110                 sub (?:format~) {
 111                         my $format = lc ($_{format} // '');
 112                         response_filter {
 113                                 my ($r) = @_;
 114                                 return $r if ref $r ne 'Plack::App::Gruntmaster::Response';
 115                                 my @hdrs = ('X-Forever' => 1, 'Cache-Control' => "$privacy, max-age=$r->{maxage}");
 116                                 push @hdrs, Vary => 'Authorization' if $privacy eq 'private';
 117                                 return [200, ['Content-Type' => 'application/json; charset=utf-8', @hdrs], [encode_json $r->{params}]] if $format eq 'json';
 118                                 my $ret = render $r->{template}, 'en', title => $r->{title}, %{$r->{params}};
 119                                 [200, ['Content-Type' => 'text/html; charset=utf-8', @hdrs], [encode 'UTF-8', $ret]]
 120                         },
 121                 },
 122
 123                 sub (/st/:contest) {
 124                         response st => 'Standings', {
 125                                 st => [ contest->standings ],
 126                                 problems => [
 127                                         map { [$_->id, $_->name] }
 128                                         sort { $a->value <=> $b->value }
 129                                         map { $_->problem } contest->contest_problems],
 130                         }, 10
 131                 },
 132
 133                 sub (/ed/:contest) {
 134                         forbid !contest->is_finished;
 135                         my $pblist = db->problem_list(contest => $_{contest}, solution => 1);
 136                         response ed => 'Editorial of ' . contest->name, {%$pblist, editorial => contest->editorial};
 137                 },
 138
 139                 sub (/login) {
 140                         forbid !remote_user;
 141
 142                         my $return = $env->{HTTP_REFERER} // '/';
 143                         [303, ['Set-Cookie' => "username=".remote_user->id, Location => $return], []]
 144                 },
 145
 146                 sub (/ct/:contest/log/st) { redirect "/st/$_{contest}" },
 147
 148                 sub (/us/)                                        { response us => 'Users', {us => db->user_list} },
 149                 sub (/ct/  + ?:owner~)                            { response ct => 'Contests', db->contest_list(%_) },
 150                 sub (/log/ + ?:contest~&:owner~&:page~&:problem~&:private~) {
 151                         forbid $_{private};
 152                         response log => 'Job list', {%{db->job_list(%_)}, maybe contest => $_{contest},}
 153                 },
 154                 sub (/pb/  + ?:owner~&:contest~&:private~)                  {
 155                         forbid $_{private};
 156                         response pb => 'Problems', db->problem_list(%_)
 157                 },
 158
 159                 sub (/us/:user)    { response us_entry => user->name, db->user_entry($_{user}) },
 160                 sub (/ct/:contest) { response ct_entry => contest->name, db->contest_entry($_{contest}) },
 161                 sub (/log/:job)    {
 162                         forbid job->private;
 163                         response log_entry => "Job  $_{job}", db->job_entry($_{job})
 164                 },
 165                 sub (/pb/:problem + ?contest~) {
 166                         my (undef, undef, $contest) = @_;
 167                         $_{contest} = $contest;
 168                         return NOT_FOUND if contest && !db->contest_problems->find($_{contest}, $_{problem});
 169                         forbid problem->private && !contest;
 170                         if (contest) {
 171                                 return redirect "/pb/$_{problem}" unless contest->is_running;
 172                                 forbid !remote_user;
 173                                 $privacy = 'private';
 174                         }
 175                         response pb_entry => problem->name, {%{db->problem_entry($_{problem}, $_{contest}, remote_user && remote_user->id)}, maybe contest => $_{contest}};
 176                 },
 177                 sub (/sol/:problem) {
 178                         forbid problem->private;
 179                         response sol => 'Solution of ' . problem->name, {solution => db->problem($_{problem})->solution};
 180                 },
 181
 182                 sub (/) { redispatch_to '/index' },
 183                 sub (/favicon.ico) { redirect '/static/favicon.ico' },
 184                 sub (/:article) { [200, ['Content-Type' => 'text/html; charset=utf-8', 'Cache-Control' => 'public, max-age=60', 'X-Forever' => 1], [render_article $_{article}, 'en']] }
 185         },
 186
 187         sub (POST) {
 188                 sub (/action/submit + %:problem=&:contest~&:prog_format=&:source_code~ + *prog~) {
 189                         my (undef, undef, $prog) = @_;
 190                         forbid !remote_user;
 191                         my $private = (problem->private && !contest) ? 1 : 0;
 192                         return reply 'This contest has finished' if contest && contest->is_finished;
 193                         return reply 'This contest has not yet started' if contest && contest->is_pending;
 194                         return reply 'This problem is private' if !admin && $private;
 195                         return reply 'This problem does not belong to this contest' if contest && !db->contest_problems->find($_{contest}, $_{problem});
 196                         return reply 'Maximum source size is 10KB' if ($prog ? $prog->size : length $_{source_code}) > 10 * 1024;
 197                         return reply 'You must wait 30 seconds between jobs' if !admin && time <= remote_user->lastjob + 30;
 198                         remote_user->update({lastjob => time});
 199
 200                         my $source = $prog ? read_file $prog->path : $_{source_code};
 201                         unlink $prog->path if $prog;
 202                         my $newjob = db->jobs->create({
 203                                 maybe contest => $_{contest},
 204                                 private => $private,
 205                                 date => time,
 206                                 extension => FORMAT_EXTENSION->{$_{prog_format}},
 207                                 format => $_{prog_format},
 208                                 problem => $_{problem},
 209                                 source => $source,
 210                                 owner => remote_user->id,
 211                         });
 212
 213                         [303, [Location => '/log/' . $newjob->id], []]
 214                 },
 215         }
 216 }
 217
 218
 219 1;
 220 __END__