lib/Plack/App/Gruntmaster.pm

   1 package Plack::App::Gruntmaster;
   2
   3 use 5.014000;
   4 use strict;
   5 our $VERSION = '5999.000_001';
   6
   7 use CSS::Minifier::XS;
   8 use Encode qw/encode decode/;
   9 use File::Slurp qw/read_file/;
  10 use JavaScript::Minifier::XS;
  11 use JSON::MaybeXS qw/encode_json/;
  12 use PerlX::Maybe;
  13 use Scope::Upper qw/unwind SUB UP/;
  14 use Web::Simple;
  15
  16 use Gruntmaster::Data;
  17 use Plack::App::Gruntmaster::HTML;
  18
  19 use Email::Sender::Simple qw/sendmail/;
  20 use Email::Simple;
  21
  22 use warnings NONFATAL => 'all';
  23 no warnings 'illegalproto';
  24
  25 ##################################################
  26
  27 use constant USER_REGEX => qr/^\w{2,20}$/a;
  28
  29 use constant CONTENT_TYPES => +{
  30         c => 'text/x-csrc',
  31         cpp => 'text/x-c++src',
  32         cs => 'text/x-csharp', # Used by GNOME. Not in mime.types.
  33         go => 'text/plain', # ?
  34         hs => 'text/x-haskell',
  35         java => 'text/x-java',
  36         pas => 'text/x-pascal',
  37         pl => 'text/x-perl',
  38         py => 'text/x-python',
  39         l => 'text/plain',
  40 };
  41
  42 use constant FORMAT_EXTENSION => {
  43         C => 'c',
  44         CPP => 'cpp',
  45         GCCGO => 'go',
  46         GOLANG => 'go',
  47         HASKELL => 'hs',
  48         MONO => 'cs',
  49         JAVA => 'java',
  50         PASCAL => 'pas',
  51         PERL => 'pl',
  52         PYTHON => 'py',
  53         SBCL => 'l',
  54 };
  55
  56 use constant NOT_FOUND => [404, ['X-Forever' => 1, 'Content-Type' => 'text/plain'], ['Not found']];
  57 use constant FORBIDDEN => [401, ['Content-Type' => 'text/plain', 'WWW-Authenticate' => 'Basic realm="Gruntmaster 6000"'], ['Forbidden']];
  58
  59 sub development() { ($ENV{PLACK_ENV} // 'development') eq 'development' }
  60
  61 my ($env, $privacy);
  62
  63 sub db { $env->{'gruntmaster.dbic'} }
  64
  65 sub remote_user {
  66         my $user = $env->{'gruntmaster.user'};
  67         $user &&= db->user($user);
  68         $user
  69 }
  70
  71 sub admin   { remote_user && remote_user->admin }
  72 sub contest { db->contest ($_{contest}) }
  73 sub problem { db->problem ($_{problem}) }
  74 sub job     { db->job     ($_{job})     }
  75 sub user    { db->user    ($_{user})    }
  76
  77 sub redirect { [301, ['X-Forever' => 1, 'Location' => $_[0]], []] }
  78 sub reply    { [200, ['Content-Type' => 'text/plain; charset=utf-8'], \@_] }
  79 sub response {
  80         my ($template, $title, $params, $maxage) = @_;
  81         unless ($params) {
  82                 $params = $title;
  83                 $title = 'No title';
  84         }
  85         $params->{time} = time;
  86         $params->{args} = {%_};
  87         bless {template => $template, title => $title, params => $params, maxage => ($maxage // 1)}, __PACKAGE__.'::Response'
  88 }
  89
  90 sub forbid {
  91         my ($condition) = @_;
  92         $privacy = 'private' if $condition;
  93         return if !$condition || admin;
  94         unwind FORBIDDEN, SUB UP
  95 }
  96
  97 sub dispatch_request{
  98         $env = $_[PSGI_ENV];
  99         $privacy = 'public';
 100
 101         sub (GET) {
 102                 sub (/css/:theme) {
 103                         my $theme = $_{theme};
 104                         return NOT_FOUND unless -e "css/themes/$theme.css";
 105                         my $css = read_file "css/themes/$theme.css";
 106                         $css .= read_file $_ for <css/*.css>;
 107                         my @headers = ('X-Forever' => 1, 'Cache-Control' => 'public, max-age=604800', 'Content-Type' => 'text/css; charset=utf-8');
 108                         [200, \@headers, [development ? $css : CSS::Minifier::XS::minify $css]]
 109                 },
 110
 111                 sub (/js.js) {
 112                         my $js;
 113                         $js .= read_file $_ for <js/*.js>;
 114                         my @headers = ('X-Forever' => 1, 'Cache-Control' => 'public, max-age=604800', 'Content-Type' => 'application/javascript; charset=utf-8');
 115                         [200, \@headers, [development ? $js : JavaScript::Minifier::XS::minify $js]]
 116                 },
 117
 118                 sub (/robots.txt) { NOT_FOUND },
 119                 sub (/favicon.ico) { NOT_FOUND },
 120
 121                 sub (/src/:job) {
 122                         return NOT_FOUND if !job;
 123                         my $isowner = remote_user && remote_user->id eq job->rawowner;
 124                         my $private = job->private || job->problem->private || job->contest && job->contest->is_running;
 125                         forbid !$isowner && $private;
 126                         my $privacy = $private ? 'private' : 'public';
 127                         my @headers = ('X-Forever' => 1, 'Cache-Control' => "$privacy, max-age=604800", 'Content-Type' => CONTENT_TYPES->{job->format});
 128                         push @headers, (Vary => 'Authorization') if $private;
 129                         [200, \@headers, [job->source]]
 130                 },
 131
 132                 sub (?:contest=) {
 133                         return NOT_FOUND if !contest;
 134                         forbid contest->is_pending;
 135                         response_filter { return shift }
 136                 },
 137
 138                 sub (?:problem=) {
 139                         return NOT_FOUND if !problem;
 140                         forbid problem->is_private;
 141                         response_filter { return shift }
 142                 },
 143
 144                 sub (?:format~) {
 145                         my $format = lc ($_{format} // '');
 146                         response_filter {
 147                                 my ($r) = @_;
 148                                 return $r if ref $r ne 'Plack::App::Gruntmaster::Response';
 149                                 my @hdrs = ('X-Forever' => 1, 'Cache-Control' => "$privacy, max-age=$r->{maxage}");
 150                                 push @hdrs, Vary => 'Authorization' if $privacy eq 'private';
 151                                 return [200, ['Content-Type' => 'application/json; charset=utf-8', @hdrs], [encode_json $r->{params}]] if $format eq 'json';
 152                                 my $ret = render $r->{template}, 'en', title => $r->{title}, %{$r->{params}};
 153                                 [200, ['Content-Type' => 'text/html; charset=utf-8', @hdrs], [encode 'UTF-8', $ret]]
 154                         },
 155                 },
 156
 157                 sub (/st/:contest) {
 158                         response st => 'Standings', {
 159                                 st => [ contest->standings ],
 160                                 problems => [
 161                                         map { [$_->id, $_->name] }
 162                                         sort { $a->value <=> $b->value }
 163                                         map { $_->problem } contest->contest_problems],
 164                         }, 10
 165                 },
 166
 167                 sub (/ed/:contest) {
 168                         forbid contest->is_running;
 169                         response ed => 'Editorial of ' . contest->name, db->problem_list(contest => $_{contest}, solution => 1);
 170                 },
 171
 172                 sub (/login) {
 173                         forbid !remote_user;
 174
 175                         my $return = $env->{HTTP_REFERER} // '/';
 176                         [303, ['Set-Cookie' => "username=".remote_user->id, Location => $return], []]
 177                 },
 178
 179                 sub (/ct/:contest/log/st) { redirect "/st/$_{contest}" },
 180
 181                 sub (/us/)                                        { response us => 'Users', {us => db->user_list} },
 182                 sub (/ct/  + ?:owner~)                            { response ct => 'Contests', db->contest_list(%_) },
 183                 sub (/log/ + ?:contest~&:owner~&:page~&:problem~&:private~) {
 184                         forbid $_{private};
 185                         response log => 'Job list', {%{db->job_list(%_)}, maybe contest => $_{contest},}
 186                 },
 187                 sub (/pb/  + ?:owner~&:contest~&:private~)                  {
 188                         forbid $_{private};
 189                         response pb => 'Problems', {%{db->problem_list(%_)}, maybe contest => $_{contest}}
 190                 },
 191
 192                 sub (/us/:user)    { response us_entry => user->name, db->user_entry($_{user}) },
 193                 sub (/ct/:contest) { response ct_entry => contest->name, db->contest_entry($_{contest}) },
 194                 sub (/log/:job)    {
 195                         forbid job->private;
 196                         response log_entry => "Job  $_{job}", db->job_entry($_{job})
 197                 },
 198                 sub (/pb/:problem + ?contest~) {
 199                         my (undef, undef, $contest) = @_;
 200                         $_{contest} = $contest;
 201                         return NOT_FOUND if !contest && !problem->is_in_archive || contest && !db->contest_problems->find($_{contest}, $_{problem});
 202                         forbid problem->is_private;
 203                         if (contest && contest->is_running) {
 204                                 forbid !remote_user;
 205                                 $privacy = 'private';
 206                         }
 207                         response pb_entry => problem->name, {%{db->problem_entry($_{problem}, $_{contest}, remote_user && remote_user->id)}, maybe contest => $_{contest}};
 208                 },
 209                 sub (/sol/:problem) {
 210                         forbid !problem->is_in_archive;
 211                         response sol => 'Solution of ' . problem->name, {solution => db->problem($_{problem})->solution};
 212                 },
 213
 214                 sub (/) { redispatch_to '/index' },
 215                 sub (/favicon.ico) { redirect '/static/favicon.ico' },
 216                 sub (/:article) { [200, ['Content-Type' => 'text/html; charset=utf-8', 'Cache-Control' => 'public, max-age=60', 'X-Forever' => 1], [render_article $_{article}, 'en']] }
 217         },
 218
 219         sub (POST) {
 220                 sub (/action/register + %:username=&:password=&:confirm_password=&:name=&:email=&:phone=&:town=&:university=&:country=&:level=) {
 221                         return reply 'Parameter too long' if grep { length > 200 } values %_;
 222                         return reply 'Bad username. Allowed characters are letters, digits and underscores, and the username must be between 2 and 20 characters long.' unless $_{username} =~ USER_REGEX;
 223                         return reply 'Username already in use' if db->user($_{username});
 224                         return reply 'The two passwords do not match' unless $_{password} eq $_{confirm_password};
 225
 226                         db->users->create({id => $_{username}, name => $_{name}, email => $_{email}, phone => $_{phone}, town => $_{town}, university => $_{university}, country => $_{country}, level => $_{level}});
 227                         db->user($_{username})->set_passphrase($_{password});
 228
 229                         purge '/us/';
 230                         reply 'Registered successfully';
 231                 },
 232
 233                 sub (/action/passwd + %:password=&:new_password=&:confirm_new_password=) {
 234                         forbid !remote_user;
 235                         return reply 'Incorrect password' unless remote_user->check_passphrase($_{password});
 236                         return reply 'The two passwords do not match' unless $_{new_password} eq $_{confirm_new_password};
 237                         remote_user->set_passphrase($_{new_password});
 238                         reply 'Password changed successfully';
 239                 },
 240
 241                 sub (/action/submit + %:problem=&:contest~&:prog_format=&:source_code~ + *prog~) {
 242                         my (undef, undef, $prog) = @_;
 243                         forbid !remote_user;
 244                         return reply 'This contest has finished' if contest && contest->is_finished;
 245                         return reply 'This contest has not yet started' if !admin && contest && contest->is_pending;
 246                         return reply 'This problem does not belong to this contest' if !contest && !problem->is_in_archive || contest && !db->contest_problems->find($_{contest}, $_{problem});
 247                         return reply 'Maximum source size is 10KB' if ($prog ? $prog->size : length $_{source_code}) > 10 * 1024;
 248                         return reply 'You must wait 30 seconds between jobs' if !admin && time <= remote_user->lastjob + 30;
 249                         remote_user->update({lastjob => time});
 250
 251                         my $source = $prog ? read_file $prog->path : $_{source_code};
 252                         unlink $prog->path if $prog;
 253                         my $private = (problem->private && !$_{contest}) ? 1 : 0;
 254                         $private = 1 if contest && contest->is_pending;
 255                         my $newjob = db->jobs->create({
 256                                 maybe contest => $_{contest},
 257                                 private => $private,
 258                                 date => time,
 259                                 extension => FORMAT_EXTENSION->{$_{prog_format}},
 260                                 format => $_{prog_format},
 261                                 problem => $_{problem},
 262                                 source => $source,
 263                                 owner => remote_user->id,
 264                         });
 265
 266                         purge '/log/';
 267                         [303, [Location => '/log/' . $newjob->id], []]
 268                 },
 269
 270                 sub (/action/request-reset + %:username=) {
 271                         return reply 'Password resets are disabled' unless $ENV{GRUNTMASTER_RESET_FROM};
 272                         my $user = db->user($_{username});
 273                         return reply 'No such user' unless $user;
 274                         my $token = join ':', $user->make_reset_hmac;
 275                         my $body = <<EOF;
 276 Someone has requested a password reset for your account.
 277
 278 To reset your password, please submit the reset password form on the
 279 website using the following information:
 280
 281 Username: $_{username}
 282 Password: <your new password>
 283 Reset token: $token
 284
 285 The token is valid for 24 hours.
 286 EOF
 287                         my $email = Email::Simple->create(
 288                                 header => [
 289                                         From    => $ENV{GRUNTMASTER_RESET_FROM},
 290                                         To      => $user->email,
 291                                         Subject => 'Password reset token',
 292                                 ],
 293                                 body => $body,
 294                         );
 295
 296                         my $ok = 0;
 297                         eval {
 298                                 sendmail $email;
 299                                 $ok = 1;
 300                         };
 301                         return reply 'Email sent' if $ok;
 302                         reply "Failure sending email: $@";
 303                 },
 304
 305                 sub (/action/reset + %:username=&:password=&:token=) {
 306                         my $user = db->user($_{username});
 307                         return reply 'No such user' unless $user;
 308                         my ($token, $exp) = split ':', $_{token};
 309                         return reply 'Reset token is expired' if time >= $exp;
 310                         return reply 'Bad reset token' unless $user->make_reset_hmac($exp) eq $token;
 311                         $user->set_passphrase($_{password});
 312                         reply 'Password reset successfully';
 313                 },
 314         }
 315 }
 316
 317
 318 1;
 319 __END__