lib/Plack/App/Gruntmaster.pm

   1 package Plack::App::Gruntmaster;
   2
   3 use 5.014000;
   4 use strict;
   5 our $VERSION = '5999.000_001';
   6
   7 use CSS::Minifier::XS;
   8 use Encode qw/encode decode/;
   9 use File::Slurp qw/read_file/;
  10 use JavaScript::Minifier::XS;
  11 use JSON::MaybeXS qw/encode_json/;
  12 use PerlX::Maybe;
  13 use Scope::Upper qw/unwind SUB UP/;
  14 use Web::Simple;
  15
  16 use Gruntmaster::Data;
  17 use Plack::App::Gruntmaster::HTML;
  18
  19 use warnings NONFATAL => 'all';
  20 no warnings 'illegalproto';
  21 no if $] >= 5.017011, warnings => 'experimental::smartmatch';
  22
  23 ##################################################
  24
  25 use constant USER_REGEX => qr/^\w{2,20}$/a;
  26
  27 use constant CONTENT_TYPES => +{
  28         c => 'text/x-csrc',
  29         cpp => 'text/x-c++src',
  30         cs => 'text/x-csharp', # Used by GNOME. Not in mime.types.
  31         go => 'text/plain', # ?
  32         hs => 'text/x-haskell',
  33         java => 'text/x-java',
  34         pas => 'text/x-pascal',
  35         pl => 'text/x-perl',
  36         py => 'text/x-python',
  37 };
  38
  39 use constant FORMAT_EXTENSION => {
  40         C => 'c',
  41         CPP => 'cpp',
  42         GCCGO => 'go',
  43         GOLANG => 'go',
  44         HASKELL => 'hs',
  45         MONO => 'cs',
  46         JAVA => 'java',
  47         PASCAL => 'pas',
  48         PERL => 'pl',
  49         PYTHON => 'py',
  50 };
  51
  52 use constant NOT_FOUND => [404, ['Content-Type' => 'text/plain'], ['Not found']];
  53 use constant FORBIDDEN => [401, ['Content-Type' => 'text/plain', 'WWW-Authenticate' => 'Basic realm="Gruntmaster 6000"'], ['Forbidden']];
  54
  55 sub development() { ($ENV{PLACK_ENV} // 'development') eq 'development' }
  56
  57 my ($env, $privacy);
  58
  59 sub db { $env->{'gruntmaster.dbic'} }
  60
  61 sub remote_user {
  62         my $user = $env->{'gruntmaster.user'};
  63         $user &&= db->user($user);
  64         $user
  65 }
  66
  67 sub admin   { remote_user && remote_user->admin }
  68 sub contest { db->contest ($_{contest}) }
  69 sub problem { db->problem ($_{problem}) }
  70 sub job     { db->job     ($_{job})     }
  71 sub user    { db->user    ($_{user})    }
  72
  73 sub redirect { [301, ['X-Forever' => 1, 'Location' => $_[0]], []] }
  74 sub reply    { [200, ['Content-Type' => 'text/plain'], \@_] }
  75 sub response {
  76         my ($template, $title, $params, $maxage) = @_;
  77         unless ($params) {
  78                 $params = $title;
  79                 $title = 'No title';
  80         }
  81         $params->{time} = time;
  82         $params->{args} = {%_};
  83         bless {template => $template, title => $title, params => $params, maxage => ($maxage // 1)}, __PACKAGE__.'::Response'
  84 }
  85
  86 sub forbid {
  87         my ($condition) = @_;
  88         $privacy = 'private' if $condition;
  89         return if !$condition || admin;
  90         unwind FORBIDDEN, SUB UP
  91 }
  92
  93 sub dispatch_request{
  94         $env = $_[PSGI_ENV];
  95         $privacy = 'public';
  96
  97         sub (GET) {
  98                 sub (/css/:theme) {
  99                         my $theme = $_{theme};
 100                         return NOT_FOUND unless -e "css/themes/$theme.css";
 101                         my $css = read_file "css/themes/$theme.css";
 102                         $css .= read_file $_ for <css/*.css>;
 103                         my @headers = ('X-Forever' => 1, 'Cache-Control' => 'public, max-age=604800', 'Content-Type' => 'text/css');
 104                         [200, \@headers, [development ? $css : CSS::Minifier::XS::minify $css]]
 105                 },
 106
 107                 sub (/js.js) {
 108                         my $js;
 109                         $js .= read_file $_ for <js/*.js>;
 110                         my @headers = ('X-Forever' => 1, 'Cache-Control' => 'public, max-age=604800', 'Content-Type' => 'application/javascript');
 111                         [200, \@headers, [development ? $js : JavaScript::Minifier::XS::minify $js]]
 112                 },
 113
 114                 sub (/src/:job) {
 115                         return NOT_FOUND if !job;
 116                         my $isowner = remote_user && remote_user->id eq job->rawowner;
 117                         my $private = job->private || job->problem->private || job->contest && job->contest->is_running;
 118                         forbid !$isowner && $private;
 119                         my $privacy = $private ? 'private' : 'public';
 120                         my @headers = ('X-Forever' => 1, 'Cache-Control' => "$privacy, max-age=604800", 'Content-Type' => CONTENT_TYPES->{job->format});
 121                         push @headers, (Vary => 'Authorization') if $private;
 122                         [200, \@headers, [job->source]]
 123                 },
 124
 125                 sub (?:contest=) {
 126                         return NOT_FOUND if !contest;
 127                         forbid contest->is_pending;
 128                         response_filter { return shift }
 129                 },
 130
 131                 sub (?:problem=) {
 132                         return NOT_FOUND if !problem;
 133                         forbid problem->is_private;
 134                         response_filter { return shift }
 135                 },
 136
 137                 sub (?:format~) {
 138                         my $format = lc ($_{format} // '');
 139                         response_filter {
 140                                 my ($r) = @_;
 141                                 return $r if ref $r ne 'Plack::App::Gruntmaster::Response';
 142                                 my @hdrs = ('X-Forever' => 1, 'Cache-Control' => "$privacy, max-age=$r->{maxage}");
 143                                 push @hdrs, Vary => 'Authorization' if $privacy eq 'private';
 144                                 return [200, ['Content-Type' => 'application/json', @hdrs], [encode_json $r->{params}]] if $format eq 'json';
 145                                 my $ret = render $r->{template}, 'en', title => $r->{title}, %{$r->{params}};
 146                                 [200, ['Content-Type' => 'text/html', @hdrs], [encode 'UTF-8', $ret]]
 147                         },
 148                 },
 149
 150                 sub (/st/:contest) {
 151                         response st => 'Standings', {
 152                                 st => [ contest->standings ],
 153                                 problems => [
 154                                         map { [$_->id, $_->name] }
 155                                         sort { $a->value <=> $b->value }
 156                                         map { $_->problem } contest->contest_problems],
 157                         }, 10
 158                 },
 159
 160                 sub (/ed/:contest) {
 161                         forbid contest->is_running;
 162                         response ed => 'Editorial of ' . contest->name, db->problem_list(contest => $_{contest}, solution => 1);
 163                 },
 164
 165                 sub (/login) {
 166                         forbid !remote_user;
 167
 168                         my $return = $env->{HTTP_REFERER} // '/';
 169                         [303, ['Set-Cookie' => "username=".remote_user->id, Location => $return], []]
 170                 },
 171
 172                 sub (/ct/:contest/log/st) { redirect "/st/$_{contest}" },
 173
 174                 sub (/us/)                                        { response us => 'Users', {us => db->user_list} },
 175                 sub (/ct/  + ?:owner~)                            { response ct => 'Contests', db->contest_list(%_) },
 176                 sub (/log/ + ?:contest~&:owner~&:page~&:problem~&:private~) {
 177                         forbid $_{private};
 178                         response log => 'Job list', {%{db->job_list(%_)}, maybe contest => $_{contest},}
 179                 },
 180                 sub (/pb/  + ?:owner~&:contest~&:private~)                  {
 181                         forbid $_{private};
 182                         response pb => 'Problems', {%{db->problem_list(%_)}, maybe contest => $_{contest}}
 183                 },
 184
 185                 sub (/us/:user)    { response us_entry => user->name, db->user_entry($_{user}) },
 186                 sub (/ct/:contest) { response ct_entry => contest->name, db->contest_entry($_{contest}) },
 187                 sub (/log/:job)    {
 188                         forbid job->private;
 189                         response log_entry => "Job  $_{job}", db->job_entry($_{job})
 190                 },
 191                 sub (/pb/:problem + ?contest~) {
 192                         my (undef, undef, $contest) = @_;
 193                         $_{contest} = $contest;
 194                         return NOT_FOUND if !contest && !problem->is_in_archive || contest && !db->contest_problems->find($_{contest}, $_{problem});
 195                         forbid problem->is_private;
 196                         if (contest && contest->is_running) {
 197                                 forbid !remote_user;
 198                                 $privacy = 'private';
 199                         }
 200                         response pb_entry => problem->name, {%{db->problem_entry($_{problem}, $_{contest}, remote_user && remote_user->id)}, maybe contest => $_{contest}};
 201                 },
 202                 sub (/sol/:problem) {
 203                         forbid !problem->is_in_archive;
 204                         response sol => 'Solution of ' . problem->name, {solution => db->problem($_{problem})->solution};
 205                 },
 206
 207                 sub (/) { redispatch_to '/index' },
 208                 sub (/favicon.ico) { redirect '/static/favicon.ico' },
 209                 sub (/:article) { [200, ['Content-Type' => 'text/html', 'Cache-Control' => 'public, max-age=60', 'X-Forever' => 1], [render_article $_{article}, 'en']] }
 210         },
 211
 212         sub (POST) {
 213                 sub (/action/register + %:username=&:password=&:confirm_password=&:name=&:email=&:phone=&:town=&:university=&:country=&:level=) {
 214                         return reply 'Parameter too long' if grep { length > 200 } values %_;
 215                         return reply 'Bad username. Allowed characters are letters, digits and underscores, and the username must be between 2 and 20 characters long.' unless $_{username} =~ USER_REGEX;
 216                         return reply 'Username already in use' if db->user($_{username});
 217                         return reply 'The two passwords do not match' unless $_{password} eq $_{confirm_password};
 218
 219                         db->users->create({id => $_{username}, name => $_{name}, email => $_{email}, phone => $_{phone}, town => $_{town}, university => $_{university}, country => $_{country}, level => $_{level}});
 220                         db->user($_{username})->set_passphrase($_{password});
 221
 222                         purge '/us/';
 223                         reply 'Registered successfully';
 224                 },
 225
 226                 sub (/action/passwd + %:password=&:new_password=&:confirm_new_password=) {
 227                         forbid !remote_user;
 228                         return reply 'Incorrect password' unless remote_user->check_passphrase($_{password});
 229                         return reply 'The two passwords do not match' unless $_{new_password} eq $_{confirm_new_password};
 230                         remote_user->set_passphrase($_{new_password});
 231                         reply 'Password changed successfully';
 232                 },
 233
 234                 sub (/action/submit + %:problem=&:contest~&:prog_format=&:source_code~ + *prog~) {
 235                         my (undef, undef, $prog) = @_;
 236                         forbid !remote_user;
 237                         return reply 'This contest has finished' if contest && contest->is_finished;
 238                         return reply 'This contest has not yet started' if !admin && contest && contest->is_pending;
 239                         return reply 'This problem does not belong to this contest' if !contest && !problem->is_in_archive || contest && !db->contest_problems->find($_{contest}, $_{problem});
 240                         return reply 'Maximum source size is 10KB' if ($prog ? $prog->size : length $_{source_code}) > 10 * 1024;
 241                         return reply 'You must wait 30 seconds between jobs' if !admin && time <= remote_user->lastjob + 30;
 242                         remote_user->update({lastjob => time});
 243
 244                         my $source = $prog ? read_file $prog->path : $_{source_code};
 245                         unlink $prog->path if $prog;
 246                         my $private = (problem->private && !$_{contest}) ? 1 : 0;
 247                         $private = 1 if contest->is_pending;
 248                         my $newjob = db->jobs->create({
 249                                 maybe contest => $_{contest},
 250                                 private => $private,
 251                                 date => time,
 252                                 extension => FORMAT_EXTENSION->{$_{prog_format}},
 253                                 format => $_{prog_format},
 254                                 problem => $_{problem},
 255                                 source => $source,
 256                                 owner => remote_user->id,
 257                         });
 258
 259                         purge '/log/';
 260                         [303, [Location => '/log/' . $newjob->id], []]
 261                 }
 262         }
 263 }
 264
 265
 266 1;
 267 __END__