lib/Plack/App/Gruntmaster/HTML.pm

   1 package Plack::App::Gruntmaster::HTML;
   2 use v5.14;
   3 use parent qw/Exporter/;
   4 our @EXPORT = qw/render render_article/;
   5
   6 use File::Slurp qw/read_file/;
   7 use HTML::Element::Library;
   8 use HTML::TreeBuilder;
   9 use POSIX qw//;
  10 use Data::Dumper qw/Dumper/;
  11
  12 my $optional_end_tags = {%HTML::Tagset::optionalEndTag, tr => 1, td => 1, th => 1};
  13
  14 sub ftime ($)   { POSIX::strftime '%c', localtime shift }
  15 sub literal ($) {
  16         my ($html) = @_;
  17         return '' unless $html;
  18         my $b = HTML::TreeBuilder->new;
  19         $b->ignore_unknown(0);
  20         $b->parse($html);
  21         HTML::Element::Library::super_literal $b->guts->as_HTML(undef, undef, $optional_end_tags);
  22 }
  23
  24 sub HTML::Element::edit_href {
  25         my ($self, $sub) = @_;
  26         local $_ = $self->attr('href');
  27         $sub->();
  28         $self->attr(href => $_);
  29 }
  30
  31 sub HTML::Element::iter3 {
  32         my ($self, $data, $code) = @_;
  33         my $orig = $self;
  34         my $prev = $orig;
  35         for my $el (@$data) {
  36                 my $current = $orig->clone;
  37                 $code->($el, $current);
  38                 $prev->postinsert($current);
  39                 $prev = $current;
  40         }
  41         $orig->detach;
  42 }
  43
  44 sub HTML::Element::fid    { shift->look_down(id    => shift) }
  45 sub HTML::Element::fclass { shift->look_down(class => qr/\b$_[0]\b/) }
  46
  47 sub HTML::Element::namedlink {
  48         my ($self, $id, $name) = @_;
  49         $name = $id unless $name =~ /[[:graph:]]/;
  50         $self = $self->find('a');
  51         $self->edit_href(sub {s/id/$id/});
  52         $self->replace_content($name);
  53 }
  54
  55 my %page_cache;
  56 for (<tmpl/*>) {
  57         my ($tmpl, $lang) = m,tmpl/(\w+)\.(\w+),;
  58         my $builder = HTML::TreeBuilder->new;
  59         $builder->ignore_unknown(0);
  60         $page_cache{$tmpl, $lang} = $builder->parse_file($_);
  61 }
  62
  63 sub render {
  64         my ($tmpl, $lang, %args) = @_;
  65         $lang //= 'en';
  66         my $meat = _render($tmpl, $lang, %args);
  67         my $html = _render('skel', $lang, %args, meat => $meat);
  68         if ($tmpl eq 'pb_entry') { # Move sidebar to correct position
  69                 my $builder = HTML::TreeBuilder->new;
  70                 $builder->ignore_unknown(0);
  71                 my $tree = $builder->parse_content($html);
  72                 $tree->fid('content')->postinsert($tree->fid('sidebar'));
  73                 $html = $tree->as_HTML(undef, undef, $optional_end_tags)
  74         }
  75         $html
  76 }
  77
  78 sub render_article {
  79         my ($art, $lang, %args) = @_;
  80         $lang //= 'en';
  81         my $title = read_file "a/$art.$lang.title";
  82         chomp $title;
  83         my $meat  = read_file "a/$art.$lang";
  84         _render('skel', $lang, title => $title , meat => $meat, %args)
  85 }
  86
  87 sub _render {
  88         my ($tmpl, $lang, %args) = @_;
  89         my $tree = $page_cache{$tmpl, $lang}->clone or die "No such template/language combination: $tmpl/$lang\n";
  90         $tree = $tree->guts unless $tmpl eq 'skel';
  91         $tree->defmap(smap => \%args);
  92         my $process = __PACKAGE__->can("process_$tmpl");
  93         $process->($tree, %args) if $process;
  94         $_->attr('smap', undef) for $tree->look_down(sub {$_[0]->attr('smap')});
  95         $tree->as_HTML(undef, undef, $optional_end_tags);
  96 }
  97
  98 sub process_skel {
  99         my ($tree, %args) = @_;
 100         $tree->content_handler(
 101                 title   =>         $args{title},
 102                 content => literal $args{meat});
 103 }
 104
 105 sub process_us_entry {
 106         my ($tree, %args) = @_;
 107         $tree->fid($_)->attr('href', "/$_/?owner=$args{id}") for qw/log pb/;
 108         $tree->fid('track_user')->attr('data-user', $args{id});
 109         my @solved = map { $_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
 110         my @attempted = map { !$_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
 111
 112         my $pbiter = sub {
 113                 my ($data, $li) = @_;
 114                 $li->find('a')->namedlink($data);
 115         };
 116         $tree->fid('solved')->find('li')->iter3(\@solved, $pbiter);
 117         $tree->fid('attempted')->find('li')->iter3(\@attempted, $pbiter);
 118         $tree->fid('solved_count')->replace_content(scalar @solved);
 119         $tree->fid('attempted_count')->replace_content(scalar @attempted);
 120
 121         my $ctiter = sub {
 122                 my ($data, $td) = @_;
 123                 $td->fclass('contest')->namedlink($data->{contest}, $data->{contest_name});
 124                 $td->fclass('score')->replace_content($data->{score});
 125                 $td->fclass('rank')->replace_content($data->{rank});
 126         };
 127         $tree->find('table')->find('tbody')->find('tr')->iter3($args{contests}, $ctiter);
 128 }
 129
 130 sub process_us {
 131         my ($tree, %args) = @_;
 132         my $iter = sub {
 133                 my ($data, $tr) = @_;
 134                 $tr->fclass('user')->namedlink($data->{id}, $data->{name});
 135                 $tr->fclass($_)->replace_content($data->{$_}) for qw/solved attempted contests/;
 136         };
 137         $tree->find('tbody')->find('tr')->iter3($args{us}, $iter);
 138 }
 139
 140 sub process_ct_entry {
 141         my ($tree, %args) = @_;
 142         $_->edit_href (sub {s/contest_id/$args{id}/}) for $tree->find('a');
 143         $tree->fid('editorial')->detach unless $args{finished};
 144         $tree->fid('links')->detach unless $args{started};
 145         my $status = ($args{time} < $args{start} ? 'starts' : 'ends');
 146         $tree->fclass('timer')->attr('data-stop', $status eq 'ends' ? $args{stop} : $args{start});
 147         $tree->content_handler(
 148                 start       => ftime   $args{start},
 149                 stop        => ftime   $args{stop},
 150                 status      => $status,
 151                 description => literal $args{description});
 152         $tree->fid('ctcountdown')->detach if $args{time} >= $args{stop};
 153 }
 154
 155 sub process_ct {
 156         my ($tree, %args) = @_;
 157         my $iter = sub {
 158                 my ($data, $tr) = @_;
 159                 $data->{$_} = ftime $data->{$_} for qw/start stop/;
 160                 $tr->hashmap(class => $data, [qw/name owner/]);
 161                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 162                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 163         };
 164         for (@{$args{ct}}) {
 165                 my $state = $_->{finished} ? 'finished' : $_->{started} ? 'running' : 'pending';
 166                 push @{$args{$state} //= []}, $_;
 167         }
 168         $args{$_} ? $tree->fid($_)->find('tbody')->find('tr')->iter3($args{$_}, $iter) : $tree->fid($_)->detach for qw/running pending finished/;
 169 }
 170
 171 sub process_pb_entry {
 172         my ($tree, %args) = @_;
 173         $tree->fid('owner')->edit_href(sub{s/owner_id/$args{owner}/});
 174         $tree->fid('job_log')->edit_href(sub{s/problem_id/$args{id}/});
 175         $tree->fid('solution')->edit_href(sub{s/problem_id/$args{id}/});
 176         $tree->content_handler(
 177                 statement => literal $args{statement},
 178                 level     => ucfirst $args{level},
 179                 author    =>         $args{author},
 180                 owner     =>         $args{owner_name} || $args{owner});
 181         if ($args{limits}) {
 182                 my @limits = (@{$args{limits}}, {format => 'Other', timeout => $args{timeout} });
 183                 @limits = map { sprintf '%s (%s)', @{$_}{qw/timeout format/} } @limits;
 184                 $tree->look_down(smap => 'timeout')->replace_content(join ', ', @limits);
 185         }
 186         if ($args{contest_stop}) {
 187                 $tree->fid('solution')->detach;
 188                 $tree->fid('solution_modal')->detach;
 189                 my $score = $tree->fid('score');
 190                 $score->attr('data-start' => $args{open_time});
 191                 $score->attr('data-stop'  => $args{contest_stop});
 192                 $score->attr('data-value'  => $args{value});
 193                 $tree->fid('countdown')->attr('data-stop' => $args{contest_stop});
 194         } else {
 195                 $tree->fid('job_log')->edit_href(sub{$_ .= "&private=$args{private}"}) if $args{private};
 196                 $tree->fid('solution')->detach unless $args{solution};
 197                 $_->detach for $tree->fclass('rc'); # requires contest
 198                 $tree->fid('solution_modal')->replace_content(literal $args{solution});
 199         }
 200
 201         $tree->look_down(name => 'problem')->attr(value => $args{id});
 202         my $contest = $tree->look_down(name => 'contest');
 203         $contest->attr(value => $args{args}{contest}) if $args{args}{contest};
 204         $contest->detach unless $args{args}{contest}
 205 }
 206
 207 sub process_sol {
 208         my ($tree, %args) = @_;
 209         $tree->content_handler(solution => literal $args{solution});
 210 }
 211
 212 sub process_pb {
 213         my ($tree, %args) = @_;
 214         my $titer = sub {
 215                 my ($data, $tr) = @_;
 216                 $tr->set_child_content(class => 'author', $data->{author});
 217                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 218                 $tr->fclass('name')->find('a')->edit_href(sub {$_ .= "?contest=$args{contest}"}) if $args{contest};
 219                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 220                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private} && !$args{contest};
 221         };
 222         my $iter = sub {
 223                 my ($data, $div) = @_;
 224                 $div->attr(id => $data);
 225                 $div->find('h2')->replace_content(ucfirst $data);
 226                 $div->find('tbody')->find('tr')->iter3($args{$data}, $titer);
 227         };
 228         push @{$args{$_->{level}} //= []}, $_ for @{$args{pb}};
 229         $tree->fid('beginner')->iter3([grep {$args{$_}} qw/beginner easy medium hard/], $iter);
 230         $tree->fid('open-alert')->detach unless $args{contest};
 231 }
 232
 233 sub process_log_entry {
 234         my ($tree, %args) = @_;
 235         $tree->fid('problem')->namedlink(@args{qw/problem problem_name/});
 236         $tree->fid('owner')->namedlink(@args{qw/owner owner_name/});
 237         $tree->fid('source')->namedlink("$args{id}.$args{extension}", sprintf '%.2fKB', $args{size}/1024);
 238         if ($args{contest}) {
 239                 $tree->fid('contest')->namedlink(@args{qw/contest contest_name/});
 240                 $tree->fid('problem')->find('a')->edit_href(sub {$_.="?contest=$args{contest}"});
 241         } else {
 242                 $tree->fid('contest')->left->detach;
 243                 $tree->fid('contest')->detach;
 244         }
 245
 246         $args{errors} ? $tree->fid('errors')->find('pre')->replace_content($args{errors}) : $tree->fid('errors')->detach;
 247         my $iter = sub {
 248                 my ($data, $tr) = @_;
 249                 $data->{time} = sprintf '%.4fs', $data->{time};
 250                 $tr->defmap(class => $data);
 251                 $tr->fclass('result_text')->attr(class => "r$data->{result}")
 252         };
 253         $tree->fclass('result_text')->replace_content($args{result_text});
 254         $tree->fclass('result_text')->attr(class => "r$args{result}");
 255         $args{results} ? $tree->fid('results')->find('tbody')->find('tr')->iter3($args{results}, $iter) : $tree->fid('results')->detach;
 256         $tree->fid('no_results')->detach if $tree->fid('results') || $tree->fid('errors');
 257 }
 258
 259 sub process_log {
 260         my ($tree, %args) = @_;
 261         my $iter = sub {
 262                 my ($data, $tr) = @_;
 263                 $tr->fclass('id')->namedlink($data->{id});
 264                 $tr->fclass('problem')->namedlink($data->{problem}, $data->{problem_name});
 265                 $tr->fclass('problem')->find('a')->edit_href(sub{$_ .= "?contest=$args{args}{contest}"}) if $args{args}{contest};
 266                 $tr->fclass('contest')->namedlink($data->{contest}, $data->{contest_name}) if $data->{contest};
 267                 $tr->fclass('contest')->replace_content('None') unless $data->{contest};
 268                 $tr->fclass('date')->replace_content(ftime $data->{date});
 269                 $tr->fclass('source')->namedlink("$data->{id}.$data->{extension}", sprintf "%.2fKB %s", $data->{size}/1024, Plack::App::Gruntmaster::FORMAT_EXTENSION()->{$data->{format}});
 270                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 271                 $tr->fclass('result_text')->replace_content($data->{result_text});
 272                 $tr->fclass('result_text')->attr(class => "r$data->{result}");
 273                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private};
 274         };
 275         $tree->find('table')->find('tbody')->find('tr')->iter3($args{log}, $iter);
 276         $args{next_page} ? $tree->fclass('next')->namedlink($args{next_page}, 'Next') : $tree->fclass('next')->detach;
 277         $args{previous_page} ? $tree->fclass('previous')->namedlink($args{previous_page}, 'Previous') : $tree->fclass('previous')->detach;
 278         for my $cls (qw/next previous/) {
 279                 my $elem = $tree->fclass($cls);
 280                 next unless $elem;
 281                 delete $args{args}{page};
 282                 my $str = join '&', map { $_ . '=' . $args{args}{$_} } keys %{$args{args}};
 283                 $elem->find('a')->edit_href(sub{s/$/&$str/}) if $str;
 284         }
 285         $tree->fclass('current')->replace_content("Page $args{current_page} of $args{last_page}");
 286 }
 287
 288 sub process_st {
 289         my ($tree, %args) = @_;
 290         $args{problems} //= [];
 291         my $pbiter = sub {
 292                 my ($data, $th) = @_;
 293                 $th->attr(class => undef);
 294                 $th->namedlink(@$data);
 295                 $th->find('a')->edit_href(sub{s/$/?contest=$args{args}{contest}/});
 296         };
 297         $tree->fclass('problem')->iter3($args{problems}, $pbiter);
 298         my $iter = sub {
 299                 my ($st, $tr) = @_;
 300                 $tr->set_child_content(class => 'rank', $st->{rank});
 301                 $tr->set_child_content(class => 'score', $st->{score});
 302                 $tr->fclass('user')->namedlink($st->{user}, $st->{user_name});
 303                 my $pbscore = $tr->fclass('pbscore');
 304                 $pbscore->iter($pbscore => @{$st->{scores}});
 305         };
 306         $tree->find('tbody')->find('tr')->iter3($args{st}, $iter);
 307 }
 308
 309 sub process_ed {
 310         my ($tree, %args) = @_;
 311         $tree->content_handler(editorial => literal $args{editorial});
 312         my $iter = sub {
 313                 my ($data, $div) = @_;
 314                 $div->set_child_content(class => 'value', $data->{value});
 315                 $div->set_child_content(class => 'solution', literal $data->{solution});
 316                 $div->fclass('problem')->namedlink($data->{id}, $data->{name});
 317         };
 318         my @pb = sort { $a->{value} <=> $b->{value} } @{$args{pb}};
 319         $tree->fclass('well')->iter3(\@pb, $iter);
 320 }
 321
 322 1;
 323 __END__