lib/Plack/App/Gruntmaster/HTML.pm

   1 package Plack::App::Gruntmaster::HTML;
   2 use v5.14;
   3 use parent qw/Exporter/;
   4 our @EXPORT = qw/render render_article/;
   5
   6 use File::Slurp qw/read_file/;
   7 use HTML::Seamstress;
   8 use POSIX qw//;
   9 use Data::Dumper qw/Dumper/;
  10
  11 sub ftime ($)   { POSIX::strftime '%c', localtime shift }
  12 sub literal ($) { HTML::Element::Library::super_literal shift // '' }
  13
  14 sub HTML::Element::edit_href {
  15         my ($self, $sub) = @_;
  16         local $_ = $self->attr('href');
  17         $sub->();
  18         $self->attr(href => $_);
  19 }
  20
  21 sub HTML::Element::iter3 {
  22         my ($self, $data, $code) = @_;
  23         my $orig = $self;
  24         my $prev = $orig;
  25         for my $el (@$data) {
  26                 my $current = $orig->clone;
  27                 $code->($el, $current);
  28                 $prev->postinsert($current);
  29                 $prev = $current;
  30         }
  31         $orig->detach;
  32 }
  33
  34 sub HTML::Element::fid    { shift->look_down(id    => shift) }
  35 sub HTML::Element::fclass { shift->look_down(class => qr/\b$_[0]\b/) }
  36
  37 sub HTML::Element::namedlink {
  38         my ($self, $id, $name) = @_;
  39         $name = $id unless $name =~ /[[:graph:]]/;
  40         $self = $self->find('a');
  41         $self->edit_href(sub {s/id/$id/});
  42         $self->replace_content($name);
  43 }
  44
  45 sub render {
  46         my ($tmpl, $lang, %args) = @_;
  47         $lang //= 'en';
  48         my $meat = _render($tmpl, $lang, %args);
  49         _render('skel', $lang, %args, meat => $meat)
  50 }
  51
  52 sub render_article {
  53         my ($art, $lang) = @_;
  54         $lang //= 'en';
  55         my $title = read_file "a/$art.$lang.title";
  56         my $meat  = read_file "a/$art.$lang";
  57         _render('skel', $lang, title => $title , meat => $meat)
  58 }
  59
  60 sub _render {
  61         my ($tmpl, $lang, %args) = @_;
  62         my $builder = HTML::Seamstress->new;
  63         $builder->ignore_unknown(0);
  64         my $tree = $builder->parse_file("tmpl/$tmpl.$lang");
  65         $tree = $tree->guts unless $tmpl eq 'skel';
  66         $tree->defmap(smap => \%args);
  67         my $process = __PACKAGE__->can("process_$tmpl");
  68         $process->($tree, %args) if $process;
  69         $tree->as_HTML;
  70 }
  71
  72 sub process_skel {
  73         my ($tree, %args) = @_;
  74         $tree->content_handler(
  75                 title   =>         $args{title},
  76                 content => literal $args{meat});
  77 }
  78
  79 sub process_us_entry {
  80         my ($tree, %args) = @_;
  81         $tree->fid($_)->attr('href', "/$_/?owner=$args{id}") for qw/log pb/;
  82         $tree->fid('track_user')->attr('data-user', $args{id});
  83         my @solved = map { $_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
  84         my @attempted = map { !$_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
  85
  86         my $pbiter = sub {
  87                 my ($data, $li) = @_;
  88                 $li->find('a')->namedlink($data);
  89         };
  90         $tree->fid('solved')->find('li')->iter3(\@solved, $pbiter);
  91         $tree->fid('attempted')->find('li')->iter3(\@attempted, $pbiter);
  92         $tree->fid('solved_count')->replace_content(scalar @solved);
  93         $tree->fid('attempted_count')->replace_content(scalar @attempted);
  94
  95         my $ctiter = sub {
  96                 my ($data, $td) = @_;
  97                 $td->fclass('contest')->namedlink($data->{contest}, $data->{contest_name});
  98                 $td->fclass('score')->replace_content($data->{score});
  99                 $td->fclass('rank')->replace_content($data->{rank});
 100         };
 101         $tree->find('table')->find('tbody')->find('tr')->iter3($args{contests}, $ctiter);
 102 }
 103
 104 sub process_us {
 105         my ($tree, %args) = @_;
 106         my $iter = sub {
 107                 my ($data, $tr) = @_;
 108                 $tr->fclass('user')->namedlink($data->{id}, $data->{name});
 109                 $tr->fclass($_)->replace_content($data->{$_}) for qw/solved attempted contests/;
 110         };
 111         $tree->find('tbody')->find('tr')->iter3($args{us}, $iter);
 112 }
 113
 114 sub process_ct_entry {
 115         my ($tree, %args) = @_;
 116         $_->edit_href (sub {s/contest_id/$args{id}/}) for $tree->find('a');
 117         $tree->fid('editorial')->detach unless $args{finished};
 118         $tree->fid('links')->detach unless $args{started};
 119         my $status = ($args{time} < $args{start} ? 'starts' : 'ends');
 120         $tree->fclass('timer')->attr('data-stop', $status eq 'ends' ? $args{stop} : $args{start});
 121         $tree->content_handler(
 122                 start       => ftime   $args{start},
 123                 stop        => ftime   $args{stop},
 124                 status      => $status,
 125                 description => literal $args{description});
 126         $tree->fid('ctcountdown')->detach if $args{time} >= $args{stop};
 127 }
 128
 129 sub process_ct {
 130         my ($tree, %args) = @_;
 131         my $iter = sub {
 132                 my ($data, $tr) = @_;
 133                 $data->{$_} = ftime $data->{$_} for qw/start stop/;
 134                 $tr->hashmap(class => $data, [qw/name owner/]);
 135                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 136                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 137         };
 138         $args{$_} ? $tree->fid($_)->find('tbody')->find('tr')->iter3($args{$_}, $iter) : $tree->fid($_)->detach for qw/running pending finished/;
 139 }
 140
 141 sub process_pb_entry {
 142         my ($tree, %args) = @_;
 143         $tree->fid('owner')->edit_href(sub{s/owner_id/$args{owner}/});
 144         $tree->fid('job_log')->edit_href(sub{s/problem_id/$args{id}/});
 145         $tree->fid('solution')->edit_href(sub{s/problem_id/$args{id}/});
 146         $tree->fid('job_log')->edit_href(sub{$_ .= "&private=$args{private}"}) if $args{private};
 147         $tree->content_handler(
 148                 statement => literal $args{statement},
 149                 level     => ucfirst $args{level},
 150                 author    =>         $args{author},
 151                 owner     =>         $args{owner_name} || $args{owner});
 152         if ($args{contest_stop}) {
 153                 $tree->fid('solution')->detach;
 154                 $tree->fid('solution_modal')->detach;
 155                 my $score = $tree->fid('score');
 156                 $score->attr('data-start' => $args{open_time});
 157                 $score->attr('data-stop'  => $args{contest_stop});
 158                 $score->attr('data-value'  => $args{value});
 159                 $tree->fid('countdown')->attr('data-stop' => $args{contest_stop});
 160         } else {
 161                 $tree->fid('solution')->detach unless $args{solution};
 162                 $_->detach for $tree->fclass('rc'); # requires contest
 163                 $tree->fid('solution_modal')->fclass('modal-body')->replace_content(literal $args{solution});
 164         }
 165         if ($args{cansubmit}) {
 166                 $tree->fid('nosubmit')->detach;
 167                 $tree->look_down(name => 'problem')->attr(value => $args{id});
 168                 my $contest = $tree->look_down(name => 'contest');
 169                 $contest->attr(value => $args{contest}) if $args{contest};
 170                 $contest->detach unless $args{contest}
 171         } else {
 172                 $tree->fid('nosubmit')->find('a')->edit_href(sub{s/id/$args{id}/});
 173                 $tree->fid('submit')->detach
 174         }
 175 }
 176
 177 sub process_sol {
 178         my ($tree, %args) = @_;
 179         $tree->content_handler(solution => literal $args{solution});
 180 }
 181
 182 sub process_pb {
 183         my ($tree, %args) = @_;
 184         my $titer = sub {
 185                 my ($data, $tr) = @_;
 186                 $tr->set_child_content(class => 'author', $data->{author});
 187                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 188                 $tr->fclass('name')->find('a')->edit_href(sub {$_ .= "?contest=$args{contest}"}) if $args{contest};
 189                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 190                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private} && !$args{contest};
 191         };
 192         my $iter = sub {
 193                 my ($data, $div) = @_;
 194                 $div->attr(id => $data);
 195                 $div->find('h2')->replace_content(ucfirst $data);
 196                 $div->find('tbody')->find('tr')->iter3($args{$data}, $titer);
 197         };
 198         $tree->fid('beginner')->iter3([grep {$args{$_}} qw/beginner easy medium hard/], $iter);
 199         $tree->fid('open-alert')->detach unless $args{contest};
 200 }
 201
 202 sub process_log_entry {
 203         my ($tree, %args) = @_;
 204         $tree->fid('problem')->namedlink(@args{qw/problem problem_name/});
 205         $tree->fid('owner')->namedlink(@args{qw/owner owner_name/});
 206         $tree->fid('source')->namedlink("$args{id}.$args{extension}", sprintf '%.2fKB', $args{size}/1024);
 207         if ($args{contest}) {
 208                 $tree->fid('contest')->namedlink(@args{qw/contest contest_name/});
 209                 $tree->fid('problem')->find('a')->edit_href(sub {$_.="?contest=$args{contest}"});
 210         } else {
 211                 $tree->fid('contest')->left->detach;
 212                 $tree->fid('contest')->detach;
 213         }
 214
 215         $args{errors} ? $tree->fid('errors')->find('pre')->replace_content($args{errors}) : $tree->fid('errors')->detach;
 216         my $iter = sub {
 217                 my ($data, $tr) = @_;
 218                 $data->{time} = sprintf '%.4fs', $data->{time};
 219                 $tr->defmap(class => $data);
 220                 $tr->fclass('result_text')->attr(class => "r$data->{result}")
 221         };
 222         $tree->fclass('result_text')->replace_content($args{result_text});
 223         $tree->fclass('result_text')->attr(class => "r$args{result}");
 224         $args{results} ? $tree->fid('results')->find('tbody')->find('tr')->iter3($args{results}, $iter) : $tree->fid('results')->detach;
 225         $tree->fid('no_results')->detach if $tree->fid('results') || $tree->fid('errors');
 226 }
 227
 228 sub process_log {
 229         my ($tree, %args) = @_;
 230         my $iter = sub {
 231                 my ($data, $tr) = @_;
 232                 $tr->fclass('id')->namedlink($data->{id});
 233                 $tr->fclass('problem')->namedlink($data->{problem}, $data->{problem_name});
 234                 $tr->fclass('problem')->find('a')->edit_href(sub{$_ .= "?contest=$args{contest}"}) if $args{contest};
 235                 $tr->fclass('contest')->namedlink($data->{contest}, $data->{contest_name}) if $data->{contest};
 236                 $tr->fclass('contest')->replace_content('None') unless $data->{contest};
 237                 $tr->fclass('date')->replace_content(ftime $data->{date});
 238                 $tr->fclass('source')->namedlink("$data->{id}.$data->{extension}", sprintf "%.2fKB %s", $data->{size}/1024, $data->{format});
 239                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 240                 $tr->fclass('result_text')->replace_content($data->{result_text});
 241                 $tr->fclass('result_text')->attr(class => "r$data->{result}");
 242                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private};
 243         };
 244         $tree->find('table')->find('tbody')->find('tr')->iter3($args{log}, $iter);
 245         $args{next_page} ? $tree->fclass('next')->namedlink($args{next_page}, 'Next') : $tree->fclass('next')->detach;
 246         $args{previous_page} ? $tree->fclass('previous')->namedlink($args{previous_page}, 'Previous') : $tree->fclass('previous')->detach;
 247         for my $cls (qw/next previous/) {
 248                 my $elem = $tree->fclass($cls);
 249                 next unless $elem;
 250                 delete $args{args}{page};
 251                 my $str = join '&', map { $_ . '=' . $args{args}{$_} } keys %{$args{args}};
 252                 $elem->find('a')->edit_href(sub{s/$/&$str/}) if $str;
 253         }
 254         $tree->fclass('current')->replace_content("Page $args{current_page} of $args{last_page}");
 255 }
 256
 257 sub process_st {
 258         my ($tree, %args) = @_;
 259         $args{problems} //= [];
 260         my $pbiter = sub {
 261                 my ($data, $th) = @_;
 262                 $th->attr(class => undef);
 263                 $th->namedlink(@$data);
 264                 $th->find('a')->edit_href(sub{s/$/?contest=$args{args}{contest}/});
 265         };
 266         $tree->fclass('problem')->iter3($args{problems}, $pbiter);
 267         my $iter = sub {
 268                 my ($st, $tr) = @_;
 269                 $tr->set_child_content(class => 'rank', $st->{rank});
 270                 $tr->set_child_content(class => 'score', $st->{score});
 271                 $tr->fclass('user')->namedlink($st->{user}, $st->{user_name});
 272                 my $pbscore = $tr->fclass('pbscore');
 273                 $pbscore->iter($pbscore => @{$st->{scores}});
 274         };
 275         $tree->find('tbody')->find('tr')->iter3($args{st}, $iter);
 276 }
 277
 278 sub process_ed {
 279         my ($tree, %args) = @_;
 280         $tree->content_handler(editorial => literal $args{editorial});
 281         my $iter = sub {
 282                 my ($data, $div) = @_;
 283                 $div->set_child_content(class => 'value', $data->{value});
 284                 $div->set_child_content(class => 'solution', literal $data->{solution});
 285                 $div->fclass('problem')->namedlink($data->{id}, $data->{name});
 286         };
 287         my @pb = map { @{$args{$_} // []} } qw/beginner easy medium hard/;
 288         $tree->fclass('well')->iter3(\@pb, $iter);
 289 }