lib/Plack/App/Gruntmaster/HTML.pm

   1 package Plack::App::Gruntmaster::HTML;
   2 use v5.14;
   3 use parent qw/Exporter/;
   4 our @EXPORT = qw/render render_article/;
   5
   6 use File::Slurp qw/read_file/;
   7 use HTML::Seamstress;
   8 use POSIX qw//;
   9 use Data::Dumper qw/Dumper/;
  10
  11 sub ftime ($)   { POSIX::strftime '%c', localtime shift }
  12 sub literal ($) { HTML::Element::Library::super_literal shift // '' }
  13
  14 sub HTML::Element::edit_href {
  15         my ($self, $sub) = @_;
  16         local $_ = $self->attr('href');
  17         $sub->();
  18         $self->attr(href => $_);
  19 }
  20
  21 sub HTML::Element::iter3 {
  22         my ($self, $data, $code) = @_;
  23         my $orig = $self;
  24         my $prev = $orig;
  25         for my $el (@$data) {
  26                 my $current = $orig->clone;
  27                 $code->($el, $current);
  28                 $prev->postinsert($current);
  29                 $prev = $current;
  30         }
  31         $orig->detach;
  32 }
  33
  34 sub HTML::Element::fid    { shift->look_down(id    => shift) }
  35 sub HTML::Element::fclass { shift->look_down(class => qr/\b$_[0]\b/) }
  36
  37 sub HTML::Element::namedlink {
  38         my ($self, $id, $name) = @_;
  39         $name = $id unless $name =~ /[[:graph:]]/;
  40         $self = $self->find('a');
  41         $self->edit_href(sub {s/id/$id/});
  42         $self->replace_content($name);
  43 }
  44
  45 my %page_cache;
  46 for (<tmpl/*>) {
  47         my ($tmpl, $lang) = m,tmpl/(\w+)\.(\w+),;
  48         my $builder = HTML::Seamstress->new;
  49         $builder->ignore_unknown(0);
  50         $page_cache{$tmpl, $lang} = $builder->parse_file($_);
  51 }
  52
  53 sub render {
  54         my ($tmpl, $lang, %args) = @_;
  55         $lang //= 'en';
  56         my $meat = _render($tmpl, $lang, %args);
  57         _render('skel', $lang, %args, meat => $meat)
  58 }
  59
  60 sub render_article {
  61         my ($art, $lang, %args) = @_;
  62         $lang //= 'en';
  63         my $title = read_file "a/$art.$lang.title";
  64         my $meat  = read_file "a/$art.$lang";
  65         _render('skel', $lang, title => $title , meat => $meat, %args)
  66 }
  67
  68 sub _render {
  69         my ($tmpl, $lang, %args) = @_;
  70         my $tree = $page_cache{$tmpl, $lang}->clone or die "No such template/language combination: $tmpl/$lang\n";
  71         $tree = $tree->guts unless $tmpl eq 'skel';
  72         $tree->defmap(smap => \%args);
  73         my $process = __PACKAGE__->can("process_$tmpl");
  74         $process->($tree, %args) if $process;
  75         $_->detach for $tree->look_down(static => $args{static} ? 'no' : 'yes');
  76         $_->attr('static', undef) for $tree->look_down(sub {$_[0]->attr('static')});
  77         $_->attr('smap', undef) for $tree->look_down(sub {$_[0]->attr('defmap')});
  78         $tree->as_HTML;
  79 }
  80
  81 sub process_skel {
  82         my ($tree, %args) = @_;
  83         $tree->content_handler(
  84                 title   =>         $args{title},
  85                 content => literal $args{meat});
  86 }
  87
  88 sub process_us_entry {
  89         my ($tree, %args) = @_;
  90         $tree->fid($_)->attr('href', "/$_/?owner=$args{id}") for qw/log pb/;
  91         $tree->fid('track_user')->attr('data-user', $args{id});
  92         my @solved = map { $_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
  93         my @attempted = map { !$_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
  94
  95         my $pbiter = sub {
  96                 my ($data, $li) = @_;
  97                 $li->find('a')->namedlink($data);
  98         };
  99         $tree->fid('solved')->find('li')->iter3(\@solved, $pbiter);
 100         $tree->fid('attempted')->find('li')->iter3(\@attempted, $pbiter);
 101         $tree->fid('solved_count')->replace_content(scalar @solved);
 102         $tree->fid('attempted_count')->replace_content(scalar @attempted);
 103
 104         my $ctiter = sub {
 105                 my ($data, $td) = @_;
 106                 $td->fclass('contest')->namedlink($data->{contest}, $data->{contest_name});
 107                 $td->fclass('score')->replace_content($data->{score});
 108                 $td->fclass('rank')->replace_content($data->{rank});
 109         };
 110         $tree->find('table')->find('tbody')->find('tr')->iter3($args{contests}, $ctiter);
 111 }
 112
 113 sub process_us {
 114         my ($tree, %args) = @_;
 115         my $iter = sub {
 116                 my ($data, $tr) = @_;
 117                 $tr->fclass('user')->namedlink($data->{id}, $data->{name});
 118                 $tr->fclass($_)->replace_content($data->{$_}) for qw/solved attempted contests/;
 119         };
 120         $tree->find('tbody')->find('tr')->iter3($args{us}, $iter);
 121 }
 122
 123 sub process_ct_entry {
 124         my ($tree, %args) = @_;
 125         $_->edit_href (sub {s/contest_id/$args{id}/}) for $tree->find('a');
 126         $tree->fid('editorial')->detach unless $args{finished};
 127         $tree->fid('links')->detach unless $args{started};
 128         my $status = ($args{time} < $args{start} ? 'starts' : 'ends');
 129         $tree->fclass('timer')->attr('data-stop', $status eq 'ends' ? $args{stop} : $args{start});
 130         $tree->content_handler(
 131                 start       => ftime   $args{start},
 132                 stop        => ftime   $args{stop},
 133                 status      => $status,
 134                 description => literal $args{description});
 135         $tree->fid('ctcountdown')->detach if $args{time} >= $args{stop};
 136 }
 137
 138 sub process_ct {
 139         my ($tree, %args) = @_;
 140         my $iter = sub {
 141                 my ($data, $tr) = @_;
 142                 $data->{$_} = ftime $data->{$_} for qw/start stop/;
 143                 $tr->hashmap(class => $data, [qw/name owner/]);
 144                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 145                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 146         };
 147         $args{$_} ? $tree->fid($_)->find('tbody')->find('tr')->iter3($args{$_}, $iter) : $tree->fid($_)->detach for qw/running pending finished/;
 148 }
 149
 150 sub process_pb_entry {
 151         my ($tree, %args) = @_;
 152         $tree->fid('owner')->edit_href(sub{s/owner_id/$args{owner}/});
 153         $tree->fid('job_log')->edit_href(sub{s/problem_id/$args{id}/});
 154         $tree->fid('solution')->edit_href(sub{s/problem_id/$args{id}/});
 155         $tree->content_handler(
 156                 statement => literal $args{statement},
 157                 level     => ucfirst $args{level},
 158                 author    =>         $args{author},
 159                 owner     =>         $args{owner_name} || $args{owner});
 160         if ($args{limits}) {
 161                 my @limits = (@{$args{limits}}, {format => 'Other', timeout => $args{timeout} });
 162                 @limits = map { sprintf '%s (%s)', @{$_}{qw/timeout format/} } @limits;
 163                 $tree->look_down(smap => 'timeout')->replace_content(join ', ', @limits);
 164         }
 165         if ($args{contest_stop}) {
 166                 $tree->fid('solution')->detach;
 167                 $tree->fid('solution_modal')->detach;
 168                 my $score = $tree->fid('score');
 169                 $score->attr('data-start' => $args{open_time});
 170                 $score->attr('data-stop'  => $args{contest_stop});
 171                 $score->attr('data-value'  => $args{value});
 172                 $tree->fid('countdown')->attr('data-stop' => $args{contest_stop});
 173         } else {
 174                 $tree->fid('job_log')->edit_href(sub{$_ .= "&private=$args{private}"}) if $args{private};
 175                 $tree->fid('solution')->detach unless $args{solution};
 176                 $_->detach for $tree->fclass('rc'); # requires contest
 177                 $tree->fid('solution_modal')->fclass('modal-body')->replace_content(literal $args{solution});
 178         }
 179         if ($args{cansubmit}) {
 180                 $tree->fid('nosubmit')->detach;
 181                 $tree->look_down(name => 'problem')->attr(value => $args{id});
 182                 my $contest = $tree->look_down(name => 'contest');
 183                 $contest->attr(value => $args{args}{contest}) if $args{args}{contest};
 184                 $contest->detach unless $args{args}{contest}
 185         } else {
 186                 $tree->fid('nosubmit')->find('a')->edit_href(sub{s/id/$args{id}/});
 187                 $tree->fid('submit')->detach
 188         }
 189 }
 190
 191 sub process_sol {
 192         my ($tree, %args) = @_;
 193         $tree->content_handler(solution => literal $args{solution});
 194 }
 195
 196 sub process_pb {
 197         my ($tree, %args) = @_;
 198         my $titer = sub {
 199                 my ($data, $tr) = @_;
 200                 $tr->set_child_content(class => 'author', $data->{author});
 201                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 202                 $tr->fclass('name')->find('a')->edit_href(sub {$_ .= "?contest=$args{contest}"}) if $args{contest};
 203                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 204                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private} && !$args{contest};
 205         };
 206         my $iter = sub {
 207                 my ($data, $div) = @_;
 208                 $div->attr(id => $data);
 209                 $div->find('h2')->replace_content(ucfirst $data);
 210                 $div->find('tbody')->find('tr')->iter3($args{$data}, $titer);
 211         };
 212         $tree->fid('beginner')->iter3([grep {$args{$_}} qw/beginner easy medium hard/], $iter);
 213         $tree->fid('open-alert')->detach unless $args{contest};
 214 }
 215
 216 sub process_log_entry {
 217         my ($tree, %args) = @_;
 218         $tree->fid('problem')->namedlink(@args{qw/problem problem_name/});
 219         $tree->fid('owner')->namedlink(@args{qw/owner owner_name/});
 220         $tree->fid('source')->namedlink("$args{id}.$args{extension}", sprintf '%.2fKB', $args{size}/1024);
 221         if ($args{contest}) {
 222                 $tree->fid('contest')->namedlink(@args{qw/contest contest_name/});
 223                 $tree->fid('problem')->find('a')->edit_href(sub {$_.="?contest=$args{contest}"});
 224         } else {
 225                 $tree->fid('contest')->left->detach;
 226                 $tree->fid('contest')->detach;
 227         }
 228
 229         $args{errors} ? $tree->fid('errors')->find('pre')->replace_content($args{errors}) : $tree->fid('errors')->detach;
 230         my $iter = sub {
 231                 my ($data, $tr) = @_;
 232                 $data->{time} = sprintf '%.4fs', $data->{time};
 233                 $tr->defmap(class => $data);
 234                 $tr->fclass('result_text')->attr(class => "r$data->{result}")
 235         };
 236         $tree->fclass('result_text')->replace_content($args{result_text});
 237         $tree->fclass('result_text')->attr(class => "r$args{result}");
 238         $args{results} ? $tree->fid('results')->find('tbody')->find('tr')->iter3($args{results}, $iter) : $tree->fid('results')->detach;
 239         $tree->fid('no_results')->detach if $tree->fid('results') || $tree->fid('errors');
 240 }
 241
 242 sub process_log {
 243         my ($tree, %args) = @_;
 244         my $iter = sub {
 245                 my ($data, $tr) = @_;
 246                 $tr->fclass('id')->namedlink($data->{id});
 247                 $tr->fclass('problem')->namedlink($data->{problem}, $data->{problem_name});
 248                 $tr->fclass('problem')->find('a')->edit_href(sub{$_ .= "?contest=$args{args}{contest}"}) if $args{args}{contest};
 249                 $tr->fclass('contest')->namedlink($data->{contest}, $data->{contest_name}) if $data->{contest};
 250                 $tr->fclass('contest')->replace_content('None') unless $data->{contest};
 251                 $tr->fclass('date')->replace_content(ftime $data->{date});
 252                 $tr->fclass('source')->namedlink("$data->{id}.$data->{extension}", sprintf "%.2fKB %s", $data->{size}/1024, Plack::App::Gruntmaster::FORMAT_EXTENSION()->{$data->{format}});
 253                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 254                 $tr->fclass('result_text')->replace_content($data->{result_text});
 255                 $tr->fclass('result_text')->attr(class => "r$data->{result}");
 256                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private};
 257         };
 258         $tree->find('table')->find('tbody')->find('tr')->iter3($args{log}, $iter);
 259         $args{next_page} ? $tree->fclass('next')->namedlink($args{next_page}, 'Next') : $tree->fclass('next')->detach;
 260         $args{previous_page} ? $tree->fclass('previous')->namedlink($args{previous_page}, 'Previous') : $tree->fclass('previous')->detach;
 261         for my $cls (qw/next previous/) {
 262                 my $elem = $tree->fclass($cls);
 263                 next unless $elem;
 264                 delete $args{args}{page};
 265                 my $str = join '&', map { $_ . '=' . $args{args}{$_} } keys %{$args{args}};
 266                 $elem->find('a')->edit_href(sub{s/$/&$str/}) if $str;
 267         }
 268         $tree->fclass('current')->replace_content("Page $args{current_page} of $args{last_page}");
 269 }
 270
 271 sub process_st {
 272         my ($tree, %args) = @_;
 273         $args{problems} //= [];
 274         my $pbiter = sub {
 275                 my ($data, $th) = @_;
 276                 $th->attr(class => undef);
 277                 $th->namedlink(@$data);
 278                 $th->find('a')->edit_href(sub{s/$/?contest=$args{args}{contest}/});
 279         };
 280         $tree->fclass('problem')->iter3($args{problems}, $pbiter);
 281         my $iter = sub {
 282                 my ($st, $tr) = @_;
 283                 $tr->set_child_content(class => 'rank', $st->{rank});
 284                 $tr->set_child_content(class => 'score', $st->{score});
 285                 $tr->fclass('user')->namedlink($st->{user}, $st->{user_name});
 286                 my $pbscore = $tr->fclass('pbscore');
 287                 $pbscore->iter($pbscore => @{$st->{scores}});
 288         };
 289         $tree->find('tbody')->find('tr')->iter3($args{st}, $iter);
 290 }
 291
 292 sub process_ed {
 293         my ($tree, %args) = @_;
 294         $tree->content_handler(editorial => literal $args{editorial});
 295         my $iter = sub {
 296                 my ($data, $div) = @_;
 297                 $div->set_child_content(class => 'value', $data->{value});
 298                 $div->set_child_content(class => 'solution', literal $data->{solution});
 299                 $div->fclass('problem')->namedlink($data->{id}, $data->{name});
 300         };
 301         my @pb = map { @{$args{$_} // []} } qw/beginner easy medium hard/;
 302         $tree->fclass('well')->iter3(\@pb, $iter);
 303 }
 304
 305 1;
 306 __END__